Question

我想绘制一个白色圆圈的自定义半透明光标。我在Windows 7操作系统中使用Delphi XE3。

我的代码在某种程度上正在发挥作用。我可以设置alpha通道并修改透明度，但颜色为银色/深灰色而不是白色。

当我运行调试时，我可以看到正在设置正确的白色（$ B4FFFFFF），其中$ B4是alpha值。

我已根据之前的subject

调整了我的代码

type
pScanLineArray = ^TScanLineArray;
TScanLineArray= array [Word] of Cardinal;

procedure TForm1.Button1Click(Sender: TObject);
  const CursorIdx = TCursor(-25); {arbitrary}
        Mid = 64; {middle of cursor dimension (128)}
        FPenSize = 50;
  var IconInfo : TIconInfo;
      X, Y: Integer;
      AlphaCursor: HCURSOR;
      ForG, BackG, Border: Cardinal;
      Dist: Double;
      LineP: pScanLineArray;
      FCursorMaskBMP,FCursorColorBMP: TBitmap;
begin
  {Create Bitmaps}
  FCursorMaskBMP:= TBitMap.Create;
  FCursorMaskBMP.PixelFormat:= pf32bit;
  FCursorMaskBMP.SetSize(128, 128);

  FCursorColorBMP:= TBitMap.Create;
  FCursorColorBMP.PixelFormat:= pf32bit;
  FCursorColorBMP.SetSize(128, 128);


  {Fill the AND mask. In this case, content ignored by windows}
  FCursorMaskBMP.Monochrome := True;
  FCursorMaskBMP.Canvas.Brush.Color := clWhite;
  FCursorMaskBMP.Canvas.FillRect(FCursorMaskBMP.Canvas.ClipRect);

  {Set all the colors for the cursor}
  ForG:= $B4FFFFFF; {semi-transarent white - for inside of circle}
  BackG:= $00000000; {Full transparent - for outside of circle}
  Border:= $FF000000; {non-transparent black for border}

  {Fill the bitmap}
  for Y := 0 to (FCursorColorBMP.Height - 1) do
  begin
    LineP := FCursorColorBMP.ScanLine[Y];
    for X := 0 to (FCursorColorBMP.Width - 1)do
    begin
      Dist:= SQRT(Power(Y-Mid,2)+Power(X-Mid,2)); {Distance from middle of circle}
      if Dist<FPenSize then  {Within circle - apply forground trasparent color}
        LineP^[X] := ForG
      else
        if (Dist>=FPenSize) and (Dist<FPenSize+1) then
          LineP^[X] := Border {This is the border - apply opaque color of border}
        else
          LineP^[X] := BackG; {Outside circle - apply fully transparent color }
    end;
  end;

  FCursorColorBMP.AlphaFormat := afDefined;  {does not seem to have any effect ?}

  with IconInfo do
  begin
    fIcon := false;
    xHotspot := Mid;
    yHotspot := Mid;
    hbmMask := FCursorMaskBMP.Handle;
    hbmColor := FCursorColorBMP.Handle;
  end;

  AlphaCursor:=CreateIconIndirect(IconInfo);
  Win32Check(Bool(AlphaCursor));   {My guess is that this is some error checking ?}
  Screen.Cursors[CursorIdx] := AlphaCursor;
  Screen.Cursor := CursorIdx;

end;

注意：要编译上述内容，必须将单位“Math”添加到“uses”子句

中

请参阅附件中的图片

在这种特殊情况下，光标的最终颜色（图像白色上方的部分）是$ xxCACACA

我也尝试过除白色之外的其他颜色。结果是相似的 - 颜色变得“暗淡”

如果我将alpha通道设置为不透明，那么我会按预期获得一个白色光标（但当然不再透明）。

我的猜测是，我看到的是光标白色混合两次的结果：

混合黑/暗背景（也许是AND面具？）
与屏幕图像混合。

但这只是猜测，我无法弄清楚从哪里开始。有人可以帮忙吗？

有关

FCursorColorBMP.AlphaFormat := afDefined;

当上面的代码在代码中时，我得到以下结果

如果抓取颜色值（使用MS绘画），光标与不同颜色重叠会产生这些值（RGB）：

white overlap: 164, 164, 164
Red overlap  : 157, 97,  100
Green overlap: 89,  127, 89
Blue overlap : 89,  89,  164

如果我省略上述行或将其更改为

FCursorColorBMP.AlphaFormat := afIgnored;

然后我得到这个图像

当我抓住颜色时，我得到以下值：

white overlap: 202, 202, 202
Red overlap  : 197, 135, 138
Green overlap: 127, 165, 127
Blue overlap : 127, 127, 202

在看到Tom Brunberg的回答之后，我想我会创建一个exe文件并在另一台机器上运行它。结果很好，与汤姆的结果一致。

总之，Alphaformat应设置为AfIgnored（或ommited），这在技术上解决了某些系统的问题。

出于某种原因，我的系统仍会显示错误的颜色！我的Win7在Mac OS上通过Parallels进行虚拟运行 - 不知道这是否是造成这种奇怪行为的原因。

Answer 1

按原样应用代码时，我得到以下结果：

但是，如果我改变了

FCursorColorBMP.AlphaFormat := afIgnored;  {does not seem to have any effect ?}

我明白了：

由于afIgnored是默认值，因此您可以简单地省略该行，正如Sertac Akyuz在其评论中所建议的那样。

如果您觉得白色太不透明，请降低Alpha值。

编辑，进一步信息：

虽然我没有找到任何文档，但我非常有信心Windows在渲染游标时使用alpha值，因此不会预先计算位图。为了备份我的想法，我做了以下检查，用几种颜色的纯红色，绿色和深蓝色：

alpha混合的通用公式是

  output = alpha * foreground + (1-alpha) * background

并分别计算红色，绿色和蓝色成分。

使用上面(A:B4, R:FF, G:FF, B:FF)的白色叠加层和Alpha值

的颜色成分

 - red field   (R:FF, G:0,  B:0)  becomes R:FF, G:B4, B:B4.
 - green field (R:0,  G:BF, B:0)  becomes R:B4, G:EC, B:B4. 
 - blue field  (R:0,  G:0,  B:7F) becomes R:B4, G:B4, B:D9.

以上数值是使用图形编辑程序的“吸管”拍摄的。

值与

计算的值相同

  // Result color components
  resR := a * fgR div $FF + ($FF - a) * bgR div $FF;
  resG := a * fgG div $FF + ($FF - a) * bgG div $FF;
  resB := a * fgB div $FF + ($FF - a) * bgB div $FF;

，其中

  // overlay alpha
  a := $B4;
  // overlay color components
  fgR := $FF;
  fgG := $FF;
  fgB := $FF;

和

  // background color components for the red field
  bgR := $FF;
  bgG := $0;
  bgB := $0;
  // background color components for the green field
  bgR := $0;
  bgG := $BF;
  bgB := $0;
  // background color components for the dark blue field
  bgR := $0;
  bgG := $0;
  bgB := $7F;

将新创建的位图的bitmap.AlphaFormat设置为afDefined或afPremultiplied（默认为afIgnored）时执行预先计算。（请参阅procedure TBitmap.SetAlphaFormat(Value: TAlphaFormat);中的Vcl.Graphics）

透明光标在Delphi中显示错误的颜色

1 个答案: