我们的软件目前使用Direct3D9中的固定功能管道，为我们的用户提供了一种轻松编写脚本的方法，可以将灯光和对象投射到一个简单的场景中。我们允许定向，点和聚光灯。我试图将我们转移到Direct3D11，但我希望它尽可能接近Direct3D9固定功能管道作为基线。我们可以稍后添加像素的照片。我是着色器编码的新手，虽然我已经做了多年的C ++，但我觉得我的元素不合适。我想知道是否有支持DX11的着色器可以完美模拟DX9固定功能管道提供的照明。我已经在FixedFuncEMUFX11中看到了旧的点光模拟示例，我将尝试将其用作基础，但我只知道我没有尽可能高效地进行此操作，并且数学对于适当的聚光灯仿真是超出我的。是否有任何开源模拟固定功能管道，或者包含DirectX11 / 10的定向，点和点光实现？我认为我需要的只是.fx或.hlsl文件。即使它在8个光源处达到顶峰，也没关系。
我目前正在使用DirectXTK作为正确DirectX11编程的指南，但如果有更好的代码标准，我很想看到行业标准DirectX11渲染引擎编程方法的一个例子。感谢您提供任何建议。
答案 0 :(得分：2)
对于使用Direct3D 11的基本渲染，DirectX Tool Kit内置着色器基于XNA Game Studio 4，它提供了一组很好的基本功能，包括定向照明和每像素照明。它们旨在与所有Direct3D Feature Level硬件配合使用，因此它们不会实现像聚光灯这样的东西，可以通过更现代的硬件轻松完成。
FixedFuncEMU11 示例是旧版DirectX SDK的 FixedFuncEMU Direct3D 10示例的Direct3D 11端口。着色器对于理解各种Direct3D 9特定的固定功能管道很有用，但不包括在HLSL中实现标准照明模型等“标准”内容。另请注意，此示例使用Effects system for Direct3D 11，own issues。this article。不过，这对于看到它很有用：
您可能想尝试一些旧的Direct3D 9时代介绍HLSL着色器编程。虽然与Direct3D 11不是100％兼容，但它们非常接近，而且HLSL本身基本相同。我找到了例如Book Recommendations。
还有一些优秀的Direct3D 11书籍，所有这些都涵盖了HLSL着色器，因为Direct3D 11中没有固定功能管道。请参阅http://plnkr.co/edit/5TAvWpZ3l9ntKpJCJZAA了解一些细节和注释，因为其中一些书是在DirectX SDK已停用。特别是，你应该看看Varcholik的使用DirectX和HLSL实时3D渲染，因为它主要关注HLSL创作。
答案 1 :(得分：1)
对于那些通过在hlsl中搜索固定功能管道仿真而来到这里的人来说，这几乎就是我想要的：http://www.3dgep.com/texturing-lighting-directx-11/那里的着色器没有非常优化，但为了清晰起见并且是初学者对hlsl的一个很好的介绍。为了准确了解正在发生的事情以及让场景运行的最低限度，只需要很少的额外过滤。聚光灯并不是DX9的FFP聚光灯的精确复制，但它很容易被修改成为这样。
#define MAX_LIGHTS 8
// Light types.
#define DIRECTIONAL_LIGHT 0
#define POINT_LIGHT 1
#define SPOT_LIGHT 2
Texture2D Texture : register(t0);
sampler Sampler : register(s0);
struct _Material
{
float4 Emissive; // 16 bytes
//----------------------------------- (16 byte boundary)
float4 Ambient; // 16 bytes
//------------------------------------(16 byte boundary)
float4 Diffuse; // 16 bytes
//----------------------------------- (16 byte boundary)
float4 Specular; // 16 bytes
//----------------------------------- (16 byte boundary)
float SpecularPower; // 4 bytes
bool UseTexture; // 4 bytes
float2 Padding; // 8 bytes
//----------------------------------- (16 byte boundary)
}; // Total: // 80 bytes ( 5 * 16 )
cbuffer MaterialProperties : register(b0)
{
_Material Material;
};
struct Light
{
float4 Position; // 16 bytes
//----------------------------------- (16 byte boundary)
float4 Direction; // 16 bytes
//----------------------------------- (16 byte boundary)
float4 Color; // 16 bytes
//----------------------------------- (16 byte boundary)
float SpotAngle; // 4 bytes
float ConstantAttenuation; // 4 bytes
float LinearAttenuation; // 4 bytes
float QuadraticAttenuation; // 4 bytes
//----------------------------------- (16 byte boundary)
int LightType; // 4 bytes
bool Enabled; // 4 bytes
int2 Padding; // 8 bytes
//----------------------------------- (16 byte boundary)
}; // Total: // 80 bytes (5 * 16 byte boundary)
cbuffer LightProperties : register(b1)
{
float4 EyePosition; // 16 bytes
//----------------------------------- (16 byte boundary)
float4 GlobalAmbient; // 16 bytes
//----------------------------------- (16 byte boundary)
Light Lights[MAX_LIGHTS]; // 80 * 8 = 640 bytes
}; // Total: // 672 bytes (42 * 16 byte boundary)
float4 DoDiffuse( Light light, float3 L, float3 N )
{
float NdotL = max( 0, dot( N, L ) );
return light.Color * NdotL;
}
float4 DoSpecular( Light light, float3 V, float3 L, float3 N )
{
// Phong lighting.
float3 R = normalize( reflect( -L, N ) );
float RdotV = max( 0, dot( R, V ) );
// Blinn-Phong lighting
float3 H = normalize( L + V );
float NdotH = max( 0, dot( N, H ) );
return light.Color * pow( RdotV, Material.SpecularPower );
}
float DoAttenuation( Light light, float d )
{
return 1.0f / ( light.ConstantAttenuation + light.LinearAttenuation * d + light.QuadraticAttenuation * d * d );
}
struct LightingResult
{
float4 Diffuse;
float4 Specular;
};
LightingResult DoPointLight( Light light, float3 V, float4 P, float3 N )
{
LightingResult result;
float3 L = ( light.Position - P ).xyz;
float distance = length(L);
L = L / distance;
float attenuation = DoAttenuation( light, distance );
result.Diffuse = DoDiffuse( light, L, N ) * attenuation;
result.Specular = DoSpecular( light, V, L, N ) * attenuation;
return result;
}
LightingResult DoDirectionalLight( Light light, float3 V, float4 P, float3 N )
{
LightingResult result;
float3 L = -light.Direction.xyz;
result.Diffuse = DoDiffuse( light, L, N );
result.Specular = DoSpecular( light, V, L, N );
return result;
}
float DoSpotCone( Light light, float3 L )
{
float spotMinAngle = cos( light.SpotAngle );
float spotMaxAngle = ( spotMinAngle + 1.0f ) / 2.0f;
float cosAngle = dot( light.Direction.xyz, L );
return smoothstep( spotMinAngle, spotMaxAngle, cosAngle );
}
LightingResult DoSpotLight( Light light, float3 V, float4 P, float3 N )
{
LightingResult result;
float3 L = ( light.Position - P ).xyz;
float distance = length(L);
L = L / distance;
float attenuation = DoAttenuation( light, distance );
float spotIntensity = DoSpotCone( light, -L );
result.Diffuse = DoDiffuse( light, L, N ) * attenuation * spotIntensity;
result.Specular = DoSpecular( light, V, L, N ) * attenuation * spotIntensity;
return result;
}
LightingResult ComputeLighting( float4 P, float3 N )
{
float3 V = normalize( EyePosition - P ).xyz;
LightingResult totalResult = { {0, 0, 0, 0}, {0, 0, 0, 0} };
[unroll]
for( int i = 0; i < MAX_LIGHTS; ++i )
{
LightingResult result = { {0, 0, 0, 0}, {0, 0, 0, 0} };
if ( !Lights[i].Enabled ) continue;
switch( Lights[i].LightType )
{
case DIRECTIONAL_LIGHT:
{
result = DoDirectionalLight( Lights[i], V, P, N );
}
break;
case POINT_LIGHT:
{
result = DoPointLight( Lights[i], V, P, N );
}
break;
case SPOT_LIGHT:
{
result = DoSpotLight( Lights[i], V, P, N );
}
break;
}
totalResult.Diffuse += result.Diffuse;
totalResult.Specular += result.Specular;
}
totalResult.Diffuse = saturate(totalResult.Diffuse);
totalResult.Specular = saturate(totalResult.Specular);
return totalResult;
}
struct PixelShaderInput
{
float4 PositionWS : TEXCOORD1;
float3 NormalWS : TEXCOORD2;
float2 TexCoord : TEXCOORD0;
};
float4 TexturedLitPixelShader( PixelShaderInput IN ) : SV_TARGET
{
LightingResult lit = ComputeLighting( IN.PositionWS, normalize(IN.NormalWS) );
float4 emissive = Material.Emissive;
float4 ambient = Material.Ambient * GlobalAmbient;
float4 diffuse = Material.Diffuse * lit.Diffuse;
float4 specular = Material.Specular * lit.Specular;
float4 texColor = { 1, 1, 1, 1 };
if ( Material.UseTexture )
{
texColor = Texture.Sample( Sampler, IN.TexCoord );
}
float4 finalColor = ( emissive + ambient + diffuse + specular ) * texColor;
return finalColor;
}