Question

我的轮廓图运行得很好，它为不同的值生成相同数量的颜色。

我想要的是在右侧生成标签以使每个块具有正确的颜色。

目前的结果：

我想要的是在每个块上都有这个值：

---- 300

---- 100

---- 70

---- 30

---- 10

---- 1

---- 0

编辑：当我添加此代码时：

set cbtics ('300' 300, '100' 100, '30' 30, '10' 10, '1' 1, '0.5' 0.5, '0.1' 0.1, '0.01' 0.01, '0' 0);
set palette defined (0.1 "#4CAF4F",0.3 "#65B443",0.5 "#7FBA38",0.7 "#98BF2D",0.9 "#B2C521",1.0 "#CBCA16",2 "#E5D00B",3 "#FFD600",4 "#FFC400",5 "#FFB300",6 "#FFA100",7 "#FF9000",8 "#FF7E00",10 "#FF6D00",30 "#F85A00",50 "#F14800",70 "#EA3600",90 "#E32400",100 "#DC1200",300 "#D50000")

结果是不均匀：

我希望刻度是均匀的，但无法实现。

Answer 1

我建议您将输出从0到300的比例重新缩放到颜色条上手动定义的标签之间线性变化的比例：

rescale(x) = ( x >= 0. && x < 1. ? x : \
               x >= 1. && x < 10. ? 1.+(x-1.)/(10.-1.) : \
               x >= 10. && x < 30. ? 2.+(x-10.)/(30.-10.) : \
               x >= 30. && x < 70. ? 3.+(x-30.)/(70.-30.) : \
               x >= 70. && x < 100. ? 4.+(x-70.)/(100.-70.) : \
               x >= 100. && x < 300. ? 5.+(x-100.)/(300.-100.) : \
               1/0)
set cbrange [0:6]
set cbtics ("0" 0, "1" 1, "10" 2, "30" 3, "70" 4, "100" 5, "300" 6)
set pm3d
splot rescale(x**2+y**2)

如果要将每个块的颜色限制为一个，请添加以下行：

set palette maxcolors 6

最后，请注意，如果您有地图，标签就足够了。如果您有3D绘图，您可能还想重新标记z轴：

set ztics ("0" 0, "1" 1, "10" 2, "30" 3, "70" 4, "100" 5, "300" 6)

在Gnuplot中自定义颜色范围

1 个答案: