gnuplot 4.0中的点颜色

Question

当我尝试使用gnuplot绘制三个单独的数据文件时，我收到错误“';'当我尝试更改数据集的点颜色时，“在输出中”。

例如，这很好用：

set terminal jpeg size 900,500
set xlabel 'x axis label'
set ylabel 'y axis label'
set title 'sample title'
set output "output.jpeg"
set xrange [-0.1:1.1]
set yrange [] reverse
set xtics 0.10
#set ytics 100
set key top left
set grid ytics lt 0 lw 1
set grid xtics lt 0 lw 1

plot 'file1.dat' u 1:2 w p pt 7 ps 0.8 ti 'dataset 1', \
     'file2.dat' u 1:2 w p pt 6 ps 0.8 ti 'dataset 2', \
     'file3.dat' u 1:2 w p pt 5 ps 0.8 ti 'dataset 3'

这不是：

set terminal jpeg size 900,500
set xlabel 'x axis label'
set ylabel 'y axis label'
set title 'sample title'
set output "output.jpeg"
set xrange [-0.1:1.1]
set yrange [] reverse
set xtics 0.10
#set ytics 100
set key top left
set grid ytics lt 0 lw 1
set grid xtics lt 0 lw 1

plot 'file1.dat' u 1:2 w p pt 7 ps 0.8 lc 9 ti 'dataset 1', \
     'file2.dat' u 1:2 w p pt 6 ps 0.8 ti 'dataset 2', \
     'file3.dat' u 1:2 w p pt 5 ps 0.8 ti 'dataset 3'

这是为什么？有没有一种解决方法可以简单地改变点颜色而不受点样式和尺寸的影响？

谢谢！

Answer 1

关键字linecolor（lc）是在4.2版中引入的。在您的情况下，您可以使用linetype（lt）更改颜色：

set terminal jpeg size 900,500
set output "output.jpeg"
plot 'file1.dat' u 1:2 w p pt 7 ps 0.8 lt 9 ti 'dataset 1'

但我也强烈建议你升级！