Question

我试图使用XSL将XML文件转换为漂亮的HTML表格，但我无法确定如何正确排列列。我发现了一个类似的问题（Convert XML List to HTML Table Using XSL），它提供了丰富的信息（我对XSL很新，所以每一点都有帮助），但我的XML结构更加......不规则：

<?xml version="1.0"?>
<root>
    <Group>
        <Type>Type1</Type>
        <Desc>Desc1</Desc>
        <Name>Name1</Name>
    </Group>
    <Group>
        <Type>Type2</Type>
        <Name>Name2</Name>
        <State>State2</State>
    </Group>
    <Group>
        <Type>Type3</Type>
        <State>State3</State>
        <Country>Country4</Country>
    </Group>
</root>

有没有一种好方法可以将其转换为格式良好的表格？我喜欢它是否适用于XML，就好像我们曾经向其中一个Group元素添加新字段一样，我不希望他们必须为每个元素添加相同的标记其他元素（尽管如果有另外一种方法自动将所有丢失的子元素添加到其他Group元素中存在的Group元素中，那也可能是好的，也许使用第二个元素可以先运行的XSLT）。这个XML没有后备架构，但如果它有帮助就可以制作。

很抱歉，如果之前已经回答过这个问题，除了提到的问题之外，我找不到任何更接近的问题，也没有关于如何将缺少的孩子添加到元素中的信息。

Answer 1

首先，这并不简单。如果您是XSLT的新手，那么这可能不是您最好的项目。

为了理解以下解决方案，您需要熟悉使用keys以及Muenchian grouping技术。

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:key name="col-by-name" match="/root/Group/*" use="name()" />
<xsl:key name="cell-by-rowXcol" match="/root/Group/*" use="concat(generate-id(..), '|', name())" />

<xsl:template match="/root">
    <xsl:variable name="distinct-columns" select="Group/*[count(. | key('col-by-name', name())[1]) = 1]"/>
    <table border="1">
        <thead>
            <tr>
                <xsl:for-each select="$distinct-columns">
                    <th><xsl:value-of select="name()"/></th>
                </xsl:for-each>
            </tr>
        </thead>
        <tbody>
            <xsl:for-each select="Group">
            <xsl:variable name="row" select="generate-id()" />
                <tr>
                    <xsl:for-each select="$distinct-columns">
                        <td>
                            <xsl:value-of select="key('cell-by-rowXcol', concat($row, '|', name()))" />
                        </td>
                    </xsl:for-each>
                </tr>
            </xsl:for-each>
        </tbody>
    </table>
</xsl:template>

</xsl:stylesheet>

结果（已呈现）：

在XSLT 2.0中，您可以使用distinct-values()函数代替Muenchian分组。

Answer 2

以下是我对XSLT 2.0解决方案的尝试：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="html" version="5.0" encoding="UTF-8" indent="yes" />

    <xsl:variable name="col-names" select="distinct-values(root/Group/*/node-name(.))"/>

    <xsl:template match="root">
        <table>
            <thead>
                <tr>
                    <xsl:for-each select="$col-names">
                        <th>
                            <xsl:value-of select="."/>
                        </th>
                    </xsl:for-each>
                </tr>
            </thead>
            <tbody>
                <xsl:apply-templates select="Group"/>                
            </tbody>
        </table>
    </xsl:template>

    <xsl:template match="Group">
        <tr>
            <xsl:variable name="this" select="."/>
            <xsl:for-each select="$col-names">
                <td>
                    <xsl:value-of select="$this/*[node-name(.) eq current()]"/>
                </td>
            </xsl:for-each>
        </tr>
    </xsl:template>
</xsl:transform>

使用XSL将稀疏填充的XML列表转换为HTML表

2 个答案: