Question

我试图将使用Jenkins Job DSL插件的代码分解为可重用的部分，我怀疑我的问题对Groovy是通用的，而不是Jenkins特有的。例如，我想重用此块的部分内容：

freeStyleJob() {
    //generic stuff
    name "something"
    description "something else"

    //custom stuff
    scm {
       svn {
           //etc....
       }
    }
}

通过在实用方法中放置名称和描述（显然我想做的不仅仅是在现实生活中）。但是，我找不到为当前范围创建闭包的正确语法。我认为这应该是这样的：

def jobCommonItems() {
    return {
        //generic stuff
        name "something"
        description "something else"
    }
}


freeStyleJob() {
    jobCommonItems().call()

    //custom stuff
    scm {
       svn {
           //etc....
       }
    }
}

（也许有一个closure.delegate =这个地方）

然而，这并不适合关闭。它适用于方法，如下所示：https://dzone.com/articles/groovy-closures-owner-delegate

为了说明，这里有一个测试，显示了三种可能的语法组合：

String myString = "Top Level: string"
def myMethod() {
    println "Top Level: Method"
}
def myClosure = { println "Top Level: Class"}

class MyClass1 {
    String myString = "Class1: String"
    def myMethod() {
        println "Class1: Method"
    }
    def myClosure = { println "Class1: Closure"}
}

class MyClass2 {
    String myString = "Class2: String"
    def myMethod() {
        println "Class2: Method"
    }
    def myClosure = { println "Class2: Closure"}
}

class MyClass {
    def closure = {
        println "In-Class generated closure begins, delegate is ${delegate}"
        myMethod()
        myClosure()
        println myString
    }
}

def closure = new MyClass().closure
closure.delegate = new MyClass1()
closure()

closure = new MyClass().closure
closure.delegate = new MyClass2()
closure()

// This fails - it can find the top level method, but not closure or string
closure.delegate = this
closure()



def methodMissing(String methodName, args) {
    println "Method not found in class ${this} by name ${methodName}"
}

我得到一个错误，即闭包不在主类中（即测试test.groovy）：在类测试@60611244中找不到名称myClosure的方法

我已尝试将代理更改为＆＃34;此＆＃34;，我尝试更改查找策略等等。我可能遗漏了一些基本内容。

Answer 1

freeStyleJob等作业工厂方法返回一个对象，该对象可用于使用with方法应用更多配置。该方法需要一个闭包参数，该参数与传递给freeStyleJob方法的闭包具有相同的属性。

def basicConfiguration() {
    return {
        description('foo')
        scm {
            // whatever
        }
    }
}

def myJob = freeStyleJob('example') {
    publishers {
        // more config
    }
}
myJob.with basicConfiguration()

脚本本身是DslFactory的一个实例，它是包含例如{0}的接口。 freeStyleJob方法。您可以将该对象传递给类或方法以使用freeStyleJob。

def myJobFactory(def dslFactory, def jobName) {
    dslFactory.freeStyleJob(jobName) {
        description('foo')
    }
}

def myJob = myJobFactory(this, 'example')

然后您可以使用myJob对象使用with进行进一步配置。

Answer 2

似乎一个解决方案是颠倒这样的关系，并通过＆＃34;这个＆＃34;作为查找DSL顶级闭包的上下文。

class Utils {
    static def makeMeABasicJob(def context) {
        context.freeStyleJob() {
            //generic stuff
            name "something"
            description "something else"
        }

    }
}

def job1 = Utils.makeMeABasicJob(this) //Passing the groovy file class as the resolution context
job1.with({
    //custom stuff
    scm {
        svn {
            //etc....
        }
    }
})

Answer 3

这样的事情怎么样？

def jobCommonItems(job) {
    job.name = "something"
    job.description = "something else"
}

freeStyleJob() {
    jobCommonItems(this)

    //custom stuff
    scm {
       svn {
           //etc....
       }
    }
}

Answer 4

当试图从我的 Jenkins DSL groovy 脚本中提取通用逻辑时，我最初使用的样式是将 job 对象传递给一个通用的静态助手，然后执行类似于 job.with{...} daspilker 解决方案。

但是我发现使用委托更直接一些。例如：

freeStyleJob('name') {
    jobDesc(delegate, 'something')
    jobSCM(delegate, 'git@gitlab.com:MyGroup/MyProject.git', 'master')
}

def jobDesc(def context, def descText) {
    context.description(descText)
}

def jobSCM(def context, def repoURL, def branchName)
{
    context.scm {
        git {
                remote {
                    url(repoURL)
                }
                branch('refs/heads/' + branchName)
        }   
    }
}

jobDesc 和 jobSCM 方法可以作为静态助手移动到单独的实用程序类，然后您可以将其导入到您的 DSL groovy 脚本中。

Groovy：如何从另一个闭包中调用top作用域中的闭包

4 个答案: