以下是Stata格式的销售交易数据集。每一行都是
的销售某个城市的所有商店都没有销售部分产品。对于所有产品，我想以某一周的百分比计算该城市的市场供应量。例如，如果产品A在第1周出售，在城市所有不同商店的一半（可用商店的数量从一周到一周不等），新列将表明市场可用性为50％所有这些观察（计数）。对于不同的示例，在第1周的以下示例数据集中，我想要的变量market_availability看起来像这样（暂时忽略unit_sold列）：
week store SKU city units_sold mkt_avail
1 200059 01182007 C 5 1
1 200060 01182007 C 4 1
1 200061 01182007 C 4 1
1 200060 01182090 C 6 0.66
1 200059 01182090 C 4 0.66
1 200061 01182888 C 1 0.33
2 200059 01182007 K 4 1
2 200060 01182007 K 1 1
2 200061 01182007 K 4 1
2 200059 01182090 K 8 0.66
2 200060 01182090 K 9 0.66
2 200061 01182888 K 4 0.33
这是Stata表：
clear
set more off
input str5 week str8 store str30 SKU units_sold str1 city
1 200059 01182007 5 C
1 200059 01182090 4 C
1 200060 01182007 4 C
1 200060 01182090 6 C
1 200061 01182007 4 C
1 200061 01182888 1 C
2 200059 01182007 4 K
2 200060 01182007 1 K
2 200061 01182007 4 K
2 200059 01182090 8 K
2 200060 01182090 9 K
2 200061 01182888 4 K
end
问题在于，在此交易数据集中，由于重复购买，同一周的商店城市SKU组合可能会出现多次;但我们不想在计算股票时考虑重复观察，因为我们已经知道当时有特定项目可用。
我首先按星期和城市标记独特的观察结果
egen tag = tag(week city)
我也试试
egen tag1 = tag(store SKU)
现在，我应该尝试将它们一起匹配吗？
从逻辑上讲，我认为我首先需要总结不同的城市/周/商店/ SKU数量;那么我需要计算一下这个城市/周的商店数量，如果SKU曾经为这个组合出售过。然后将第一个数字除以第二个数字。有什么想法吗？
答案 0 :(得分：2)
你的策略似乎很好。您可以用两种方式标记不同的（不是“唯一的”）观察，然后通过除以总计来计算分数。这可以在没有任何文件编排的情况下完成。这里的假设是没有观察记录零销售。但如果有，那么在if units_sold计算中添加tag()就足以忽略它们。
. clear
. set more off
. input str5 week str8 store str30 SKU units_sold str1 city
week store SKU units_s~d city
1. 1 200059 01182007 5 C
2. 1 200059 01182090 4 C
3. 1 200060 01182007 4 C
4. 1 200060 01182090 6 C
5. 1 200061 01182007 4 C
6. 1 200061 01182888 1 C
7. 2 200059 01182007 4 K
8. 2 200060 01182007 1 K
9. 2 200061 01182007 4 K
10. 2 200059 01182090 8 K
11. 2 200060 01182090 9 K
12. 2 200061 01182888 4 K
13. end
. egen tag = tag(city week store SKU)
. egen stores_selling_product = total(tag), by(city week SKU)
. egen tag2 = tag(city week store)
. egen stores_in_city = total(tag2), by(city week)
. gen fraction = stores_sell/stores_in
. sort week SKU store
. l week store SKU city stores* fraction , sepby(week)
+------------------------------------------------------------------+
| week store SKU city stores~t stores~y fraction |
|------------------------------------------------------------------|
1. | 1 200059 01182007 C 3 3 1 |
2. | 1 200060 01182007 C 3 3 1 |
3. | 1 200061 01182007 C 3 3 1 |
4. | 1 200059 01182090 C 2 3 .6666667 |
5. | 1 200060 01182090 C 2 3 .6666667 |
6. | 1 200061 01182888 C 1 3 .3333333 |
|------------------------------------------------------------------|
7. | 2 200059 01182007 K 3 3 1 |
8. | 2 200060 01182007 K 3 3 1 |
9. | 2 200061 01182007 K 3 3 1 |
10. | 2 200059 01182090 K 2 3 .6666667 |
11. | 2 200060 01182090 K 2 3 .6666667 |
12. | 2 200061 01182888 K 1 3 .3333333 |
+------------------------------------------------------------------+
关于Stata上下文中 distinct 和 unique 的术语，更重要的是对此领域的技术进行审核，请参阅this paper。
答案 1 :(得分：1)
我认为这个解决方案并不是最好的，但可以按照您的意愿行事：
save original,replace // keeping your original dataset
collapse (count)has_sold=units_sold if units_sold>0, by(week store SKU city) // make binary flag for counting
replace has_sold=1 // force binary flag
save tmp,replace // preserving current status
bysort week store: keep if _n==1
egen numStoreWeekly = count(has_sold), by(week) // get total number of stores in week regardless city
drop SKU has_sold // dropping temporary variables
merge m:m week store city using tmp // adding numStoreWeekly to tmp.dta ("merge m:m" was used to assign same numStoreWeekly to same week/store/city combination)
egen numStoreSold = count(has_sold), by(week city SKU) // counting stores sold by week city SKU
gen mkt_avail = numStoreSold/numStoreWeekly
drop numStoreSold numStoreWeekly _merge has_sold // dropping temporary variables
merge m:m week store city SKU using original // merging back (adding mkt_avail to original.dta )
drop _merge
sort week city SKU store