Question

{-# LANGUAGE TypeFamilies #-}

import GHC.Prim
import qualified Data.Set as Set

class Functor' f where
    type FConstraint f :: * -> Constraint
    fmap' :: (FConstraint f a, FConstraint f b) => (a -> b) -> f a -> f b

instance Functor' Set.Set where
    type FConstraint Set.Set = Ord Num  --error here, won't let me put Num
    fmap' = Set.map

我想知道如何才能完成上述工作。现在我知道我可以手动要求两个类型类，但我希望能够组合任意数量的类型。

现在我知道在这种情况下要求Num没有意义，但这只是一个例子。

Answer 1

您需要定义一个类型类（因为可以部分应用类型类），它会通过超类减少您想要的约束：

{-# LANGUAGE 
    PolyKinds, UndecidableInstances, TypeOperators
  , MultiParamTypeClasses, ConstraintKinds, TypeFamilies
  , FlexibleContexts, FlexibleInstances 
#-}

class (f x, g x) => (&) f g (x :: k)
instance (f x, g x) => (&) f g x

显然(f & g) x代表iff f x和g x成立。 FConstraint'的定义现在应该是显而易见的：

class Functor' ... 

instance Functor' Set.Set where
    type FConstraint Set.Set = Ord & Num
    fmap' f = Set.map ( (+1) . f )  -- (+1) to actually use the Num constraint

Answer 2

看起来我需要做的唯一更改不是部分应用FConstraint：

{-# LANGUAGE TypeFamilies #-}

import GHC.Prim
import qualified Data.Set as Set

class Functor' f where
    type FConstraint f a :: Constraint
    fmap' :: (FConstraint f a, FConstraint f b) => (a -> b) -> f a -> f b 

instance Functor' Set.Set where
    type FConstraint Set.Set a = (Ord a, Num a)
    fmap' f = Set.map ((+ 1) . f)

foo = fmap (+ 1) $ Set.fromList [1, 2, 3]

不幸的是，据我所知，这不允许我使用具体类型，但我认为无论如何它都不会与Functor匹配（Functor有类{{1}但是* -> *等具体值的列表具有种类String）。

Haskell结合了多个类型类约束

2 个答案: