Question

我正在建模一个系统，该系统具有创建资源的操作以及使用该资源的其他操作。但是，给定的资源只能被使用一次 - 有没有一种方法可以保证在编译时？

为了具体，我们可以说第一次操作是一个蛋糕，还有另外两个操作，一个用于＆＃34;选择吃＆＃34;蛋糕和一个选择蛋糕的蛋糕＆＃34;并且我只能做其中一个。

-- This is my current "weakly typed" interface:
bake :: IO Cake
eat  :: Cake -> IO ()
keep :: Cake -> IO ()

-- This is OK
do
  brownie <- bake
  muffin <- bake
  eat brownie
  keep muffin

-- Eating and having the same cake is not OK:
do
  brownie <- bake
  eat brownie
  keep brownie -- oops! already eaten!

通过在我们使用它之后在蛋糕上设置标志，很容易强制执行限制，即不在运行时保留已经吃过的蛋糕（反之亦然）。但有没有办法在编译时强制执行此操作？

顺便说一句，这个问题是为了概念验证，所以我可以使用任何可以给我静电安全的黑魔法。

Answer 1

在Haskell中，这个的基本版本可以用GADT表示，该GADT由一组蛋糕索引（由Nat - s列表表示）：

{-# LANGUAGE
  TypeFamilies, GADTs, TypeOperators, PartialTypeSignatures,
  DataKinds, PolyKinds #-}

import GHC.TypeLits
import Data.Proxy
import GHC.Exts

-- Allocate a new cake
type family New cs where
  New '[]       = 0
  New (c ': cs) = c + 1

-- Constraint satisfiable if "c" is in "cs"
type family Elem c cs :: Constraint where
  Elem c (c ': cs)  = ()
  Elem c (c' ': cs) = Elem c cs

type family Remove c cs where
  Remove c '[]        = '[]  
  Remove c (c ': cs)  = cs
  Remove c (c' ': cs) = c' ': Remove c cs

data Bake :: [Nat] -> [Nat] -> * -> * where
  Pure :: a -> Bake cs cs a
  Bake :: (Proxy (New cs) -> Bake (New cs ': cs) cs' a) -> Bake cs cs' a
  Eat  :: Elem c cs => Proxy c -> Bake (Remove c cs) cs' a -> Bake cs cs' a
  Keep :: Elem c cs => Proxy c -> Bake cs cs' a -> Bake cs cs' a

ok :: Bake '[] _ _
ok =
  Bake $ \cake1 ->
  Bake $ \cake2 ->
  Eat cake1 $
  Keep cake2 $
  Eat cake2 $
  Pure ()

not_ok :: Bake '[] _ _
not_ok =
  Bake $ \cake1 ->
  Bake $ \cake2 ->
  Eat cake1 $
  Keep cake1 $ -- we already ate that
  Eat cake2 $
  Pure ()

不幸的是，我们无法从Bake操作中删除类型注释并留下要推断的类型：

foo =
  Bake $ \cake1 ->
  Bake $ \cake2 ->
  Eat cake1 $
  Pure ()

-- Error: Could not deduce (Elem (New cs0) (New cs0 + 1 : New cs0 : cs0))

显然，(Elem (New cs0) (New cs0 + 1 : New cs0 : cs0))对所有cs0都是可以满足的，但GHC无法看到这一点，因为它无法确定New cs0是否等于New cs0 + 1，因为GHC可以不假设灵活的cs0变量。

如果我们添加NoMonomorphismRestriction，foo会进行类型检查，但通过将所有Elem约束推到顶部，这甚至会导致错误的程序类型检查。这仍然会阻止对不正确的术语做任何有用的事情，但这是一个相当丑陋的解决方案。

更一般地说，我们可以将Bake表达为索引的免费monad，它会使我们do - 使用RebindableSyntax的符号，并允许BakeF的定义比我们以前见过的更清楚。它也可以像普通的Free monad一样减少样板，尽管我发现在实际代码中人们不太可能在两个不同的场合找到索引的免费monad。

{-# LANGUAGE
  TypeFamilies, GADTs, TypeOperators, PartialTypeSignatures, StandaloneDeriving,
  DataKinds, PolyKinds, NoImplicitPrelude, RebindableSyntax, DeriveFunctor #-}

import Prelude hiding (Monad(..))
import GHC.TypeLits
import Data.Proxy
import GHC.Exts

class IxFunctor f where
  imap :: (a -> b) -> f i j a -> f i j b

class IxFunctor m => IxMonad m where
  return :: a -> m i i a
  (>>=)  :: m i j a -> (a -> m j k b) -> m i k b
  fail   :: String -> m i j a

infixl 1 >>
infixl 1 >>=

(>>) :: IxMonad m => m i j a -> m j k b -> m i k b
ma >> mb = ma >>= const mb

data IxFree f i j a where
  Pure :: a -> IxFree f i i a
  Free :: f i j (IxFree f j k a) -> IxFree f i k a

liftf :: IxFunctor f => f i j a -> IxFree f i j a
liftf = Free . imap Pure

instance IxFunctor f => IxFunctor (IxFree f) where
  imap f (Pure a)  = Pure (f a)
  imap f (Free fa) = Free (imap (imap f) fa)

instance IxFunctor f => IxMonad (IxFree f) where
  return = Pure
  Pure a  >>= f = f a
  Free fa >>= f = Free (imap (>>= f) fa)
  fail = error

-- Old stuff for Bake

type family New cs where
  New '[]       = 0
  New (c ': cs) = c + 1

type family Elem c cs :: Constraint where
  Elem c (c ': cs)  = ()
  Elem c (c' ': cs) = Elem c cs

type family Remove c cs where
  Remove c '[]        = '[]  
  Remove c (c ': cs)  = cs
  Remove c (c' ': cs) = c' ': Remove c cs

-- Now the return type indices of BakeF directly express the change
-- from the old store to the new store.
data BakeF cs cs' k where
  BakeF :: (Proxy (New cs) -> k) -> BakeF cs (New cs ': cs) k
  EatF  :: Elem c cs => Proxy c -> k -> BakeF cs (Remove c cs) k
  KeepF :: Elem c cs => Proxy c -> k -> BakeF cs cs k

deriving instance Functor (BakeF cs cs')
instance IxFunctor BakeF where imap = fmap

type Bake = IxFree BakeF

bake   = liftf (BakeF id)
eat  c = liftf (EatF c ())
keep c = liftf (KeepF c ())

ok :: Bake '[] _ _
ok = do
  cake1 <- bake
  cake2 <- bake
  eat cake1
  keep cake2
  eat cake2

-- not_ok :: Bake '[] _ _
-- not_ok = do
--   cake1 <- bake
--   cake2 <- bake
--   eat cake1
--   keep cake1 -- already ate it
--   eat cake2

Answer 2

Polakow在他的Haskell研讨会论文Embedding a full linear lambda calculus in Haskell (pdf)中展示了如何做到这一点。

主要思想是使用输入和输出上下文为每个构造函数编制索引，以跟踪各个子项中消耗的资源。

Answer 3

部分解决方案。我们可以定义一个包装类型

data Caked a = Caked { getCacked :: IO a } -- ^ internal constructor

我们不导出构造函数/访问器。

它将有两个几乎但不是非常类似的绑定函数：

beforeCake :: IO a -> (a -> Caked b) -> Caked b
beforeCake a f = Caked (a >>= getCaked . f)

afterCake :: Caked a -> (a -> IO b) -> Caked b
afterCake (Caked a) f = Caked (a >>= f)

客户创建Caked值的唯一方法是：

eat :: Cake -> Caked ()
eat = undefined

keep :: Cake -> Caked ()
keep = undefined

我们会在回调中分配Cake个值：

withCake :: (Cake -> Caked b) -> IO b
withCake = undefined

我认为，这可确保eat和keep仅在回调中被调用一次。

问题：多个Cake分配不起作用，Cake值仍然可以逃避回调的范围（幻象类型有帮助吗？）

有没有办法在Haskell中模拟线性类型？

3 个答案: