我有一堆DocBook XML文件，它们都被合并到一个DocBook文件中，以便转换成HTML。每个单独的文档都是一个参考页面（用于函数或类似的构造）。我使用分块的HTML生成，以便每个参考页面成为自己的HTML页面。
问题是：我想在每个页面上找到目录。但我不想要the table of contents for that page。我想要整个参考手册的完整TOC。
也就是说，从任何页面，我都希望能够通过使用TOC跳转到任何其他页面。我可以使用CSS样式将TOC粘贴在左侧（甚至隐藏它以供移动查看或其他）。
有一种明显的方法可以解决这个问题。我可以通过后处理脚本提取主TOC，并让脚本将其复制到每个输出HTML文档中。我正在寻找的是一种在DocBook XSL中运行的方法。
我希望结果看起来更像DocBook XSL's newer webhelp，但JavaScript参与度较低。
答案 0 :(得分：2)
有一种相对简单的方法可以实现，但我很确定你不能没有creating a DocBook XSL customization layer或只是直接修改已安装的（系统）样式表。
无论哪种方式，我认为您需要修改或覆盖的实际docbook-xsl模板名为make.toc，位于文件html/autotoc.xsl中的样式表分发中。
这是一个很大的模板 - 近百行 - 但你只需要对它进行一行修改：
--- /usr/share/xml/docbook/stylesheet/docbook-xsl/html/autotoc.xsl 2012-12-16 11:35:12.000000000 +0900
+++ /opt/workspace/autotoc.xsl 2015-12-26 09:19:36.000000000 +0900
@@ -28,7 +28,7 @@
</xsl:variable>
<xsl:template name="make.toc">
- <xsl:param name="toc-context" select="."/>
+ <xsl:param name="toc-context" select="/"/>
<xsl:param name="toc.title.p" select="true()"/>
<xsl:param name="nodes" select="/NOT-AN-ELEMENT"/>
也就是说，您需要将toc-context参数设置为“/”（而不是“.”）来调用该模板。
默认的“.”值告诉模板，在为块创建TOC时，它应该只查看它当前正在处理的任何元素的（子）内容（即，它的根）特别的块）;例如，如果它正在处理section，它只会查看section的子项。
但是，如果您将该值更改为“/”，那么您每次都要告诉模板（重新）查看源文档的整个内容。因此，如果您的文档是book，则每次都会为您提供整本书的整个TOC，或者您的文档是article，整篇文章等等。
所以我认为应该给你你想要的东西。
如果您决定只修改已安装的样式表，并且已从您使用的任何特定于操作系统的程序包管理器安装它们，则需要找到html/autotoc.xsl文件的安装位置。
在我的Debian Linux系统上，html/autotoc.xsl文件在这里：
/usr/share/xml/docbook/stylesheet/docbook-xsl/html/autotoc.xsl
在我的OS X系统上，从自制软件包安装，就在这里：
/usr/local/opt/docbook-xsl/docbook-xsl/html/autotoc.xsl
如果您决定改为create a customization layer，则需要将整个make.toc模板复制到自定义图层中（但toc-context参数更改为“/ “）。
答案 1 :(得分：1)
截至2019年7月6日使用docbook-xsl-1.79.2，当前接受的答案不足以使每个目录完整。
但是，以下XSL模板可以。关键的见解是逐步使用Oxygen XML编辑器的调试器，并注意到虽然toc-context正确设置为根元素，但nodes变量仍然是本地子集。
我取消了toc-context的更改。相反，我选择了root-nodes创建了一个新变量/，并编辑了make.toc模板以使用root-nodes而不是nodes.
现在将其放在我的自定义层中可使每个目录成为完整的目录。
<xsl:template name="make.toc">
<xsl:param name="toc-context" select="."/>
<xsl:param name="toc.title.p" select="true()"/>
<xsl:param name="nodes" select="/NOT-AN-ELEMENT"/>
<xsl:variable name="root-nodes" select="/"/>
<xsl:variable name="nodes.plus" select="$root-nodes | d:qandaset"/>
<xsl:variable name="toc.title">
<xsl:if test="$toc.title.p">
<xsl:choose>
<xsl:when test="$make.clean.html != 0">
<div class="toc-title">
<xsl:call-template name="gentext">
<xsl:with-param name="key">TableofContents</xsl:with-param>
</xsl:call-template>
</div>
</xsl:when>
<xsl:otherwise>
<p>
<strong>
<xsl:call-template name="gentext">
<xsl:with-param name="key">TableofContents</xsl:with-param>
</xsl:call-template>
</strong>
</p>
</xsl:otherwise>
</xsl:choose>
</xsl:if>
</xsl:variable>
<xsl:choose>
<xsl:when test="$manual.toc != ''">
<xsl:variable name="id">
<xsl:call-template name="object.id"/>
</xsl:variable>
<xsl:variable name="toc" select="document($manual.toc, .)"/>
<xsl:variable name="tocentry" select="$toc//d:tocentry[@linkend=$id]"/>
<xsl:if test="$tocentry and $tocentry/*">
<div class="toc">
<xsl:copy-of select="$toc.title"/>
<xsl:element name="{$toc.list.type}" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="toc.list.attributes">
<xsl:with-param name="toc-context" select="$toc-context"/>
<xsl:with-param name="toc.title.p" select="$toc.title.p"/>
<xsl:with-param name="nodes" select="$root-nodes"/>
</xsl:call-template>
<xsl:call-template name="manual-toc">
<xsl:with-param name="tocentry" select="$tocentry/*[1]"/>
</xsl:call-template>
</xsl:element>
</div>
</xsl:if>
</xsl:when>
<xsl:otherwise>
<xsl:choose>
<xsl:when test="$qanda.in.toc != 0">
<xsl:if test="$nodes.plus">
<div class="toc">
<xsl:copy-of select="$toc.title"/>
<xsl:element name="{$toc.list.type}" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="toc.list.attributes">
<xsl:with-param name="toc-context" select="$toc-context"/>
<xsl:with-param name="toc.title.p" select="$toc.title.p"/>
<xsl:with-param name="nodes" select="$root-nodes"/>
</xsl:call-template>
<xsl:apply-templates select="$nodes.plus" mode="toc">
<xsl:with-param name="toc-context" select="$toc-context"/>
</xsl:apply-templates>
</xsl:element>
</div>
</xsl:if>
</xsl:when>
<xsl:otherwise>
<xsl:if test="$root-nodes">
<div class="toc">
<xsl:copy-of select="$toc.title"/>
<xsl:element name="{$toc.list.type}" namespace="http://www.w3.org/1999/xhtml">
<xsl:call-template name="toc.list.attributes">
<xsl:with-param name="toc-context" select="$toc-context"/>
<xsl:with-param name="toc.title.p" select="$toc.title.p"/>
<xsl:with-param name="nodes" select="$root-nodes"/>
</xsl:call-template>
<xsl:apply-templates select="$root-nodes" mode="toc">
<xsl:with-param name="toc-context" select="$toc-context"/>
</xsl:apply-templates>
</xsl:element>
</div>
</xsl:if>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
注意： 还有一个问题，不是每个分块页面都有自己的ToC，但这与特定页面无关。如果对它进行排序，我将添加有关其操作方式的评论。