结合memoization和尾递归

时间：2010-08-11 14:32:47

标签： f# functional-programming tail-recursion memoization

是否有可能以某种方式结合memoization和tail-recursion？我现在正在学习F＃并理解这两个概念，但似乎无法将它们结合起来。

假设我有以下memoize函数（来自Real-World Functional Programming）：

let memoize f = let cache = new Dictionary<_, _>()
                (fun x -> match cache.TryGetValue(x) with
                          | true, y -> y
                          | _       -> let v = f(x)
                                       cache.Add(x, v)
                                       v)

以及以下factorial函数：

let rec factorial(x) = if (x = 0) then 1 else x * factorial(x - 1)

记住factorial并不太难，并且使其尾递归也不是：

let rec memoizedFactorial =
  memoize (fun x -> if (x = 0) then 1 else x * memoizedFactorial(x - 1))

let tailRecursiveFactorial(x) =
  let rec factorialUtil(x, res) = if (x = 0)
                                  then res
                                  else let newRes = x * res
                                       factorialUtil(x - 1, newRes)
  factorialUtil(x, 1)

但是你能结合memoization和tail-recursion吗？我做了一些尝试，但似乎无法让它工作。或者这根本不可能？

5 个答案:

答案 0 :(得分：23)

与往常一样，continuation会产生一个优雅的尾调解决方案：

open System.Collections.Generic 

let cache = Dictionary<_,_>()  // TODO move inside 
let memoizedTRFactorial =
    let rec fac n k =  // must make tailcalls to k
        match cache.TryGetValue(n) with
        | true, r -> k r
        | _ -> 
            if n=0 then
                k 1
            else
                fac (n-1) (fun r1 ->
                    printfn "multiplying by %d" n  //***
                    let r = r1 * n
                    cache.Add(n,r)
                    k r)
    fun n -> fac n id

printfn "---"
let r = memoizedTRFactorial 4
printfn "%d" r
for KeyValue(k,v) in cache do
    printfn "%d: %d" k v

printfn "---"
let r2 = memoizedTRFactorial 5
printfn "%d" r2

printfn "---"

// comment out *** line, then run this
//let r3 = memoizedTRFactorial 100000
//printfn "%d" r3

有两种测试。首先，这个调用F（4）的演示按照你的意愿缓存F（4），F（3），F（2），F（1）。

然后，注释掉*** printf并取消注释最终测试（并在Release模式下编译）以显示它不是StackOverflow（它正确使用尾调用）。

也许我会概括出'memoize'并在'fib'上展示它......

修改

好的，这是下一步，我认为，将memoization与factorial分离：

open System.Collections.Generic 

let cache = Dictionary<_,_>()  // TODO move inside 
let memoize fGuts n =
    let rec newFunc n k =  // must make tailcalls to k
        match cache.TryGetValue(n) with
        | true, r -> k r
        | _ -> 
            fGuts n (fun r ->
                        cache.Add(n,r)
                        k r) newFunc
    newFunc n id 
let TRFactorialGuts n k memoGuts =
    if n=0 then
        k 1
    else
        memoGuts (n-1) (fun r1 ->
            printfn "multiplying by %d" n  //***
            let r = r1 * n
            k r) 

let memoizedTRFactorial = memoize TRFactorialGuts 

printfn "---"
let r = memoizedTRFactorial 4
printfn "%d" r
for KeyValue(k,v) in cache do
    printfn "%d: %d" k v

printfn "---"
let r2 = memoizedTRFactorial 5
printfn "%d" r2

printfn "---"

// comment out *** line, then run this
//let r3 = memoizedTRFactorial 100000
//printfn "%d" r3

修改

好的，这是一个似乎有效的完全通用版本。

open System.Collections.Generic 

let memoize fGuts =
    let cache = Dictionary<_,_>()
    let rec newFunc n k =  // must make tailcalls to k
        match cache.TryGetValue(n) with
        | true, r -> k r
        | _ -> 
            fGuts n (fun r ->
                        cache.Add(n,r)
                        k r) newFunc
    cache, (fun n -> newFunc n id)
let TRFactorialGuts n k memoGuts =
    if n=0 then
        k 1
    else
        memoGuts (n-1) (fun r1 ->
            printfn "multiplying by %d" n  //***
            let r = r1 * n
            k r) 

let facCache,memoizedTRFactorial = memoize TRFactorialGuts 

printfn "---"
let r = memoizedTRFactorial 4
printfn "%d" r
for KeyValue(k,v) in facCache do
    printfn "%d: %d" k v

printfn "---"
let r2 = memoizedTRFactorial 5
printfn "%d" r2

printfn "---"

// comment out *** line, then run this
//let r3 = memoizedTRFactorial 100000
//printfn "%d" r3

let TRFibGuts n k memoGuts =
    if n=0 || n=1 then
        k 1
    else
        memoGuts (n-1) (fun r1 ->
            memoGuts (n-2) (fun r2 ->
                printfn "adding %d+%d" r1 r2 //%%%
                let r = r1+r2
                k r)) 
let fibCache, memoizedTRFib = memoize TRFibGuts 
printfn "---"
let r5 = memoizedTRFib 4
printfn "%d" r5
for KeyValue(k,v) in fibCache do
    printfn "%d: %d" k v

printfn "---"
let r6 = memoizedTRFib 5
printfn "%d" r6

printfn "---"

// comment out %%% line, then run this
//let r7 = memoizedTRFib 100000
//printfn "%d" r7

答案 1 :(得分：15)

尾随递归函数的记忆困境当然是尾递归函数

let f x = 
   ......
   f x1

调用自身，不允许对递归调用的结果做任何事情，包括将其放入缓存中。整蛊;所以，我们能做些什么？

这里的关键见解是，由于递归函数不允许对递归调用的结果执行任何操作，因此递归调用的所有参数的结果都是相同的！因此，如果递归调用跟踪是这个

f x0 -> f x1 -> f x2 -> f x3 -> ... -> f xN -> res

然后对于x0，x1，...，xN中的所有x，f x的结果将是相同的，即res。因此，递归函数的最后一次调用（非递归调用）知道所有先前值的结果 - 它可以缓存它们。您唯一需要做的就是将访问值列表传递给它。以下是它可能寻找的因子：

let cache = Dictionary<_,_>()

let rec fact0 l ((n,res) as arg) = 
    let commitToCache r = 
        l |> List.iter  (fun a -> cache.Add(a,r))
    match cache.TryGetValue(arg) with
    |   true, cachedResult -> commitToCache cachedResult; cachedResult
    |   false, _ ->
            if n = 1 then
                commitToCache res
                cache.Add(arg, res)
                res
            else
                fact0 (arg::l) (n-1, n*res)

let fact n = fact0 [] (n,1)

但是等等！ Look - l fact0参数包含递归调用fact0的所有参数 - 就像堆栈在非尾递归版本中一样！这是完全正确的。通过将“堆栈帧列表”从堆栈移动到堆并将递归调用结果的“后处理”转换为遍历该数据结构，可以将任何非尾递归算法转换为尾递归算法。

实用主义说明：上面的因子示例说明了一种通用技术。这是非常无用的 - 对于阶乘函数来说，它足以缓存顶级fact n结果，因为特定n的fact n计算只能达到（n，res）的唯一系列fact0的参数对 - 如果（n，1）尚未缓存，那么将不会调用fact0对。

注意，在这个例子中，当我们从非尾递归阶乘到尾递归阶乘时，我们利用了乘法是关联和交换的事实 - 尾递归阶乘执行不同的乘法集而不是非乘法 - 尾递归的。

实际上，存在从非尾递归到尾递归算法的一般技术，其产生等效于tee的算法。这种技术被称为“连续传递变换”。走这条路线，你可以采用一个非尾递归的记忆因子，并通过几乎机械的转换得到一个尾递归的记忆因子。请参阅Brian的答案，了解此方法。

答案 2 :(得分：8)

我不确定是否有更简单的方法可以做到这一点，但一种方法是创建一个记忆y组合器：

let memoY f =
  let cache = Dictionary<_,_>()
  let rec fn x =
    match cache.TryGetValue(x) with
    | true,y -> y
    | _ -> let v = f fn x
           cache.Add(x,v)
           v
  fn

然后，您可以使用此组合子代替“let rec”，第一个参数表示递归调用的函数：

let tailRecFact =
  let factHelper fact (x, res) = 
    printfn "%i,%i" x res
    if x = 0 then res 
    else fact (x-1, x*res)
  let memoized = memoY factHelper
  fun x -> memoized (x,1)

修改

正如Mitya指出的那样，memoY不保留memoee的尾递归属性。这是一个修订的组合子，它使用异常和可变状态来记忆任何递归函数而不会溢出堆栈（即使原始函数本身不是尾递归！）：

let memoY f =
  let cache = Dictionary<_,_>()
  fun x ->
    let l = ResizeArray([x])
    while l.Count <> 0 do
      let v = l.[l.Count - 1]
      if cache.ContainsKey(v) then l.RemoveAt(l.Count - 1)
      else
        try
          cache.[v] <- f (fun x -> 
            if cache.ContainsKey(x) then cache.[x] 
            else 
              l.Add(x)
              failwith "Need to recurse") v
        with _ -> ()
    cache.[x]

不幸的是，插入每个递归调用的机制有点沉重，因此需要深度递归的非记忆输入的性能可能会有点慢。但是，与其他一些解决方案相比，这样做的好处是它需要对递归函数的自然表达进行相当小的更改：

let fib = memoY (fun fib n -> 
  printfn "%i" n; 
  if n <= 1 then n 
  else (fib (n-1)) + (fib (n-2)))

let _ = fib 5000

修改

我将稍微介绍一下这与其他解决方案的比较。这种技术利用了异常提供侧通道的事实：类型'a -> 'b的函数实际上不需要返回类型'b的值，而是可以通过异常退出。如果返回类型明确包含指示失败的附加值，则不需要使用异常。当然，为此目的，我们可以使用'b option作为函数的返回类型。这将导致以下记忆组合：

let memoO f =
  let cache = Dictionary<_,_>()
  fun x ->
    let l = ResizeArray([x])
    while l.Count <> 0 do
      let v = l.[l.Count - 1]
      if cache.ContainsKey v then l.RemoveAt(l.Count - 1)
      else
        match f(fun x -> if cache.ContainsKey x then Some(cache.[x]) else l.Add(x); None) v with
        | Some(r) -> cache.[v] <- r; 
        | None -> ()
    cache.[x]

以前，我们的记忆过程如下：

fun fib n -> 
  printfn "%i" n; 
  if n <= 1 then n 
  else (fib (n-1)) + (fib (n-2))
|> memoY

现在，我们需要纳入fib应该返回int option而不是int的事实。给定option类型的合适工作流程，可以写成如下：

fun fib n -> option {
  printfn "%i" n
  if n <= 1 then return n
  else
    let! x = fib (n-1)
    let! y = fib (n-2)
    return x + y
} |> memoO

但是，如果我们愿意更改第一个参数的返回类型（在这种情况下从int更改为int option），我们也可以一直使用并继续使用continuation相反，返回类型，如Brian的解决方案。以下是他定义的变体：

let memoC f =
  let cache = Dictionary<_,_>()
  let rec fn n k =
    match cache.TryGetValue(n) with
    | true, r -> k r
    | _ -> 
        f fn n (fun r ->
          cache.Add(n,r)
          k r)
  fun n -> fn n id

同样，如果我们有一个合适的计算表达式来构建CPS函数，我们可以像这样定义递归函数：

fun fib n -> cps {
  printfn "%i" n
  if n <= 1 then return n
  else
    let! x = fib (n-1)
    let! y = fib (n-2)
    return x + y
} |> memoC

