Question

我读了here如何在剪辑规则的lhs上调用python函数。

现在我有以下规则：

(defrule python_func_lhs "comment me"
    (object (is-a clips_TEST_CLASS) (some_slot ?some_slot_value))
    (test (eq (python-call python_print (str-cat "some_slot: " ?some_slot_value)) TRUE))
    =>
    ;(assert (do_something))
)

我的问题是python函数被调用两次，首先打印

some_slot：nil

然后

some_slot：some_slot_value

似乎包含python函数的第二个规则部分不会“等待”LHS规则的第一部分匹配。

一旦LHS规则的第一部分匹配，我怎样才能使剪辑调用python函数一次？换句话说，我想等到?some_slot_value变量有值。

如果可能的话，我想避免创建几个规则并使用“控制事实”。

Answer 1

不同的规则引擎具有指定对象更改何时完成的不同方法，但一般而言，当您对对象进行多个不同的更改时，将针对每个更改调用一次模式匹配过程。您在问题中包含了代码片段，而不是可重现的示例，所以我只能猜测问题的原因，但您可能正在做的是创建对象，然后在单独的步骤中对其进行修改。创建对象时模式匹配会延迟，直到处理完所有插槽覆盖，并且类似于进行对象修改时，您可以使用modify-instance函数将插槽更改的集合分组为一个更改。如果需要在多个函数调用之间延迟模式匹配，可以使用模式匹配延迟函数。

CLIPS> 
(defclass clips_TEST_CLASS
   (is-a USER)
   (slot some_slot))
CLIPS>    
(definstances initial
   (i1 of clips_TEST_CLASS (some_slot some_slot_value)))   
CLIPS> 
(deffunction pcall (?v) (printout t ?v crlf) TRUE)
CLIPS> 
(defrule python_func_lhs 
    (object (is-a clips_TEST_CLASS) (some_slot ?some_slot_value))
    (test (pcall (str-cat "some_slot: " ?some_slot_value)))
    =>)
CLIPS> (reset)
some_slot: some_slot_value
CLIPS> (make-instance i2 of clips_TEST_CLASS (some_slot some_other_value))
some_slot: some_other_value
[i2]
CLIPS> (make-instance i3 of clips_TEST_CLASS)
some_slot: nil
[i3]
CLIPS> (send [i3] put-some_slot another_value)
some_slot: another_value
another_value
CLIPS> 
(object-pattern-match-delay
   (make-instance i4 of clips_TEST_CLASS)
   (send [i4] put-some_slot still_another_value))
some_slot: still_another_value
still_another_value
CLIPS> (modify-instance [i4] (some_slot value))
some_slot: value
TRUE
CLIPS>

CLIPS规则的LHS中的Python函数多次调用 - 如何等待变量包含值？

1 个答案: