Question

我在制作一个准电子商务网站时正在为大学做一个作业（所以我不熟悉XSL编码），并且会尽可能多地提供详细信息，这样才有意义。

示例XML数据：

<Items>
  <Item>
    <ItemID>50001</ItemID>
    <ItemName>Samsung Galaxy S4</ItemName>
    <ItemPrice>629</ItemPrice>
    <ItemQty>14</ItemQty>
    <ItemDesc>4G Mobile</ItemDesc>
    <QtyHold>0</QtyHold>
    <QtySold>1</QtySold>
  </Item>
  <Item>
    <ItemID>50002</ItemID>
    <ItemName>Samsung Galaxy S5</ItemName>
    <ItemPrice>779</ItemPrice>
    <ItemQty>21</ItemQty>
    <ItemDesc>4G Mobile</ItemDesc>
    <QtyHold>0</QtyHold>
    <QtySold>1</QtySold>
  </Item>
</Items>

Website

因此，当一个人点击顶部表中的“添加到购物车”时，过程就是，XML中ItemQty的ItemQty减少1，而XML中的QtyHold则增加1。（QtyHold表示已添加到购物车的内容。因此，如果QtyHold> 0，则将其添加到购物车中）

我的问题是指第二个表（下面的代码），其中总数也适用 - 仅在处理1个项目时。因此，如果第二次添加项目编号'50001'，则总计不会改变。

<xsl:template match="/">
    <fieldset>
    <legend>Shopping Cart</legend>
    <BR />
    <table border="1" id="CartTable" align="center">
    <tr><th>Item Number</th>
    <th>Price</th>
    <th>Quantity</th>
    <th>Remove</th></tr> 
    <xsl:for-each select="/Items/Item[QtyHold > 0]">
        <tr><td><xsl:value-of select="ItemID"/></td>
        <td>$<xsl:value-of select="ItemPrice"/></td>
        <td><xsl:value-of select="QtyHold"/></td>
        <td><button onclick="addtoCart({ItemID}, 'Remove')">Remove from Cart</button></td> </tr>
    </xsl:for-each>
    <tr><td ALIGN="center" COLSPAN="3">Total:</td><td>$<xsl:value-of select="sum(//Item[QtyHold >0]/ItemPrice)"/></td></tr>
    </table>
    <BR />
    <button onclick="Purchase()" class="submit_btn float_l">Confirm Purchase</button>
    <button onclick="CancelOrder()" class="submit_btn float_r">Cancel Order</button>
    </fieldset>
</xsl:template>
</xsl:stylesheet>

所以需要发生的是在下面的代码中，同时检查QtyHold是否大于0（这意味着它在购物车中）＆amp;总结这些值，它还需要乘以QtyHold＆amp; ITEMPRICE。

<xsl:value-of select="sum(//Item[QtyHold >0]/ItemPrice)"/>

我尝试了下面的代码的许多变体......但似乎无法使任何工作。

select="sum(//Item[QtyHold >0]/ItemPrice)/(QtyHold*ItemPrice"/>

Answer 1

如果您使用的是XSLT 2.0，那么您可以使用的表达式为：

<xsl:value-of select="sum(//Item[QtyHold >0]/(ItemPrice * QtyHold))"/>

但是，在XSLT 1.0中是不允许的。相反，您可以使用扩展功能获得所需的结果。特别是“node-set”功能。首先，您将创建一个这样的变量，在其中构建包含每个项目总数的新节点

<xsl:variable name="itemTotals">
     <xsl:for-each select="//Item[QtyHold >0]">
          <total>
              <xsl:value-of select="ItemPrice * QtyHold" />
          </total>
     </xsl:for-each>
</xsl:variable>

理想情况下，您希望执行sum($itemTotals/total)，但这不起作用，因为itemTotals是“结果树片段”，sum函数只接受节点集。所以你使用节点集扩展函数来转换它。首先在XSLT中声明这个命名空间......

 xmlns:exsl="http://exslt.org/common"

然后，你的sum函数看起来像这样：

 <xsl:value-of select="sum(exsl:node-set($itemTotals)/total)"/>

或者，如果您甚至无法使用扩展功能，则可以使用“follow-sibling”方法，一次选择每个Item，并保持运行总计。所以，你会得到一个这样的模板：

<xsl:template match="Item" mode="sum">
    <xsl:param name="runningTotal" select="0" />

    <xsl:variable name="newTotal" select="$runningTotal + ItemPrice * QtyHold" />
    <xsl:variable name="nextItem" select="following-sibling::Item[1]" />
    <xsl:choose>
        <xsl:when test="$nextItem">
            <xsl:apply-templates select="$nextItem" mode="sum">
                <xsl:with-param name="runningTotal" select="$newTotal" />
            </xsl:apply-templates>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$newTotal" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

要调用它，要获得总和，您只需从选择第一个节点

开始

<xsl:apply-templates select="(//Item)[1]" mode="sum" />

试试这个展示各种方法的XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
               xmlns:exsl="http://exslt.org/common"
               exclude-result-prefixes="exsl">

    <xsl:output method="html" indent="yes" />

    <xsl:template match="/">
        <table border="1" id="CartTable" align="center">
        <tr><th>Item Number</th>
        <th>Price</th>
        <th>Quantity</th>
        </tr> 
        <xsl:for-each select="/Items/Item[QtyHold > 0]">
            <tr>
                <td><xsl:value-of select="ItemID"/></td>
                 <td>$<xsl:value-of select="ItemPrice"/></td>
                <td><xsl:value-of select="QtyHold"/></td>
            </tr>
        </xsl:for-each>
        <tr>
            <td ALIGN="center" COLSPAN="2">Total:</td>
            <xsl:variable name="itemTotals">
                <xsl:for-each select="//Item[QtyHold >0]">
                    <total>
                        <xsl:value-of select="ItemPrice * QtyHold" />
                    </total>
                </xsl:for-each>
            </xsl:variable>
            <td>
                <!-- XSLT 2.0 only: $<xsl:value-of select="sum(//Item[QtyHold >0]/(ItemPrice * QtyHold))"/>-->
                $<xsl:value-of select="sum(exsl:node-set($itemTotals)/total)"/>
                $<xsl:apply-templates select="(//Item)[1]" mode="sum" />
            </td>
        </tr>
        </table>
</xsl:template>

<xsl:template match="Item" mode="sum">
    <xsl:param name="runningTotal" select="0" />

    <xsl:variable name="newTotal" select="$runningTotal + ItemPrice * QtyHold" />
    <xsl:variable name="nextItem" select="following-sibling::Item[1]" />
    <xsl:choose>
        <xsl:when test="$nextItem">
            <xsl:apply-templates select="$nextItem" mode="sum">
                <xsl:with-param name="runningTotal" select="$newTotal" />
            </xsl:apply-templates>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$newTotal" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
</xsl:stylesheet>

最后想一想，为什么不向XML中的每个Total元素添加一个新的Item元素。最初，它将设置为0，如QtyHold。然后，当您将QtyHold增加1时，通过您执行的任何处理，您还可以将Total增加ItemPrice中的数量。这样，您可以将此Total节点求和以获得总计，而无需扩展函数或递归模板。

XSL，SUM＆amp;与条件相乘

1 个答案: