AS3动态更改对象的图像

Question

如何更改已创建对象的图像
让我们说我有一个名为Icon的空类，在运行时我希望将其图像更改为某些内容并将其添加到舞台上。图像可以作为另一个对象来自库，也可以只是一个位图。

var icon1 = new Icon(myIcon);
...

public class Icon extends MovieClip {
public function Icon(icon:Class) {
    //change image
    addChild(this);
}

编辑：在java中我曾经这样做过：

new Icon(myIcon);
...

public class Icon {

public Image image;
public String icon;

public Icon(String icon) {

        ImageIcon ii = new ImageIcon(this.getClass().getResource(icon + ".png"));
        image = ii.getImage();
        this.icon = icon;
    }

并且在paint方法上我只需键入icon1.image即可在屏幕上显示，如果需要，还可以通过访问此变量来更改图像。

这可以在as3上做到这样吗？

Answer 1

  

假设我有一个名为Icon的空类，并且在运行时我想要   将其形象改为某种东西

在代码之前，请确保按照以下示例步骤准备...

1）打开库（ctrl + L）并右键单击以选择MovieClip类型的“创建新符号”，并将其命名为图标，然后查看高级标签位于下方......

2）勾选名为“Export For ActionScript”的框，该框应自动填充一个名为 Class 的框，文字说明图标。单击“确定”即可。

3）将一个或两个图像添加到库中，然后右键单击以选择“属性”，再次像链接部分中的步骤（2）一样，勾选“导出为AS”选项并给出您希望稍后通过代码键入的名称。我们假设您选择了 Pic1 和 Pic2 等名称。另请注意，这些位图的“基类”是 bitmapData ？这是您为了按代码更新图像而更改的数据。

因此，要通过代码动态更新...使用库中的任何 bitmapData 创建位图并更新其像素数据。类似的东西：

//# in your imports...
import flash.display.MovieClip;
import flash.display.Bitmap;    
import flash.display.BitmapData;
import flash.utils.getQualifiedClassName;
import flash.utils.*;

....

//# in vars declarations...
public var my_icon : Icon = new Icon ();
public var my_BMP : Bitmap;
public var str_Type : String = ""; //later holds library object type for checks

....

//# later in your code
stage.addChild(my_icon); //looks invisible since empty

my_BMP = new Bitmap; //create new instance
my_icon.addChild ( my_BMP ); //add the empty bitmap into Icon

change_Icon ( Pic1 ); //parameter can be Library's Bitmap or Movieclip 

制作change_Icon功能......

如果您只保留位图（PNG文件？），您可以使用这样的简单函数......

public function change_Icon ( in_Param : Class ) : void
{
    my_BMP.bitmapData = new in_Param as BitmapData; //replace pixels of existing bitmap container
}

但是既然你说它可能是任何东西，有时候是Bitmap或者有时是MovieClip，那么在这种情况下你必须检查输入并相应地处理。

public function change_Icon ( in_Param : * ) : void
{
    //# Check the input type and handle it 
    str_Type = String ( getDefinitionByName( String( getQualifiedSuperclassName(in_Param) ) ) );

    if ( str_Type == "[class BitmapData]" )
    {
        trace ( "this object is a Bitmap..." );
        my_BMP.bitmapData = new in_Param as BitmapData; //replace pixels of existing bitmap container
    }

    if ( str_Type == "[class MovieClip]" )
    {
        trace ( "this object is a Movieclip..." );

        var temp_MC = new in_Param();
        var temp_BMD : BitmapData = new BitmapData( temp_MC.width, temp_MC.height );

        my_BMP.bitmapData = temp_BMD; //assign data to this bitmap
        temp_BMD.draw (temp_MC); //update by drawing
    }

}

Answer 2

将图标（图像文件）添加到库后，将它们转换为MovieClip并像这样设置其AS链接，例如：

例如，您可以使用Sprite对象在Icon类实例中加载图标，其中Icon类可以是这样的，例如：

package  {

    import flash.display.Sprite;

    public class Icon extends Sprite 
    {
        private var _icon:Sprite;

        public function Icon(IconClass:Class): void
        {
            _icon = new IconClass();
            addChild(_icon);
        }

        public function changeIcon(IconClass:Class): void 
        {
            removeChild(_icon);
            _icon = new IconClass();
            addChild(_icon);
        }

    }

}

然后在主代码中，您可以使用该类：

import Icon;

var icon:Icon = new Icon(PHPIcon);
addChild(icon);

然后要更改图标，您只需调用changeIcon()函数：

icon.changeIcon(JSIcon).

修改：

如果您不想调用addChild()将Icon类的实例添加到其父容器中，则Icon类的构造函数可以是这样的，例如：

public function Icon(container:DisplayObjectContainer, IconClass:Class): void
{
    container.addChild(this);
    _icon = new IconClass();
    addChild(_icon);
}

然后是它的实例

var icon:Icon = new Icon(this, PHPIcon);

希望可以提供帮助。

Answer 3

最后，谢谢我有一个基类来处理未来的项目，我也使用list所以我所要做的就是调用new Icon(myIcon, x, y, this);

package  {

    import flash.display.Sprite;
    import flash.display.DisplayObjectContainer;

    public class Icon extends Sprite {
        public static var list:Array = new Array();
        private var icon:Sprite;
        private var n:int;

        public function Icon(IconClass:Class, x:int, y:int, container:DisplayObjectContainer):void {
            container.addChild(this);
            icon = new IconClass();
            n = list.push(this);
            addChild(icon);
            this.x = x; this.y = y;
        }
        public function changeIcon(IconClass:Class):void {
            removeChild(icon);
            icon = new IconClass();
            addChild(icon);
        }
        public function removeIcon():void {
            this.parent.removeChild(this);
            list.splice(n-1,1);
        }
    }
}