这与Brian所做的完全相同，但我发现这里的语法更容易理解。为了完成这项工作，我们所需要的只有以下两个定义：

type CpsBuilder() =
  member this.Return x k = k x
  member this.Bind(m,f) k = m (fun a -> f a k)

let cps = CpsBuilder()

答案 3 :(得分：3)

我写了一个测试来形象化memoization。每个点都是一个递归调用。

......720 // factorial 6
......720 // factorial 6
.....120  // factorial 5

......720 // memoizedFactorial 6
720       // memoizedFactorial 6
120       // memoizedFactorial 5

......720 // tailRecFact 6
720       // tailRecFact 6
.....120  // tailRecFact 5

......720 // tailRecursiveMemoizedFactorial 6
720       // tailRecursiveMemoizedFactorial 6
.....120  // tailRecursiveMemoizedFactorial 5

kvb的解决方案返回相同的结果，就像这个函数一样直接记忆。

let tailRecursiveMemoizedFactorial = 
    memoize 
        (fun x ->
            let rec factorialUtil x res = 
                if x = 0 then 
                    res
                else 
                    printf "." 
                    let newRes = x * res
                    factorialUtil (x - 1) newRes

            factorialUtil x 1
        )

测试源代码。

open System.Collections.Generic

let memoize f = 
    let cache = new Dictionary<_, _>()
    (fun x -> 
        match cache.TryGetValue(x) with
        | true, y -> y
        | _ -> 
            let v = f(x)
            cache.Add(x, v)
            v)

let rec factorial(x) = 
    if (x = 0) then 
        1 
    else
        printf "." 
        x * factorial(x - 1)

let rec memoizedFactorial =
    memoize (
        fun x -> 
            if (x = 0) then 
                1 
            else 
                printf "."
                x * memoizedFactorial(x - 1))

let memoY f =
  let cache = Dictionary<_,_>()
  let rec fn x =
    match cache.TryGetValue(x) with
    | true,y -> y
    | _ -> let v = f fn x
           cache.Add(x,v)
           v
  fn

let tailRecFact =
  let factHelper fact (x, res) = 
    if x = 0 then 
        res 
    else
        printf "." 
        fact (x-1, x*res)
  let memoized = memoY factHelper
  fun x -> memoized (x,1)

let tailRecursiveMemoizedFactorial = 
    memoize 
        (fun x ->
            let rec factorialUtil x res = 
                if x = 0 then 
                    res
                else 
                    printf "." 
                    let newRes = x * res
                    factorialUtil (x - 1) newRes

            factorialUtil x 1
        )

factorial 6 |> printfn "%A"
factorial 6 |> printfn "%A"
factorial 5 |> printfn "%A\n"

memoizedFactorial 6 |> printfn "%A"
memoizedFactorial 6 |> printfn "%A"
memoizedFactorial 5 |> printfn "%A\n"

tailRecFact 6 |> printfn "%A"
tailRecFact 6 |> printfn "%A"
tailRecFact 5 |> printfn "%A\n"

tailRecursiveMemoizedFactorial 6 |> printfn "%A"
tailRecursiveMemoizedFactorial 6 |> printfn "%A"
tailRecursiveMemoizedFactorial 5 |> printfn "%A\n"

System.Console.ReadLine() |> ignore

答案 4 :(得分：0)

如果通过y的相互尾递归没有创建堆栈帧，这应该有效：

let rec y f x = f (y f) x

let memoize (d:System.Collections.Generic.Dictionary<_,_>) f n = 
   if d.ContainsKey n then d.[n] 
   else d.Add(n, f n);d.[n]

let rec factorialucps factorial' n cont = 
    if n = 0I then cont(1I) else factorial' (n-1I) (fun k -> cont (n*k))

let factorialdpcps  = 
    let d =  System.Collections.Generic.Dictionary<_, _>()
    fun n ->  y (factorialucps >> fun f n -> memoize d f n ) n id


factorialdpcps 15I //1307674368000
相关问题
最新问题