我正在创建一个名为TriangleOS的操作系统，其中包含一些文件，如sysldr.sys，kernel.sys等。当我在VMWare上运行它时，我收到此错误：
删除磁盘或其他媒体。按任意键重新启动
我在Windows 10上进行编译。我使用partcopy来创建引导扇区。我打字：
partcopy.exe boot.asm 0 200 -f0
这是我的文件boot.asm：
bits 16
org 0
%include"Floppy16.inc"
start: jmp main
Print:
lodsb
or al, al
jz PrintDone
mov ah, 0eh
int 10h
jmp Print
PrintDone:
ret
main:
cli
mov ax, 0x07C0
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ax, 0x0000
mov ss, ax
mov sp, 0xFFFF
sti
mov si, msgLoading
call Print
LOAD_ROOT:
xor cx, cx
xor dx, dx
mov ax, 0x0020
mul WORD [bpbRootEntries]
div WORD [bpbBytesPerSector]
xchg ax, cx
mov al, BYTE [bpbNumberOfFATs]
mul WORD [bpbSectorsPerFAT]
add ax, WORD [bpbReservedSectors]
mov WORD [datasector], ax
add WORD [datasector], cx
mov bx, 0x0200
call ReadSectors
mov cx, WORD [bpbRootEntries]
mov di, 0x0200
.LOOP:
push cx
mov cx, 0x000B
mov si, ImageName
push di
rep cmpsb
pop di
je LOAD_FAT
pop cx
add di, 0x0020
loop .LOOP
jmp FAILURE
LOAD_FAT:
mov dx, WORD [di + 0x001A]
mov WORD [cluster], dx
xor ax, ax
mov al, BYTE [bpbNumberOfFATs]
mul WORD [bpbSectorsPerFAT]
mov cx, ax
mov ax, WORD [bpbReservedSectors]
mov bx, 0x0200
call ReadSectors
mov ax, 0x0050
mov es, ax
mov bx, 0x0000
push bx
LOAD_IMAGE:
mov ax, WORD [cluster]
pop bx
call ClusterLBA
xor cx, cx
mov cl, BYTE [bpbSectorsPerCluster]
call ReadSectors
push bx
mov ax, WORD [cluster]
mov cx, ax
mov dx, ax
shr dx, 0x0001
add cx, dx
mov bx, 0x0200
add bx, cx
mov dx, WORD [bx]
test ax, 0x0001
jnz .ODD_CLUSTER
.EVEN_CLUSTER:
and dx, 0000111111111111b
jmp .DONE
.ODD_CLUSTER:
shr dx, 0x0004
.DONE:
mov WORD [cluster], dx
cmp dx, 0x0FF0
jb LOAD_IMAGE
DONE:
mov si, msgCRLF
call Print
push WORD 0x0050
push WORD 0x0000
retf
FAILURE:
mov si, msgFailure
call Print
mov ah, 0x00
int 0x16
int 0x19
bootdevice db 0
ImageName: db "KRNLDR SYS"
msgLoading: db 0x0D, 0x0A, "Reading Kernel Loader", 0x00
msgCRLF: db 0x0D, 0x0A, 0x00
msgProgress: db ".", 0x00
msgFailure: db 0x0D, 0x0A, "Can't find Kernel Loader (krnldr.sys). Press Any Key to Reboot", 0x0D, 0x0A, 0x00
TIMES 510-($-$$) DB 0
DW 0xAA55
文件Floppy16.inc是文件驱动程序助手。这是代码：
%ifndef __FLOPPY16_INC_
%define __FLOPPY16_INC_
bits 16
bpbOEM db "TriangOS"
bpbBytesPerSector: DW 512
bpbSectorsPerCluster: DB 1
bpbReservedSectors: DW 1
bpbNumberOfFATs: DB 2
bpbRootEntries: DW 224
bpbTotalSectors: DW 2880
bpbMedia: DB 0xf0
bpbSectorsPerFAT: DW 9
bpbSectorsPerTrack: DW 18
bpbHeadsPerCylinder: DW 2
bpbHiddenSectors: DD 0
bpbTotalSectorsBig: DD 0
bsDriveNumber: DB 0
bsUnused: DB 0
bsExtBootSignature: DB 0x29
bsSerialNumber: DD 0xa0a1a2a3
bsVolumeLabel: DB "TOS FLOPPY "
bsFileSystem: DB "FAT12 "
datasector dw 0x0000
cluster dw 0x0000
absoluteSector db 0x00
absoluteHead db 0x00
absoluteTrack db 0x00
ClusterLBA:
sub ax, 0x0002
xor cx, cx
mov cl, BYTE [bpbSectorsPerCluster]
mul cx
add ax, WORD [datasector]
ret
LBACHS:
xor dx, dx
div WORD [bpbSectorsPerTrack]
inc dl
mov BYTE [absoluteSector], dl
xor dx, dx
div WORD [bpbHeadsPerCylinder]
mov BYTE [absoluteHead], dl
mov BYTE [absoluteTrack], al
ret
; CX=>Kolko sektori da procita
; AX=>Pocetni sektor
; ES:EBX=>Na koju mem. lokaciju da ga stavi
ReadSectors:
.MAIN
mov di, 0x0005
.SECTORLOOP
push ax
push bx
push cx
call LBACHS
mov ah, 0x02
mov al, 0x01
mov ch, BYTE [absoluteTrack]
mov cl, BYTE [absoluteSector]
mov dh, BYTE [absoluteHead]
mov dl, BYTE [bsDriveNumber]
int 0x13
jnc .SUCCESS
xor ax, ax
int 0x13
dec di
pop cx
pop bx
pop ax
jnz .SECTORLOOP
int 0x18
.SUCCESS
pop cx
pop bx
pop ax
add bx, WORD [bpbBytesPerSector]
inc ax
loop .MAIN
ret
%endif
我使用以下命令编译了引导扇区：
nasm.exe -f bin boot.asm -o boot.bin
项目真的很大。我做了这个，所以我不需要GRUB。我注意到我的十六进制编辑器在最后55。逆转是正常的吗？在我的代码中，正常0xAA55。为什么输出Remove disks or other media?如何解决此问题？有什么建议吗？
答案 0 :(得分：5)
在代码顶部执行此操作：
bits 16
org 0
%include"Floppy16.inc"
start: jmp main
%include"Floppy16.inc"会在文件floppy16.inc中插入所有内容，就好像它是boot.asm代码的一部分一样。问题是您的引导参数块（BPB）出现在任何代码之前，因此数据将逐字地作为代码执行，因为引导加载程序将从物理地址0x07c00开始执行。我想你应该这样做：
bits 16
org 0
start: jmp main
nop ; Place NOP so BPB starts at the 4th byte of binary file.
; relative(short) JMP is 2 bytes long. NOP acts as 1 byte padding.
%include"Floppy16.inc"
通过跳过文件floppy16.inc包含的BPB数据，可以避免将数据作为代码执行。
启动时，此输出：
删除磁盘或其他媒体。按任意键重新启动
建议系统中可能插入了一个磁盘但没有找到可启动媒体。
我觉得好奇的是你似乎从汇编程序代码生成二进制文件但是你使用这个命令：
partcopy.exe boot.asm 0 200 -f0
这会将汇编程序 source 代码放入软盘的前512个字节。您想将创建的二进制文件放在软盘上。我想你应该用过：
partcopy.exe boot.bin 0 200 -f0
文件boot.bin是从此命令创建的二进制文件：
nasm.exe -f bin boot.asm -o boot.bin
由于您将boot.asm复制到软盘的引导扇区中，扇区的最后2个字节将不包含单词0xAA55，因此不会被检测为可引导软盘。如果您的虚拟机上没有其他可启动媒体，则会出现有关删除媒体和重新启动的错误。
Fifoernik在评论中提到：
不相关但仍然......不要在奇怪的地址初始化你的堆栈指针！最好使用偶数地址mov sp，0xFFFE
在过去的几天里，我写了一篇Stackoverflow answer来讨论这个问题。我可能建议将 SP 设置为0x0000。如果在真正的8086处理器上运行，则与奇数字边界（如0xffff）对齐的堆栈将受到显着的性能影响。将 SP 设置为零是有效的，因为它是一个偶数地址，并且首先将一个字推入堆栈会先将 SP 减少2，然后再写入该值。推送的第一个单词是SS：0xfffe。
因为你的代码不会在386以下运行，因为你有：
mov fs, ax
mov gs, ax
fs和gs个寄存器。您的代码无法在真正的8086/8088/80188/80286处理器上运行。这可能是设计上的，但我觉得我应该提一下。
由于您使用的是lodsb等指令，因此应考虑设置方向标记。在你的情况下，你似乎依赖于向前移动，所以我建议我们在引导加载程序开头附近的CLD指令。您不能保证它将被正确设置。
您的代码似乎破坏了 DL 的内容。 BIOS将通过 DL 将启动驱动器传递给引导加载程序。您可以考虑保存它，以便它可以用于从引导的驱动器中读取扇区。您可能会考虑到这一点，但如果没有看到floppy16.inc