Question

有一段时间以来，我一直在问自己是否有办法定义一个具有多个可变参数的函数。这是我写的一个示例函数（我知道没有异常管理加上也许有更好的编码方式 - 实际上我没有调试它 - 但我只关注可变方面）：

(defn write-csv
  "Writes a csv from data that is already formatted for clojure.data.csv/write-csv or not.
   In the second case, the function guesses a header and writes it. Can handle three types of
   data : nested rows (example : {1 {:a 2 :b 3} 2 {:a 25 :b 17} ...), flattened data (like the one you use
   in clj-data-process-utils.data (example : ({:id 1 :a 2 :b 3} {:id 2 :a 25 :b 17} ...)) or already formatted
   data (example : [['ID' 'B' 'C'] [1 2 3] [2 25 17]]). Note that in the last case you have to provide a header if you want one.
   The guesses can be overriden by the :header arg. Optimized for Excel with default values.
   Input :
   - data : data to write as CSV
   - path : the filepath of the new CSV
   - (optional) sep : the separator to use, must be of type char [default : ;]
   - (optional) dec : the decimal separator to use, must be of type char [default : .]
   - (optional) newline : the newline character, see cljure.data.csv options, default here for windows [default : :cr+lf]
   - (optional) header : if you want to provide your own data, pass here a vector of columns names, guesses by default if data is not formatted [default : :guess]"
  [data path & {:keys [sep dec newline header] :or {sep \; dec \. newline :cr+lf header :guess}}]
  (let [f-data (cond (or (map? data) (seq? data))
                       (cond (vec? header)
                               (format-for-csv sep data header)
                             (= :guess header)
                               (->> (guess-header data)
                                    (format-for-csv sep data)))
                     (vec? data)
                       data)
        wrtr (io/writer path)]
    (csv/write-csv wrtr f-data :separator sep :newline newline)))

如您所见，我们可以选择传递标题。我把它放在可选键上，但我希望在第一个实例中有这样的东西（即使这个aritties地图对我来说还可以）：

(defn write-csv 
  ([data path & {:keys [sep dec newline] :or {sep \; dec \. newline :cr+lf}}]
    ...)
  ([data header path & {:keys [sep dec newline] :or {sep \; dec \. newline :cr+lf}}]
    ...))

当然它不起作用，因为我们不能有超过1个可变的重载。我更喜欢它，因为它对最终用户来说更清楚。

我这么做了两件事：

使用第二个私有函数和apply ...但它没有解决第一个问题的问题，因为我想要两种可能的输入样式。
我看了defmulti，但我看到每个子方法也需要相同的arities

当然我也可以将函数拆分为两个或区分第一个arg中的两个案例（带有类型[vector map]的向量意味着用户已经传递了未格式化的数据+一个标题）但是更糟糕的是用户。我真的想提供这些输入的可能性。

在clojure函数中是否有一些我没有注意到的东西，还是我们无法解决的更深层次的问题？

谢谢！

Answer 1

将所有关键字args保存在单独的地图中是最好的解决方案，我猜..但是还有一种相对流行的方法，如果你真的需要（我认为不是）：你可以使用一个可变参数签名与arglists元数据结合使用：

user> (defn parse
        {:arglists '([data header? path & {:keys [sep dec newline]
                                           :or {sep :aaa
                                                dec :bbb
                                                newline :ccc}}])}
        [data header-or-path & args]
        (let [[header path {:keys [sep dec newline]
                            :or {sep :aaa dec :bbb newline :ccc}}]
              (if (even? (count args))
                [nil header-or-path args]
                [header-or-path (first args) (rest args)])]
          (println data header path sep dec newline)))
#'user/parse

user> (parse 1 2)
1 nil 2 :aaa :bbb :ccc
nil

user> (parse 1 2 3)
1 2 3 :aaa :bbb :ccc
nil

user> (parse 1 2 :sep :a :dec :b)
1 nil 2 :a :b :ccc
nil

user> (parse 1 2 3 :sep :a :dec :b)
1 2 3 :a :b :ccc
nil

您（或您的lib用户）使用的ide将显示来自:arglists的签名，忽略真实签名：

user/parse
 [data header? path & {:keys [sep dec newline], :or {sep :aaa, dec :bbb, newline :ccc}}]
  Not documented.
user/parse is defined in *cider-repl localhost*.

但同样：这太冗长且难以维护（由于代码重复），所以你应该明智地使用它（我的意思是没有人应该这样做）

Clojure：超过1的可变超载，更惯用的方法呢？

1 个答案: