Question

我正在尝试删除节点但是在祖先节点中注入内容。这是xml：

    <w lemma="comment2" type="adv." ana="comment">comment</w>
<name ref="roland"><w lemma="roland" type="nom propre" ana="roland">roland</w></name>
<w lemma="faire" type="vindps3" ana="fyt"><choice><orig>fyt</orig><reg>fist</reg></choice></w>
<name ref="yvon de montauban"><w lemma="yvon" type="nom propre" ana="yvon">yvon</w>
<w lemma="de" type="prép" ana="de">de</w>

我希望完整删除<reg>及其内容，删除标记<choice>并删除标记<orig>但是将其内容放入<w>标记。有人可以帮帮我吗？

xslt现在是这样的：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">
    <xsl:output method="xml"/>
    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:for-each select="./@*">
                <xsl:attribute name="{local-name()}">
                    <xsl:value-of select="."/>
                </xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="div">
        <xsl:element name="{local-name()}">
            <xsl:for-each select="./@*">
                <xsl:attribute name="{local-name()}">
                    <xsl:value-of select="."/>
                </xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="s">
        <xsl:element name="{local-name()}">
            <xsl:for-each select="./@*">
                <xsl:attribute name="{local-name()}">
                    <xsl:value-of select="."/>
                </xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="name">
        <xsl:element name="{local-name()}">
            <xsl:for-each select="./@*">
                <xsl:attribute name="{local-name()}">
                    <xsl:value-of select="."/>
                </xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="pb">
        <xsl:choose>
            <xsl:when test="@ed='bnf'">
                <xsl:element name="{local-name()}">
                    <xsl:for-each select="./@*">
                        <xsl:attribute name="{local-name()}">
                            <xsl:value-of select="."/>
                        </xsl:attribute>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                </xsl:element>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="w">
        <xsl:choose>
            <xsl:when test="descendant::orig">
                <xsl:element name="w">
                    <xsl:for-each select="./@*">
                        <xsl:attribute name="{local-name()}">
                            <xsl:value-of select="."/>
                        </xsl:attribute>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                </xsl:element>
            </xsl:when>
            <xsl:when test="descendant::reg">
                    <xsl:apply-templates/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:element name="w">
                    <xsl:for-each select="./@*">
                        <xsl:attribute name="{local-name()}">
                            <xsl:value-of select="."/>
                        </xsl:attribute>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                </xsl:element>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="choice"/>
    <xsl:template match="orig">
        <xsl:apply-templates select="*" />
        <xsl:apply-templates/>
    </xsl:template>
    <xsl:template match="reg"/> 
</xsl:stylesheet>

谢谢你的帮助:) 米莎

Answer 1

给出格式良好的 XML输入：

<root>
  <w lemma="comment2" type="adv." ana="comment">comment</w>
  <name ref="roland">
    <w lemma="roland" type="nom propre" ana="roland">roland</w>
  </name>
  <w lemma="faire" type="vindps3" ana="fyt">
    <choice>
      <orig>fyt</orig>
      <reg>fist</reg>
    </choice>
  </w>
  <name ref="yvon de montauban">
    <w lemma="yvon" type="nom propre" ana="yvon">yvon</w>
    <w lemma="de" type="prép" ana="de">de</w>
  </name>
</root>

以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="choice|orig">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="reg"/>

</xsl:stylesheet>

将返回：

<?xml version="1.0" encoding="UTF-8"?>
<root>
   <w lemma="comment2" type="adv." ana="comment">comment</w>
   <name ref="roland">
      <w lemma="roland" type="nom propre" ana="roland">roland</w>
   </name>
   <w lemma="faire" type="vindps3" ana="fyt">fyt</w>
   <name ref="yvon de montauban">
      <w lemma="yvon" type="nom propre" ana="yvon">yvon</w>
      <w lemma="de" type="pr√©p" ana="de">de</w>
   </name>
</root>

注意：

choice包装已被删除;
orig的内容已成为祖先w的内容节点;
整个reg节点已被禁止。

Answer 2

我知道这不是一个答案，但它不能在评论栏中格式化。

你的XSLT代码可以改进得那么多！例如，而不是

<xsl:template match="w">
        <xsl:choose>
            <xsl:when test="descendant::orig">
                <xsl:element name="w">
                    <xsl:for-each select="./@*">
                        <xsl:attribute name="{local-name()}">
                            <xsl:value-of select="."/>
                        </xsl:attribute>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                </xsl:element>
            </xsl:when>

你可以写

<xsl:template match="w[.//orig]">
  <w>
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </w>
</xsl:template>

XSLT删除节点但保留内容

2 个答案: