Question

我目前在实时编程语言的大学课程中学习Ada，并对泛型有疑问。

我有一个通用程序csv_put

package PSU_Logging is

   type logged_signal_names_t is (
      t,
      U_V1,
      I_L1,
      U_C1,
      I_L2,
      U_C2,
      I_Load
   );

private
   ... Some types, tasks and subprogramms ...

   generic
      type Item_Type_t is private;
      procedure csv_put (File : in File_Type; Item : in Item_Type_t);

end PSU_Logging;

带有定义

package body PSU_Logging is

   procedure csv_put (File : in File_Type; Item : in Item_Type_t) is
   begin
      Put (File, Item_Type_t'Image (Item));
      Put (File, ", ");
   end csv_put;

   procedure csv_put_float is new csv_put (Item_Type_t => Float);
   procedure csv_put_duration is new csv_put (Item_Type_t => Duration);
   procedure csv_put_signal_name is new csv_put (Item_Type_t => logged_signal_names_t);

   ... Definition of other things ...

end PSU_Logging;

到目前为止一切顺利。太糟糕了，我在编译期间遇到以下错误

Compile
   [Ada]          psu_logging.adb
      psu_logging.adb:9:18: prefix of "image" attribute must be a scalar type or a scalar object name
gprbuild: *** compilation phase failed

有什么想法吗？我以为我可以在通用过程中使用泛型类型，就像任何其他类型一样。由于我的所有实例都使用标量类型，我认为这应该不是问题。

顺便问一下：你最喜欢的Ada教程/参考是什么？我喜欢Ada上的Wikibooks页面，但它还没有完成。

Answer 1

可能的workround（原谅我的资本重组，这是我的编辑器的设置方式）：提供Image作为通用参数，

generic
   type Item_Type_T is private;
   with function Image (Item : Item_Type_T) return String;
procedure Csv_Put (File : in File_Type; Item : in Item_Type_T);

procedure Csv_Put (File : in File_Type; Item : in Item_Type_T) is
begin
   Put (File, Image (Item));
   Put (File, ", ");
end Csv_Put;

并使用’Image进行实例化，如果可用，则使用其他方式：

procedure Csv_Put_Float is new Csv_Put (Item_Type_T => Float,
                                        Image => Float'Image);

Answer 2

除了询问如何执行此操作之外，您还似乎想知道它为何如此工作。通用正式类型

type Item_Type_T is private;

可以使用具有赋值和＆＃34; =＆＃34;的任何实际类型进行实例化。这涵盖了各种类型，并非所有类型都是标量。对于所有可能的实际类型，通用必须是合法的。由于＆＃39; Image对于某些可能的实际类型不合法，因此您无法在通用中将此类型用于此类型。

Ada通用类型图像属性

2 个答案: