Question

我的任务非常简单。

有一个文件夹包含多个具有不同扩展名的文件。我需要创建一个脚本，它将在此文件夹中找到扩展名为.txt的所有文件，从每个文件中读取第一行，然后在新创建的文件中写入所有第一行。

现在，我最终得到了类似的东西：

Option Explicit
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

Dim f, colFiles , objFile
Dim tFolder, tFile
Dim lineToCopy, fileContents
Dim input, output

Set tFolder = fso.GetFolder("C:\Temp")
Set tFile = tFolder.CreateTextFile("test.txt", true) 

Set f = fso.GetFolder("D:\Folder")
Set colFiles = f.Files
    For Each objFile in colFiles
        If LCase(fso.GetExtensionName(objFile.name)) = "txt" Then
            Set input = fso.OpenTextFile(LCase(objFile.name))
            If Not input.AtEndofStream Then lineToCopy = input.ReadLine
            input.close
            output = fso.OpenTextFile(tFolder, True)
            output.WriteLine lineToCopy
            output.close
        End If
    Next

WScript.sleep 60000000

激活后，.vbs文件告诉我他无法从该行找到该文件：

Set input = fso.OpenTextFile(LCase(objFile.name))

我想这是因为IF LCASE＆lt; ...＆gt; block不会将文件夹内容理解为.txt文件。我错在哪里以及解决这个问题需要做些什么？

请你的，理查德

Answer 1

使用OpenTextFile文件的完整.Path或通过OpenAsTextStream获取流。使用tFile而不是重复创建输出。删除所有危险/货物崇拜脂肪：

Option Explicit

Dim fso   : Set fso = CreateObject("Scripting.FileSystemObject")
Dim tFile : Set tFile = fso.CreateTextFile(fso.BuildPath(".\", "test.txt"))
Dim oFile

For Each oFile in fso.GetFolder("..\data").Files
    If LCase(fso.GetExtensionName(oFile.Path)) = "txt" Then
'      Dim input: Set input = fso.OpenTextFile(LCase(oFile.Path))
       Dim input: Set input = oFile.OpenAsTextStream()
       If Not input.AtEndofStream Then tFile.WriteLine input.ReadLine()
       input.Close
    End If
Next

tFile.Close

Answer 2

看起来我已经找到了自己的决定：

Option Explicit
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

Dim f, colFiles , objFile
Dim tFolder, tFile
Dim lineToCopy, readFile

Set tFolder = fso.GetFolder("C:\Temp")
Set tFile = tFolder.CreateTextFile("test.txt", true) 

Set f = fso.GetFolder("D:\Scripting Games 2008\Beginner")
Set colFiles = f.Files
    For Each objFile in colFiles
        If LCase(fso.GetExtensionName(objFile.name)) = "txt" Then
        REM Preceding passage finds all .txt files in selected folder
            Set readFile = objFile.OpenAsTextStream
            lineToCopy = ""
                Do Until lineToCopy <> "" Or readfile.atEndOfStream
                    lineToCopy = Trim(readFile.ReadLine)
                Loop
                REM Extracts first line of the text, if it is not empty
            tFile.WriteLine objFile.name & ": " & lineToCopy
        End If
    Next

仍然，谢谢你的答案。我找到了一些有趣的解决方案，这些解决方案有一段时间可以使用。

请你的，理查德

从几个.txt文件中读取一行并将其写入创建的文件中

2 个答案: