Question

我正在寻找从我的单独模块中导出所有常量的最有效和可读的方法，该模块仅用于存储常量。
例如

use strict;
use warnings;

use Readonly;

Readonly our $MY_CONSTANT1         => 'constant1';
Readonly our $MY_CONSTANT2    => 'constant2'; 
....
Readonly our $MY_CONSTANT20    => 'constant20';

所以我有很多变量，并将它们全部列在@EXPORT = qw( MY_CONSTANT1.... );中这将是痛苦的。有没有任何优雅的方法来导出所有常量，在我的情况下，Readonly变量（强制导出所有，不使用@EXPORT_OK）。

Answer 1

如果这些是可能需要插入字符串等的常量，请考虑将相关常量分组为散列，并使用Const::Fast使散列为常量。这减少了命名空间污染，允许您检查特定组中的所有常量等。例如，考虑IE的ReadyState属性的READYSTATE枚举值。您可以将它们分组为散列：

，而不是为每个值创建单独的变量或单独的常量函数

package My::Enum;

use strict;
use warnings;

use Exporter qw( import );
our @EXPORT_OK = qw( %READYSTATE );

use Const::Fast;

const our %READYSTATE => (
    UNINITIALIZED => 0,
    LOADING => 1,
    LOADED => 2,
    INTERACTIVE => 3,
    COMPLETE => 4,
);

__PACKAGE__;
__END__

然后，您可以直观地使用它们，如：

use strict;
use warnings;

use My::Enum qw( %READYSTATE );

for my $state (sort { $READYSTATE{$a} <=> $READYSTATE{$b} } keys %READYSTATE) {
    print "READYSTATE_$state is $READYSTATE{$state}\n";
}

另见Neil Bowers' excellent review on 'CPAN modules for defining constants'。

Answer 2

实际常数：

use constant qw( );
use Exporter qw( import );    

our @EXPORT_OK;

my %constants = (
   MY_CONSTANT1 => 'constant1',
   MY_CONSTANT2 => 'constant2',
   ...
);

push @EXPORT_OK, keys(%constants);
constant->import(\%constants);

使用Readonly对变量进行只读：

use Exporter qw( import );
use Readonly qw( Readonly );

our @EXPORT_OK;

my %constants = (
   MY_CONSTANT1 => 'constant1',
   MY_CONSTANT2 => 'constant2',
   #...
);

for my $name (keys(%constants)) {
   push @EXPORT_OK, '$'.$name;
   no strict 'refs';
   no warnings 'once';
   Readonly($$name, $constants{$name});
}

Answer 3

要回复@CROSP，您可以使用@ikegami的Readonly方法，如下所示：

在MyConstants.pm

package MyConstants;
<code from answer above>
1;

然后在foo.pl

use MyConstants qw($MY_CONSTANT1, $MY_CONSTANT2);
print "This is $MY_CONSTANT1\n";

从Perl模块

3 个答案: