Question

ans:= RichEdit1.Text     
for i:=1 to Length(ans) do
begin
   RichEdit1.SelStart :=  i-1;
   RichEdit1.SelLength:= 1;
   if ans[i] = correct[i] then
      RichEdit1.SelAttributes.Color := clRed
   else
      RichEdit1.SelAttributes.Color := clBlue;

如果ans中的字母与correct字符串中字母位于同一位置的字母匹配，则为红色，否则为蓝色。

我的问题是，当我再次输入时，整个RichEdit1文本的颜色与第一个字母相同（如果RichEdit1的第一个字母为蓝色，则整个文本变为蓝色）。

顺便说一句，这不是我简化它的实际代码，因为有多个TRichEdits。
TRichEdits是只读的，我通过类似RichEdit1.Text := RichEdit1.Text+Key;的字母分配字母（这样做是因为它是一个多键盘程序，我需要分开用户输入）

这是正确的行为吗？如何阻止我的颜色更改覆盖默认颜色？

更新：解决它...以一种草率的方式（每当有人打字时应用默认颜色），但我保持这个开放，以防有人提出更好的解决方案。

Answer 1

正如您已经发现的那样，您必须在完成后重置默认颜色，例如：

ans := RichEdit1.Text;
for i := 1 to Length(ans) do 
begin 
  RichEdit1.SelStart := i-1; 
  RichEdit1.SelLength := 1; 
  if ans[i] = correct[i] then 
    RichEdit1.SelAttributes.Color := clRed 
  else 
    RichEdit1.SelAttributes.Color := clBlue;
end;
RichEdit1.SelStart := RichEdit1.GetTextLen;
RichEdit1.SelLength := 0;
RichEdit1.SelAttributes.Color := RichEdit1.Font.Color;

有一种更有效的方法来处理这个问题，而不是一次着色一个字母，例如：

const
  colors: array[Boolean] of TColor = (clRed, clBlue);
var
  ans: string;
  start, len: Integer;
  cur_state: Boolean;

  procedure ColorRange(AStart, ALength: Integer; AColor: TColor);
  begin
    RichEdit1.SelStart := AStart;
    RichEdit1.SelLength := ALength;
    RichEdit1.SelAttributes.Color := AColor;
  end;

begin
  RichEdit1.Lines.BeginUpdate;
  try
    ans := RichEdit1.Text;
    start := 0;
    len := 0;
    cur_start := False;

    for i := 1 to Length(ans) do 
    begin 
      if (ans[i] = correct[i]) = cur_state then
        Inc(len)
      else begin
        if len > 0 then
          ColorRange(start, len, colors[cur_state]);
        start := i-1;
        len := 1;
        cur_state := not cur_state;
      end;
    end;
    if len > 0 then
      ColorRange(start, len, colors[cur_state]);
    ColorRange(RichEdit1.GetTextLen, 0, RichEdit1.Font.Color);
  finally
    RichEdit1.Lines.EndUpdate;
  end;
end;

另外，使用Text属性追加单个Char效率非常低。请改用SelText属性，例如：

RichEdit1.SelStart := RichEdit1.GetTextLen;
RichEdit1.SelLength := 0;
RichEdit1.SelAttributes.Color := ...; // optional
RichEdit1.SelText := Key;

TRichEdit颜色问题

1 个答案: