Question

我们正在使用Qt开发应用程序，在服务器中我们有genkin服务器用于自动构建和自动测试。我们希望有一个像vera ++这样的Coding-Convention测试工具。我们没有使用vera ++或其他工具的经验，但我们想要的是使用vera ++处理Qt项目（.pro）的每个文件。此外，是否可以将此工具集成到QtCreator中？

我在互联网上找不到任何东西。感谢。

Answer 1

解决方案

我在复合qmake项目中集成了vera ++，在项目的根目录中的文件.qmake.conf中添加了以下行：

defineReplace(absolute_paths) {
    result =
    for(path, ARGS) {
        result += $$absolute_path($$path, $$_PRO_FILE_PWD_)
    }
    return($$result)
}
equals(TEMPLATE, subdirs): prepareRecursiveTarget(vera++)
else {
    # We prefix the report file name with the project file base name to prevent name collisions.
    VERA_TARGET = $$basename(_PRO_FILE_).vera++.xml
    vera++.commands = vera++ --checkstyle-report $$VERA_TARGET --show-rule $$absolute_paths($$HEADERS) $$absolute_paths($$SOURCES)
    QMAKE_CLEAN += $$VERA_TARGET
}
QMAKE_EXTRA_TARGETS += vera++

这会添加一个递归的make target vera++，它处理每个非子目标子项目中的所有头文件和源文件。

要生成XML报告，请调用以下命令：

qmake
make qmake_all
make vera++

其他信息

.qmake.conf自动包含在所有子目录中的所有.pro文件中。

的qmake
- defineReplace()
- prepareRecursiveTarget()
vera++

将vera ++（或其他编码约定工具）与Qt / QtCreator集成

1 个答案:

解决方案

其他信息