Question

我有以下XML文档：

<nodes>
    <node>  
        <type>A</type>  
        <val>1,000</val>  
    </node>  
    <node>  
        <type>B</type>  
        <val>2,000</val>  
    </node>  
    <node>  
        <type>A</type>  
        <val>3,000</val>  
    </node>  
</nodes>

我的目标是获取唯一类型的列表并汇总其所有<val>。我得到以下输出：

<nodes>  
    <node>  
        <type>A</type>  
        <sum>3</sum>  
    </node>  
    <node>  
        <type>B</type>  
        <sum>2</sum>  
    </node>  
</nodes>

我期待一个总和（对于A型）4000，但我得到了3。

这是我的xslt：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">  
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>  
    <xsl:key name="type" match="/nodes/node/type/text()" use="." />
    <xsl:template match="/">
        <nodes>
            <xsl:for-each select="/nodes/node/type/text()[generate-id()=generate-id(key('type',.)[1])]">
                <node>
                    <xsl:variable name="t" select="."/>
                    <type><xsl:value-of select="$t"/></type>
                    <sum>
                       <xsl:value-of select="sum(/nodes/node[type=$t]/val)"/>
                    </sum>
                </node>
            </xsl:for-each>
        </nodes>
    </xsl:template>
</xsl:stylesheet>

关于如何使用sum（）在逗号中对值进行求和的任何想法？

Answer 1

此转化：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kType" match="type" use="."/>

 <xsl:variable name="vrtfPass1">
  <xsl:apply-templates select="/*"/>
 </xsl:variable>

 <xsl:variable name="vPass1" select="ext:node-set($vrtfPass1)"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:apply-templates mode="pass2" select=
   "$vPass1/*/*/type[generate-id()=generate-id(key('kType',.)[1])]"/>
 </xsl:template>

 <xsl:template match="val/text()[true()]">
  <xsl:value-of select="translate(., translate(.,'01234567890', ''), '')"/>
 </xsl:template>

 <xsl:template match="type" mode="pass2">
  <type><xsl:value-of select="."/></type>
  <sum><xsl:value-of select="sum(key('kType',.)/../val)"/></sum>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时：

<nodes>
    <node>
        <type>A</type>
        <val>1,000</val>
    </node>
    <node>
        <type>B</type>
        <val>2,000</val>
    </node>
    <node>
        <type>A</type>
        <val>3,000</val>
    </node>
</nodes>

会产生想要的正确结果：

<type>A</type>
<sum>4000</sum>
<type>B</type>
<sum>2000</sum>

如何使用sum（）用逗号对值求和

1 个答案: