Question

我在C＃中定义了这个COM-Server接口：

[ComVisible(true)]
[InterfaceType(ComInterfaceType.InterfaceIsIUnknown)]
[Guid("58C77969-0E7D-3778-9999-B7716E4E1111")]
public interface IMyInterface    
{
    string MyName { get; }
}

此接口是在Delphi XE5程序中导入和实现的。

导入如下：

IMyInterface = interface(IUnknown)
  ['{58C77969-0E7D-3778-9999-B7716E4E1111}']
  function Get_MyName (out pRetVal: WideString): HResult; stdcall;
end;

这样的实现：

type
  TMyImpl = class(TInterfacedObject, IMyInterface)
  public
    function Get_MyName (out pRetVal: WideString): HResult; stdcall;    
 end;

 function TMyImpl.Get_MyName (out pRetVal: WideString): HResult;
 var
  s: string;
 begin
   s:=''; // empty!
   pRetVal:=s;
   result:=S_OK;
 end;

当我从c＃调用该服务器时：

var server = new Server();
string s = server.MyName;

然后s为NULL，而不是空字符串，例如。

我如何强制将空字符串作为空字符串在COM中传输，而不是通过编组替换为NULL？

Answer 1

Delphi将空字符串实现为nil指针（参见System._NewUnicodeString）。您可以手动分配空的COM兼容字符串：

function TMyImpl.Get_MyName(out pRetVal: WideString): HResult;
var
  BStr: TBstr;
begin
  BStr := SysAllocString('');
  if Assigned(BStr) then
  begin
    Pointer(pRetVal) := BStr;
    Result := S_OK;
  end
  else
    Result := E_FAIL;
end;

或者你可以创建一个辅助函数：

function EmptyWideString: WideString;
begin
  Pointer(Result) := SysAllocString('');
end;

Answer 2

在德尔福方面试试这个：

IMyInterface = interface(IUnknown)
  ['{58C77969-0E7D-3778-9999-B7716E4E1111}']
  function Get_MyName (out pRetVal: BSTR): HResult; stdcall;
end;

function TMyImpl.Get_MyName (out pRetVal: BSTR): HResult;
begin
  pRetVal := SysAllocString('');
  Result := S_OK;
end;

如果您希望处理SysAllocString失败的情况，那么您可以这样写：

function TMyImpl.Get_MyName (out pRetVal: BSTR): HResult;
begin
  pRetVal := SysAllocString('');
  Result := IfThen(Assigned(pRetVal), S_OK, E_FAIL);
end;

虽然我个人认为在检查SysAllocString('')的电话时检查错误是否合理。

我的猜测是，Delphi将空WideString编组为nil指针，而不是空BSTR。在我看来，这是一个缺陷。

COM服务器发送空字符串，该字符串转换为NULL指针

2 个答案: