Question

Unity的优秀新Sprite（以及Unity's excellent new sprites），以及其他有价值的优势，实际上是双面的。在2D或3D用例中，你可以翻转周围的小混蛋，仍然可以从后面看到它们 - 它们是从两侧渲染的。

我也喜欢上面使用的不亮的着色器（即Sprite-Default，而不是Sprite-Diffuse）。

但是我需要一个老式的单面Sprite。

幸运的是，您可以免费下载Unity使用的优秀着色器的来源...令人困惑的是，您不能只在编辑器中打开它，但请参阅here及其here。< / p>

在相当持久的努力涉及廉价威士忌之后，我对着色器做了两（2）次修改。

1）我将文件第一行的名称更改为“DefaultSingle”而不是“Default”

2）我评论了Cull Off

行

（然后我做了一个新的Material，称之为“Sprite Single Sided”，将着色器设置为这个新的，并在Sprite s上用新材料替换材质槽。）

事实上，我是否通过进行此修改搞砸了着色器中的任何内容？一个人可以快速评论出“剔除”而不会引起进一步的问题吗？是否有一些改变Sprite使用的常用材料（你不能“看到”它，所以我不知道）。更广泛地说，是否有更正确的方法来实现单面Sprite？

// file "Sprites-DefaultSingle.shader"
Shader "Sprites/DefaultSingle"
{
  Properties
  {
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)
    [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
  }

  SubShader
  {
    Tags
    { 
      "Queue"="Transparent" 
      "IgnoreProjector"="True" 
      "RenderType"="Transparent" 
      "PreviewType"="Plane"
      "CanUseSpriteAtlas"="True"
    }

  ///  Cull Off
    Lighting Off
    ZWrite Off
    Blend One OneMinusSrcAlpha

    Pass
    {
    CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag
      #pragma multi_compile _ PIXELSNAP_ON
      #pragma shader_feature ETC1_EXTERNAL_ALPHA
      #include "UnityCG.cginc"

      struct appdata_t
      {
        float4 vertex   : POSITION;
        float4 color    : COLOR;
        float2 texcoord : TEXCOORD0;
      };

      struct v2f
      {
        float4 vertex   : SV_POSITION;
        fixed4 color    : COLOR;
        float2 texcoord  : TEXCOORD0;
      };

      fixed4 _Color;

      v2f vert(appdata_t IN)
      {
        v2f OUT;
        OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
        OUT.texcoord = IN.texcoord;
        OUT.color = IN.color * _Color;
        #ifdef PIXELSNAP_ON
        OUT.vertex = UnityPixelSnap (OUT.vertex);
        #endif

        return OUT;
      }

      sampler2D _MainTex;
      sampler2D _AlphaTex;

      fixed4 SampleSpriteTexture (float2 uv)
      {
        fixed4 color = tex2D (_MainTex, uv);

#if ETC1_EXTERNAL_ALPHA
        // get the color from an external texture ..
        color.a = tex2D (_AlphaTex, uv).r;
#endif //ETC1_EXTERNAL_ALPHA

        return color;
      }

      fixed4 frag(v2f IN) : SV_Target
      {
        fixed4 c = SampleSpriteTexture (IN.texcoord) * IN.color;
        c.rgb *= c.a;
        return c;
      }
    ENDCG
    }
  }
}

Answer 1

据我所知，除了你想要的那些之外，这些变化都没有任何影响。此外，这是实现这一目标的最正确方法 - 它是Cull唯一的用途。

Answer 2

这不会造成任何问题，是正确的做事方式。如果你想真正明确它，你可以将行更改为Cull Back而不是将其注释掉，但是背面剔除被定义为默认行为，所以只需删除就可以了。

Unity3D Sprite ......但单面？

2 个答案: