Question

这是我目前在GAMS上的代码。是的，我知道它可以更简洁，但请耐心等待我：

set activity /a*q/;

parameter duration (activity) "in days"
/a 15, b 4, c 5, d 10, e 4, f 15, g 15, h 5, i 5, j 10, k 4, l 3, m 4, n 20, o 5,
p 2, q 2/;

alias (activity, x, y);

set prec(x,y) "Precedence Order"

/A.(B,C,D)
(B,C,D).E
E.(F,G,H)
F.N
G.(K,I) 
H.I
K.M
I.J
J.L
L.M
M.N
N.O
O.P
P.Q/            ;

Free Variable
T Completion Time; 

Nonnegative Variables
A, B, C, D, E, F, G, H, I, J, K, L, M, N, O, P, Q;

equations
t_A, t_B, t_C, t_D, t_E, t_F, t_G, t_H, t_I, t_J, t_K, t_L, t_M, t_N, t_O, t_P,
t_Q, s_AB, s_AC, s_AD, s_BE, s_CE, s_DE, s_EF, s_EG, s_EH, s_FN, s_GK, s_GI,
s_HI, s_KM, s_IJ, s_JL, s_LM, s_MN, s_NO, s_OP, s_PQ;

t_A.. T =G= A + 15;
t_B.. T =G= B + 4;
t_C.. T =G= C + 5;
t_D.. T =G= D + 10;
t_E.. T =G= E + 4;
t_F.. T =G= F + 15;
t_G.. T =G= G + 15;
t_H.. T =G= H + 5;
t_I.. T =G= I + 5;
t_J.. T =G= J + 10;
t_K.. T =G= K + 4;
t_L.. T =G= L + 3;
t_M.. T =G= M + 4;
t_N.. T =G= N + 20;
t_O.. T =G= O + 5;
t_P.. T =G= P + 2;
t_Q.. T =G= Q + 10;

s_AB.. A + 15 =L= B;
s_AC.. A + 15 =L= C;
s_AD.. A + 15 =L= D;
s_BE.. B + 4 =L= E;
s_CE.. C + 5 =L= E;
s_DE.. D + 10 =L= E;
s_EF.. E + 4 =L= F;
s_EG.. E + 4 =L= G;
s_EH.. E + 4 =L= H;
s_FN.. F + 15 =L= N;
s_GK.. G + 15 =L= K;
s_GI.. G + 15 =L= I;
s_HI.. H + 5 =L= I;
s_KM.. K + 4 =L= M;
s_IJ.. I + 5 =L= J;
s_JL.. J + 10 =L= L;
s_LM.. L + 3 =L= M;
s_MN.. M + 4 =L= N;
s_NO.. N + 20 =L= O;
s_OP.. O + 5 =L= P;
s_PQ.. P + 2 =L= Q;

model thesis /all/;
solve thesis using lp minimizing t;
display t.l;

此代码为我提供了大量详细信息，例如我应该开始每项活动的日期。但是，它并没有告诉我（据我所知），哪些活动是关键路径。如何使用GAMS确定这一点？

Answer 1

如果依赖方程中的边际（公式中的s_AB等）为-1，则依赖关系位于关键路径上。您可以在列表（.lst）文件中或使用以下代码进行检查：

set activity /a*q/;

parameter duration (activity) "in days"
/a 15, b 4, c 5, d 10, e 4, f 15, g 15, h 5, i 5, j 10, k 4, l 3, m 4, n 20, o 5,
p 2, q 2/;

alias (activity, x, y);

set prec(x,y) "dependency Order"

/A.(B,C,D)
(B,C,D).E
E.(F,G,H)
F.N
G.(K,I) 
H.I
K.M
I.J
J.L
L.M
M.N
N.O
O.P
P.Q/;

Free Variable
T Completion Time; 

Nonnegative Variables
start(x);

equations
t_bound(x)
dependency(x,y);

t_bound(x).. T =G= start(x) + duration(x);

dependency(x,y)$prec(x,y).. start(x) + duration(x) =l= start(y);

model thesis /all/;
solve thesis using lp minimizing t;

set criticalpath(x,y);
criticalpath(x,y) = 1$(dependency.M(x,y) < 0);

display t.l, criticalpath;

Answer 2

据我所知，这是一个没有资源限制的项目调度问题。

在这种情况下，开始时间等于最早开始时间的活动和等于最近完成时间的结束时间都在关键路径上。

换句话说，关键活动没有松懈。

因此，您需要在获得解决方案后找到所有活动的最早开始时间和最晚完成时间。

如果您不知道如何操作，活动的最早开始时间等于其所有前任的最长完成时间。同样，活动的最后结束时间等于其所有继承人的最短开始时间。

希望这会有所帮助。

如何确定哪些项目在GAMS的关键路径上？

2 个答案: