Question

我有一个XSLT 1.0转换要编写，我找不到我的问题的在线好解决方案。我有以下XML示例：

    <?xml version="1.0" encoding="utf-8"?>

    <MainDoc>
    <node1>
            <node2>
                    <User>jsmith</User>
                    <Amount>1,23</Amount>
            </node2>
            <node2>
                    <User>abrown</User>
                    <Amount>4,56</Amount>
            </node2>
    </node1>

正如您所看到的，由于逗号，sum函数不起作用。我需要的是将所有金额值相加，即1,23 + 4,56 +等......

我尝试了各种解决方案但没有成功。大多数情况下，我找到了基本的例子，但没有像这种情况。

问题是我希望从XSLT代码调用转换，例如：

    <xsl:call-template name="sumAll">
        <xsl:with-param name="node" select="/MainDoc/node1/node2/Amount"/> 
    </xsl:call-template>

这样，它将汇总/ MainDoc / node1 / node2路径中“Amount”的所有值。

感谢任何帮助

Answer 1

我建议你这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/MainDoc">
    <!-- first-pass -->
    <xsl:variable name="numbers">
        <xsl:for-each select="node1/node2/Amount">
            <num>
                <xsl:value-of select="translate(., ',', '.')"/>
            </num>
        </xsl:for-each>
    </xsl:variable>
    <!-- output -->
    <total>
        <xsl:value-of select="format-number(sum(exsl:node-set($numbers)/num), '0.00')"/>
    </total>
</xsl:template>

</xsl:stylesheet>

应用于您的示例，结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<total>5.79</total>

请注意，结果使用小数点，而不是小数点逗号。如果需要，可以通过更改format-number()。

使用的格式来更改此设置

Answer 2

您可以使用递归模板执行此操作，而无需使用扩展名调用：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes" />
  <xsl:template match="/">
    <xsl:call-template name="addAmount" />
  </xsl:template>
  <xsl:template name="addAmount">
    <xsl:param name="index" select="1" />
    <xsl:param name="lastVal" select="0" />
    <xsl:param name="total" select="count(//node2/Amount)" />

    <xsl:variable name="newTotal" select="number(translate(//node2[$index]/Amount, ',','.')) + $lastVal" />
    <xsl:if test="not($index = $total)">
      <xsl:call-template name="addAmount">
         <xsl:with-param name="index" select="$index + 1" />
         <xsl:with-param name="lastVal" select="$newTotal" />
      </xsl:call-template>
    </xsl:if>

    <xsl:if test="$index = $total">
      <xsl:value-of select="$newTotal" />
    </xsl:if>

    </xsl:template>
  <xsl:template match="text()" />
</xsl:stylesheet>

输出：

5.789999999999999

如果你需要这个四舍五入，那么你可以为那个最后一部分做<xsl:value-of select="round($newTotal * 100) div 100" />之类的事情。

XSLT 1.0如何使用sum（）使用逗号对值求和 - 在xpath

2 个答案: