Question

我正在尝试编译此代码：https://github.com/RanaExMachina/ada-fuse

不幸的是，在构建时我收到此错误：

fuse-system.ads:147:04: size clause not allowed for variable length type

这似乎是一个问题，因为在代码中它尝试设置具有泛型类型作为条目的记录的大小。这似乎是一个新的错误，因为开发人员在2。5年前撰写时没有遇到过这个问题。不幸的是，他无法在短时间内帮助我，但我必须让那个图书馆继续。然而，我对解决这个问题有点无奈。

基本上在我看来，我必须以某种方式告诉gnat这种类型有多大，这与gnat相信 - 是先验可知的：它是一种访问类型。在record或泛型类型定义中。

相关部分是：

fuse-main.ads:
  package Fuse.Main is
    package IO is
      new Ada.Direct_IO (Element_Type);
    type File_Access is access IO.File_Type;

fuse-system.ads:
  generic
    type File_Access is private;
  package Fuse.System is
  ...
    type File_Info_Type is record
      Flags       : Flags_Type;
      Fh_Old      : Interfaces.C.unsigned_long;
      Writepage   : Interfaces.C.int;
      Direct_IO   : Boolean := True;
      Keep_Cache  : Boolean := True;
      Flush       : Boolean := True;
      Nonseekable : Boolean := True;
      Fh          : File_Access;
      Lock_Owner  : Interfaces.Unsigned_64;
    end record;
  type File_Info_Access is access File_Info_Type;
  pragma Convention (C, File_Info_Type);
  for File_Info_Type'Size use 32*8;

我的gnat版本是：4.9.2-1（debian jessie）

Answer 1

您知道File_Access是一种访问类型，但在Fuse.System内，编译器没有;所有它知道的是它是明确的并且支持任务和平等。实际可能是几百个字节。

告诉编译器是一种访问类型，请尝试这样的事情（为了方便起见，我将它压缩到一个软件包中，在Mac OS X上，因此64位指针大小;它编译OK）：

with Ada.Text_IO;
package Fuse_Tests is

   generic
      type File_Type is limited private;
      type File_Access is access File_Type;
   package Fuse_System is
      type File_Info_Type is record
         Fh : File_Access;
      end record;
      for File_Info_Type'Size use 64;
   end Fuse_System;

   type File_Access is access Ada.Text_IO.File_Type;

   package My_Fuse_System is new Fuse_System
     (File_Type   => Ada.Text_IO.File_Type,
      File_Access => File_Access);

end Fuse_Tests;

或者，评论中建议的替代方案：

with Ada.Text_IO;
package Fuse_Tests is

   generic
      type File_Type;
   package Fuse_System is
      type File_Access is access File_Type;
      type File_Info_Type is record
         Fh : File_Access;
      end record;
      for File_Info_Type'Size use 64;
   end Fuse_System;

   package My_Fuse_System is new Fuse_System
     (File_Type => Ada.Text_IO.File_Type);

   --  if needed ...
   subtype File_Access is My_Fuse_System.File_Access;

end Fuse_Tests;

如何在Ada中使泛型类型的大小显式化？

1 个答案: