Question

Arduino Uno
- ENC28J60
- EtherCard.h

我正在尝试编译并运行此示例。但是我收到了这个错误。

“退出状态1”单词homePage（）'被声明为'extern'以及之后 'static'[-fpermissive]“

TSample1

代码或库有问题吗？该示例是从网上复制的。图书馆已更新。

你可以帮我解决这个问题。如何解决？

Answer 1

似乎函数homePage是在没有storafe类说明符static的头文件中声明的。

然而，它是使用存储类说明符static

定义的

static word homePage() { 
//...

并且编译器报告了这种不一致。

我认为您可以删除函数定义中的存储类说明符static。

另一种方法是在标题之前放置一个带有存储类说明符static的函数声明。在这种情况下，该函数将具有内部链接。

Answer 2

arduino gui使用的工具的变化可能比以前更不容忍，并且库已更新。

看起来您的图书馆已经过时了，在github repo中搜索主页只会显示3个文件，所有这些都是示例。

https://github.com/jcw/ethercard/search?utf8=%E2%9C%93&q=homepage

我建议从https://github.com/jcw/ethercard更新。

Answer 3

请查看我提供的代码。它与Jean-Claude Wipper's Github page提供的草图完全相同，除了我总是必须向“ ether.begin ”功能提供芯片选择引脚，否则我的ENC28J60赢了不回应。

// Present a "Will be back soon web page", as stand-in webserver.
// 2011-01-30 <jc@wippler.nl> http://opensource.org/licenses/mit-license.php
// Connection Diagram: http://i.stack.imgur.com/SvG7J.jpg

#include <EtherCard.h>

#define STATIC 1  // set to 1 to disable DHCP (adjust myip/gwip values below)
#define CS_PIN 10

#if STATIC
// ethernet interface ip address
static byte myip[] = { 192,168,1,200 };
// gateway ip address
static byte gwip[] = { 192,168,1,1 };
#endif

// ethernet mac address - must be unique on your network
static byte mymac[] = { 0x74,0x69,0x69,0x2D,0x30,0x31 };

byte Ethernet::buffer[500]; // tcp/ip send and receive buffer

const char page[] PROGMEM =
"HTTP/1.0 503 Service Unavailable\r\n"
"Content-Type: text/html\r\n"
"Retry-After: 600\r\n"
"\r\n"
"<html>"
  "<head><title>"
    "Service Temporarily Unavailable"
  "</title></head>"
  "<body>"
    "<h3>This service is currently unavailable</h3>"
    "<p><em>"
      "The main server is currently off-line.<br />"
      "Please try again later."
    "</em></p>"
  "</body>"
"</html>"
;

void setup(){
  Serial.begin(9600);
  Serial.println("\n[backSoon]");

  if (ether.begin(sizeof Ethernet::buffer, mymac, CS_PIN) == 0) 
    Serial.println( "Failed to access Ethernet controller");
#if STATIC
  ether.staticSetup(myip, gwip);
#else
  if (!ether.dhcpSetup())
    Serial.println("DHCP failed");
#endif

  ether.printIp("IP:  ", ether.myip);
  ether.printIp("GW:  ", ether.gwip);  
  ether.printIp("DNS: ", ether.dnsip);  
}

void loop(){
  // wait for an incoming TCP packet, but ignore its contents
  if (ether.packetLoop(ether.packetReceive())) {
    memcpy_P(ether.tcpOffset(), page, sizeof page);
    ether.httpServerReply(sizeof page - 1);
  }
}

下载：Arduino EtherCard Library

基本任务
在上传草图之前，首先需要使用LAN电缆将ENC28J60模块连接到PC，或者也可以连接到路由器。现在主要部分来了。变量“ gwip ”必须与您的网关IP地址匹配。

如果您已连接电脑，请找到您的电脑＆gt;以太网的IP地址可能看起来像“169.254.x.x”：
如果您已连接到路由器，请将路由器的IP放入“gwip”。

获得Gateway IP后，将其写入“gwip”变量并上传草图：）

Arduino - ENC28J60 - EtherCard.h - 编译错误 - 'word homePage（）'被声明为'extern'，后来被称为'static'[-fpermissive]

3 个答案: