Question

我正在尝试使用mydataset.loadfromfile("myfile.xml")

将XML文件加载到Delphi数据集中

问题在于我不知道XML字段名称以及它有多少字段。我知道XML只有一个级别，例如：

<DOCTO id ="3892" usuario="2" data="22/12/2015 10:33:22">
  <CONDUTA_1>teste conduta 1</CONDUTA_1>
  <CONDUTA_2>teste conduta 2</CONDUTA_2>
</DOCTO>

我正在寻找一种在不创建字段之前加载xml的方法。

Answer 1

正如您所说，您无法使用XMLMapper，我已将我的答案部分移至底部。

由于您无法使用XmlMapper，因此您需要使用XML解析器自行解析XML。下面的示例使用Windows附带的XML DOM Parser，在MSXML列表中需要Uses。为了说明如何这样做，我将使用与您的结构相同的XML但使用抽象节点 - 和属性名称，以避免您的XML的节点名称和值分散注意力。

<data a1="a" a2="b" a3="c">
  <r1>11111</r1>
  <r2>22222</r2>
</data>

在一个极端，字段名称可能是<data>节点属性的名称a1，a2，a3，字段值可能是这些属性＆＃39;值。

如何获取这些内容显示在LoadFromAttributes例程中。基本上，它加载 XML进入XMLDoc对象，使用XPath查询来查找<data>节点和他们掌握了它的属性来创建数据集字段并设置它们的值。

在另一个极端，子节点<r1>和<r2>可能是字段名称及其节点文本，字段值。 LoadFromNodes例程显示了如何执行此操作。

当然，在实践中，XML的语义可能意味着字段名称和价值观是两者的混合，但你没有说什么你的XML＆＃34;意味着＆＃34;，我必须把它留给你。

  TForm1 = class(TForm)
    Memo1: TMemo;
    CDS1: TClientDataSet;
    DataSource1: TDataSource;
    DBGrid1: TDBGrid;
    btnAttributes: TButton;
    btnFromNodes: TButton;
    procedure FormCreate(Sender: TObject);
    procedure btnAttributesClick(Sender: TObject);
    procedure btnFromNodesClick(Sender: TObject);
  public
    XMLDoc : IXMLDOMDocument;
    procedure PrepareCDS;
    procedure LoadFromAttributes;
    procedure LoadFromNodes;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  scXML =
     '<data a1="a" a2="b" a3="c">'#13#10
   + '  <r1>11111</r1>'#13#10
   + '  <r2>22222</r2>'#13#10
   + '</data>';

   scRootNodeName = 'data';

procedure TForm1.FormCreate(Sender: TObject);
begin
  XmlDoc := CoDOMDocument.Create;
  XmlDoc.Async := False;
  XMLDoc.loadXML(scXML);
  Memo1.Lines.Text := scXML;
end;

procedure TForm1.LoadFromAttributes;
var
  PathQuery : String;
  NodeList : IXmlDOMNodeList;
  Node,
  AttrNode : IXmlDomNode;
  Attributes : IXMLDOMNamedNodeMap;
  Field : TField;
  i : Integer;
begin
  PrepareCDS;

  PathQuery := scRootNodeName;
  NodeList := XMLDoc.SelectNodes(PathQuery);
  Assert(NodeList.Length > 0);
  Node := NodeList.item[0];
  Attributes := Node.attributes;
  for i := 0 to Attributes.Length - 1 do begin
    AttrNode := Attributes.item[i];
    Field := TStringField.Create(Self);
    Field.Size := 80;
    Field.FieldName := AttrNode.nodeName;
    Field.DataSet := CDS1;
  end;

  CDS1.CreateDataSet;

  CDS1.Insert;
  for i := 0 to Attributes.Length - 1 do begin
    AttrNode := Attributes.item[i];
    CDS1.Fields[i].Value := AttrNode.nodeValue;
  end;
  CDS1.Post;
end;

procedure TForm1.LoadFromNodes;
var
  PathQuery : String;
  NodeList : IXmlDOMNodeList;
  Node,
  AttrNode : IXmlDomNode;
  Field : TField;
  i : Integer;
begin
  PrepareCDS;

  PathQuery := scRootNodeName + '/*';
  NodeList := XMLDoc.SelectNodes(PathQuery);
  Assert(NodeList.Length > 0);
  for i := 0 to NodeList.Length - 1 do begin
    Node := NodeList.item[i];
    Field := TStringField.Create(Self);
    Field.Size := 80;
    Field.FieldName := Node.nodeName;
    Field.DataSet := CDS1;
  end;

  CDS1.CreateDataSet;

  CDS1.Insert;
  for i := 0 to NodeList.Length - 1 do begin
    Node := NodeList.item[i];
    CDS1.Fields[i].Value := Node.Text;
  end;
  CDS1.Post;
end;

procedure TForm1.PrepareCDS;
begin
  if CDS1.Active then
    CDS1.Close;
  CDS1.FieldDefs.Clear;
  CDS1.Fields.Clear;
end;

procedure TForm1.btnAttributesClick(Sender: TObject);
begin
  LoadFromAttributes;
end;

procedure TForm1.btnFromNodesClick(Sender: TObject);
begin
  LoadFromNodes;
end;

正如您所看到的，所有这些都非常简单，只需要熟悉MS XML解析器和XPath的使用（尽管在这种情况下，XML结构非常简单，您并不需要使用XPath得到它。）

在您的情况下，它不适用，但如果您的XML结构已预先修复，您可以使用Delphi附带的实用程序XmlMapper来定义映射文件，将其转换为TClientDataSet格式使用。然后，你可以使用 TClientDataSet与另一个组件TXmlTransformProvider结合使用，该组件使用转换文件将数据加载到CDS中。富勒细节在这里：

Parsing xml file Delphi

顺便说一句，如果您的.Xml文件实际上有多个<DOCTO>节点，则存在明显的风险，您需要将它们放在根节点下，以便该文件具有有效的XML结构。

将动态XML加载到数据集中

1 个答案: