Question

鉴于以下课程：

class ListIsomorphic l where
    toList   :: l a -> [a]
    fromList :: [a] -> l a

如何使用Data.Vector.Generic为矢量类型编写实例？这不起作用：

instance (V.Vector v a) => ListIsomorphic v where
    toList   = V.toList
    fromList = V.fromList

给我：

test.hs:31:10:
    Variable ‘a’ occurs more often than in the instance head
      in the constraint: V.Vector v a
    (Use UndecidableInstances to permit this)
    In the instance declaration for ‘ListIsomorphic v’

Answer 1

<强>唐＆＃39;吨即可。由于实例重叠，将所有v的实例添加到Listable类将变得很麻烦。

Vector v a => v并不与列表同构，因为它受哪些项可以是列表元素的约束。您需要一个捕获此约束的类，如

{-# LANGUAGE ConstraintKinds #-}
{-# LANGUAGE TypeFamilies #-}

import Data.Constraint

class ConstrainedList l where
    type Elem l a :: Constraint
    toList   :: Elem l a => l a -> [a]
    fromList :: Elem l a => [a] -> l a

不是为所有类型ConstrainedList添加Vector v a => v个实例，而是让我们进入重叠的实例区域，而是仅针对我们感兴趣的类型定义它。以下内容将涵盖向量包中具有Vector实例的所有类型。

import qualified Data.Vector.Primitive as VP
import qualified Data.Vector.Generic as VG

instance ConstrainedList VP.Vector where
    type Elem VP.Vector a = VG.Vector VP.Vector a
    toList   = VG.toList
    fromList = VG.fromList

其他类型的实例

您可以为常规列表ConstrainedList编写[]个实例，该列表仅需要对其元素使用空约束。

instance ConstrainedList [] where
    type Elem [] a = ()
    toList   = id
    fromList = id

使用toList或fromList的任何地方也需要Elem l a个实例。

cmap :: (ConstrainedList l, Elem l a, Elem l b) => (a -> b) -> l a -> l b
cmap f = fromList . map f . toList

当我们知道列表和元素的具体类型时，这些函数将易于使用而不会弄乱约束。

cmap (+1) [1,2,3,4]

Here Be Dragons

不要尝试以下内容。如果您对没有附加约束的列表同构的事物类感兴趣，那么只需为它创建另一个类。这只是展示了当你将自己设计成一个角落时你可以做些什么：召唤一条龙。

您还可以编写需要证明ConstrainedList元素没有约束的函数。这是进入GHC未真正支持的constraints包和编程风格的领域，但是没有足够的constraints示例，所以我将离开这一个。

{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE ScopedTypeVariables #-}

map' :: forall l a b. (ConstrainedList l, () :=> Elem l a, () :=> Elem l b) =>
                      (a -> b) -> l a -> l b
map' f = case (ins :: () :- Elem l a) of { Sub Dict ->
         case (ins :: () :- Elem l b) of { Sub Dict ->
         fromList . map f . toList
         }}

我们可以通过检查ConstrainedList检查Elem l a ~ ()是否没有约束，但如果其约束以不同的方式编写，则无法工作。

{-# LANGUAGE FlexibleInstances #-}

class Any a
instance Any a

data AList a = AList {getList :: [a]}
    deriving (Show)

instance ConstrainedList AList where
    type Elem AList a = Any a
    toList   = getList
    fromList = AList

()与Any a的类型不同，即使()暗示Any a。约束包通过将它们引用到类型类Class和:=>

来捕获这样的关系。

{-# LANGUAGE MultiParamTypeClasses #-}

--       class () => Any a
instance Class ()   (Any a) where
    cls = Sub Dict

-- instance ()  => Any a
instance    () :=> Any a where
    ins = Sub Dict

所有这些工作都可以让我们轻松地重用函数，而无需在知道具体列表类型时提供所有这些字典。

map'' :: (a -> b) -> AList a -> AList b
map'' = map'

Answer 2

我经常遇到这个问题。以下是我提出的两个解决方案：

更改类参数：

class ListIsomorphic l a where
  toList :: l a -> [a]
  fromList :: [a] -> l a

instance (V.Vector v a) => Listable v a where
  ...

使用约束种类

class ListIsomorphic l where
  type C l a :: Constraint
  toList :: l a -> [a]
  fromList :: [a] -> l a

instance Listable v where
  type C v a = (V.Vector v a)
  ...

如何为通用向量创建ListIsomorphic实例？

2 个答案:

其他类型的实例

Here Be Dragons