Question

我正在编写一个XSLT 1.0样式表来将多名称空间XML文档转换为HTML。在结果HTML的某个地方，我想列出文档中出现的所有名称空间。

这可能吗？

我想过像

这样的东西

<xsl:for-each select="//*|//@*">
  <xsl:value-of select="namespace-uri(.)" />
</xsl:for-each>

但当然我会得到重复的重复数据。所以我必须以某种方式过滤我已经打印的内容。

递归调用模板会起作用，但我无法理解如何到达所有元素。

直接访问//@xmlns:*不起作用，因为无法通过XPath访问它（不允许将任何前缀绑定到xmlns:命名空间）。

Answer 1

另一个没有扩展功能：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="*">
        <xsl:param name="pNamespaces" select="'&#xA;'"/>
        <xsl:variable name="vNamespaces">
            <xsl:variable name="vMyNamespaces">
                <xsl:value-of select="$pNamespaces"/>
                <xsl:for-each select="namespace::*
                                        [not(contains(
                                                 $pNamespaces,
                                                 concat('&#xA;',.,'&#xA;')))]">
                    <xsl:value-of select="concat(.,'&#xA;')"/>
                </xsl:for-each>
            </xsl:variable>
            <xsl:variable name="vChildsNamespaces">
                <xsl:apply-templates select="*[1]">
                    <xsl:with-param name="pNamespaces"
                                        select="$vMyNamespaces"/>
                </xsl:apply-templates>
            </xsl:variable>
            <xsl:value-of select="concat(substring($vMyNamespaces,
                                                   1 div not(*)),
                                         substring($vChildsNamespaces,
                                                   1 div boolean(*)))"/>
        </xsl:variable>
        <xsl:variable name="vFollowNamespaces">
            <xsl:apply-templates select="following-sibling::*[1]">
                <xsl:with-param name="pNamespaces" select="$vNamespaces"/>
            </xsl:apply-templates>
        </xsl:variable>
        <xsl:value-of
             select="concat(substring($vNamespaces,
                                      1 div not(following-sibling::*)),
                            substring($vFollowNamespaces,
                                      1 div boolean(following-sibling::*)))"/>
    </xsl:template>
</xsl:stylesheet>

输出（使用Dimitre的输入样本）：

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

编辑：此XPath表达式：

//*/namespace::*[not(. = ../../namespace::*|preceding::*/namespace::*)]

作为证明，这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">
        <xsl:for-each select="//*/namespace::*
                                     [not(. = ../../namespace::*|
                                              preceding::*/namespace::*)]">
            <xsl:value-of select="concat(.,'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

输出：

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

编辑4：与两遍转换效率相同。

此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kElemByNSURI"
             match="*[namespace::*[not(. = ../../namespace::*)]]"
              use="namespace::*[not(. = ../../namespace::*)]"/>
    <xsl:template match="/">
        <xsl:for-each select=
            "//namespace::*[not(. = ../../namespace::*)]
                           [count(..|key('kElemByNSURI',.)[1])=1]">
            <xsl:value-of select="concat(.,'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

输出：

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

编辑 5：当您处理没有namespace ax实现的XSLT处理器（如TransforMiix）时，您只能提取实际使用此样式表的命名空间：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:key name="kElemByNSURI" match="*|@*" use="namespace-uri()"/>
    <xsl:template match="/">
        <xsl:for-each select=
            "(//*|//@*)[namespace-uri()!='']
                       [count(.|key('kElemByNSURI',namespace-uri())[1])=1]">
            <xsl:value-of select="concat(namespace-uri(),'&#xA;')"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

TransforMiix输出：

mynamespace2

Answer 2

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:template match="/">
   <xsl:for-each select=
    "//namespace::*[not(. = ../../namespace::*)]">
     <xsl:value-of select="concat(.,'&#xA;')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

应用于此XML文档时：

<authors xmlns:user="mynamespace">
  <?ttt This is a PI ?>
  <author xmlns:user2="mynamespace2">
    <name idd="VH">Victor Hugo</name>
    <user2:name idd="VH">Victor Hugo</user2:name>
    <nationality xmlns:user3="mynamespace3">French</nationality>
  </author>
</authors>

生成想要的正确结果：

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

<强>更新：

正如@svick评论的那样，上述解决方案仍会偶尔产生重复的命名空间，例如使用以下XML文档：

<authors xmlns:user="mynamespace">
  <?ttt This is a PI ?>
  <author xmlns:user2="mynamespace2">
    <name idd="VH">Victor Hugo</name>
    <user2:name idd="VH">Victor Hugo</user2:name>
    <nationality xmlns:user3="mynamespace3">French</nationality>
  </author>
  <t xmlns:user2="mynamespace2"/>
</authors>

命名空间"mynamespace2"将在输出中生成两次。

以下转换解决了此问题：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext">
 <xsl:output method="text"/>

 <xsl:key name="kNSbyURI" match="n" use="."/>

 <xsl:template match="/">
   <xsl:variable name="vrtfNS">
       <xsl:for-each select=
        "//namespace::*[not(. = ../../namespace::*)]">
         <n><xsl:value-of select="."/></n>
       </xsl:for-each>
   </xsl:variable>

   <xsl:variable name="vNS" select="ext:node-set($vrtfNS)/*"/>

   <xsl:for-each select=
    "$vNS[generate-id()
         =
          generate-id(key('kNSbyURI',.)[1])
         ]">
     <xsl:value-of select="concat(., '&#xA;')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于上述XML文档时，它只生成文档中的所有唯一命名空间：

http://www.w3.org/XML/1998/namespace
mynamespace
mynamespace2
mynamespace3

第二部分：XSLT 2.0解决方案。

XSLT 2.0解决方案是一个简单的XPath 2.0单行程序：

distinct-values(//namespace::*)

XSLT：如何获取所有使用的命名空间的列表

2 个答案: