Question

我正在尝试从Compiler RT获取数学例程，使用GCC工具链来处理ARM Cortex M3 / M4F处理器（带有fpu的armv7m和armv7em）。

除了以下函数中的两行代码（msr CPSR_f, ip和msr CPSR_f, #APSR_C）之外，我编译了所有内容（进行了少量更改）

#define APSR_Z (1 << 30)
#define APSR_C (1 << 29)

DEFINE_COMPILERRT_FUNCTION(__aeabi_cfcmple)
    // Per the RTABI, this function must preserve r0-r11.
    // Save lr in the same instruction for compactness
    push {r0-r3, lr}

    bl __aeabi_fcmplt
    cmp r0, #1
    IT(eq)
    moveq ip, #0
    beq 1f

    ldm sp, {r0-r3}
    bl __aeabi_fcmpeq
    cmp r0, #1
    IT(eq)
    moveq ip, #(APSR_C | APSR_Z)
    IT(ne)
    movne ip, #(APSR_C)

1:
    msr CPSR_f, ip
    pop {r0-r3}
    POP_PC()
END_COMPILERRT_FUNCTION(__aeabi_cfcmple)

另一个功能：

DEFINE_COMPILERRT_FUNCTION(__aeabi_cfcmpeq)
    push {r0-r3, lr}
    bl __aeabi_cfcmpeq_check_nan
    cmp r0, #1
    pop {r0-r3, lr}

    // NaN has been ruled out, so __aeabi_cfcmple can't trap
    bne __aeabi_cfcmple

    msr CPSR_f, #APSR_C
    JMP(lr)
END_COMPILERRT_FUNCTION(__aeabi_cfcmpeq)

armv7m指令集上没有CPSR_f表示法。如何将msr CPSR_f, ip和msr CPSR_f, #APSR_C转换为armv7m代码（armv7em应该相同）？

Answer 1

您需要使用MOV APSR, Rm指令。 Cortex-M处理器基本上没有CPSR，APSR寄存器作为条件代码的替代品。

第一个函数很容易修复，因为它使用寄存器作为源操作数。只需将msr CPSR_f, ip替换为msr APSR_nzcvq, ip即可。第二个功能需要通过寄存器。假设IP寄存器可以像第一个函数一样被破坏，你可以使用：

mov ip, #APSR_C
msr APSR_nzcvq, ip

修改Comipler RT汇编代码以编译Arm Cortex M3 / M4（CPSR / APSR位操作）

1 个答案: