ItemsControl绑定到ObservableColellection而不更新属性更改的UI

时间：2015-07-30 01:51:05

标签： wpf vb.net itemscontrol updating

经过很多头痛和深夜，我已经放弃了尝试自己解决问题的答案。虽然有大量文献可以找到非常类似的问题，但我无法找到解决我特定问题的确切方法。

我无法使用画布作为ItemsPanel获取我的ItemsControl，以便在其ItemsSource中的项目属性被修改后更新UI。

我创建了一个非常干净的示例应用程序来准确演示正在发生的事情。

在我的示例应用程序中，我有一个视图'MainWindow.xaml'，一个视图模型'MainWindowViewModel.vb'继承'ViewModelBase.vb'，最后一个命令委托'DelegateCommand.vb'用于创建RelayCommands更新我的ItemsControl的ItemSource。

首先，MainWindow.xaml：

<Window
    xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
    xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
    xmlns:local="clr-namespace:SampleApp"
    x:Class="MainWindow" Title="MainWindow" Height="347" Width="525" Background="Black">
    <Window.DataContext>
        <local:MainWindowViewModel/>
    </Window.DataContext>
    <Grid>
        <!-- LINE SEGMENTS -->
        <ItemsControl x:Name="ic1" ItemsSource="{Binding LineData, Mode=OneWay, NotifyOnTargetUpdated=True}" HorizontalAlignment="Left" Height="246" VerticalAlignment="Top" Width="517" Background="#FF191919" BorderBrush="#FF444444">
            <ItemsControl.ItemsPanel>
                <ItemsPanelTemplate>
                    <Canvas IsItemsHost="True"/>
                </ItemsPanelTemplate>
            </ItemsControl.ItemsPanel>
            <ItemsControl.ItemTemplate>
                <DataTemplate>
                    <Line X1="{Binding X1}" Y1="{Binding Y1}" X2="{Binding X2}" Y2="{Binding Y2}" Stroke="White" StrokeThickness="6"/>
                </DataTemplate>
            </ItemsControl.ItemTemplate>
        </ItemsControl>

        <Button Content="Refresh Canvas" HorizontalAlignment="Left" Margin="350,261,0,0" VerticalAlignment="Top" Width="124" Height="40" FontFamily="Verdana" FontWeight="Bold" Click="Button_Click"/>
        <Button Content="Command 1" Command="{Binding Command1}" HorizontalAlignment="Left" Margin="45,261,0,0" VerticalAlignment="Top" Width="124" Height="40" FontFamily="Verdana" FontWeight="Bold"/>
        <Button Content="Command 2" Command="{Binding Command2}" HorizontalAlignment="Left" Margin="198,261,0,0" VerticalAlignment="Top" Width="124" Height="40" FontWeight="Bold" FontFamily="Verdana"/>
    </Grid>
</Window>

如您所见，我的Window的DataContext是MainWindowViewModel，ItemSource的绑定是LineData（位于该VM中）。

另外，我有三个按钮。前两个按钮执行ICommands，而第三个按钮执行ItemsControl的后置代码刷新（这是为了调试目的，以证明在不是UI的情况下更新ItemSource中的绑定属性）。稍后会详细介绍。

第一个按钮绑定到VM中的Command1，而第二个按钮绑定到VM中的Command2。

接下来，MainWindowViewModel.vb：

Imports System.Collections.ObjectModel

Public Class MainWindowViewModel
    Inherits ViewModelBase

    ' Sample line data variable
    Private _LineData As ObservableCollection(Of LineStructure) = GetLineData()
    Public Property LineData As ObservableCollection(Of LineStructure)
        Get
            Return _LineData
        End Get
        Set(value As ObservableCollection(Of LineStructure))
            _LineData = value
            OnPropertyChanged("LineData")
        End Set
    End Property

    ' ICommands
    Private _Command1 As ICommand
    Public ReadOnly Property Command1 As ICommand
        Get
            If _Command1 Is Nothing Then
                _Command1 = New MVVM.RelayCommand(AddressOf ExecuteCommand1)
            End If
            Return _Command1
        End Get
    End Property

    Private _Command2 As ICommand
    Public ReadOnly Property Command2 As ICommand
        Get
            If _Command2 Is Nothing Then
                _Command2 = New MVVM.RelayCommand(AddressOf ExecuteCommand2)
            End If
            Return _Command2
        End Get
    End Property

    ' ICommand Methods
    Private Sub ExecuteCommand1()
        ' Re-arrange LineData(0) to make a plus sign on the canvas
        ' This works - Assigning a new value to an item of the collection updates the canvas
        LineData(0) = New LineStructure With {.X1 = "175", .Y1 = "50", .X2 = "175", .Y2 = "150"}
    End Sub

    Private Sub ExecuteCommand2()
        ' Put LineData(0) back into its original position
        ' This doesn't work - Modifying the PROPERTY of an item in the collection does not update the canvas.. even with INotifyPropertyChange being called
        LineData(0).X1 = "50"
        LineData(0).Y1 = "50"
        LineData(0).X2 = "300"
        LineData(0).Y2 = "50"

        OnPropertyChanged("LineData")
    End Sub

    ' Misc methods
    Private Function GetLineData() As ObservableCollection(Of LineStructure)
        Dim tmpList As New ObservableCollection(Of LineStructure)

        ' Create two horizontal parallel lines
        tmpList.Add(New LineStructure With {.X1 = "50", .Y1 = "50", .X2 = "300", .Y2 = "50"})
        tmpList.Add(New LineStructure With {.X1 = "50", .Y1 = "100", .X2 = "300", .Y2 = "100"})

        Return tmpList
    End Function
End Class

Public Class LineStructure
    Public Property X1
    Public Property Y1
    Public Property X2
    Public Property Y2
End Class

在我的viewmodel中，我已经立即定义了LineData（这是我的ItemsSource绑定的），所以我们有一些数据可以让我们的ItemSource准备好在执行时显示在画布中。它由GetLineData（）函数定义，该函数只返回2行的填充ObservableCollection。

当应用程序首次启动时，会显示两条水平平行线。

LineData变量是我定义的LineStructure类的ObservableObject，它只包含要绑定到画布并在画布中显示的相应对象的X1，Y1，X2，Y2字符串。

Command1（再次，它绑定到第一个按钮）将新的LineStructure分配给LineData的第一个索引。执行此操作时，一切都很棒; UI按预期更新，每个人都很高兴。这使得线条在画布上显示为加号。

以下是问题的开始：

Command2不会像Command1那样为第一个LineData索引分配新的LineStructure，而是分别在第一个LineData索引中重新定义属性。如果这样做，它将重新排列第一行，并且画布上的两条线将再次水平平行。

然而，这不会更新画布/ UI - 我无法弄清楚原因。我阅读了大量文章并尝试了许多不同的解决方案，但无济于事。

如果有人能解释为什么绑定在修改属性时不会更新而不是一起重新声明LineStructure索引，请告诉我，我将不胜感激。

最后要注意的一点是，我已经设法找到了一个可以得到我需要的解决方案，但是我不相信我应该使用它。我认为绑定应该能够照顾到检测任何财产变化。

对于任何感兴趣的人，请参阅以下代码片段，了解更改属性更改画布的临时解决方案。

我已将NotifyOnTargetUpdated = True和TargetUpdated =“RefreshCanvas”添加到xaml中的ItemsControl声明中。

这样做是调用一个名为RefreshCanvas（）的方法，它从MainWindow的代码隐藏中执行ic1.Items.Refresh（）（你可以在这篇文章的末尾找到代码隐藏）。这将刷新ItemsControl项，因此画面将刷新并显示绑定集合的更新。

<ItemsControl x:Name="ic1" TargetUpdated="RefreshCanvas" ItemsSource="{Binding LineData, Mode=OneWay, UpdateSourceTrigger=PropertyChanged, NotifyOnTargetUpdated=True}" HorizontalAlignment="Left" Height="246" VerticalAlignment="Top" Width="517" Background="#FF191919" BorderBrush="#FF444444">

我将包含我的其他文件仅供参考，因为它可能是相关的：

ViewModelBase.vb：

Imports System.ComponentModel

Public MustInherit Class ViewModelBase
    Implements INotifyPropertyChanged, IDisposable

#Region "Constructor"
    Protected Sub New()
    End Sub
#End Region ' Constructor

#Region "DisplayName"

    ' Returns the user-friendly name of this object.
    ' Child classes can set this property to a new value, or override it to determine the value on-demand.

    Private privateDisplayName As String

    Public Overridable Property DisplayName() As String
        Get
            Return privateDisplayName
        End Get
        Protected Set(ByVal value As String)
            privateDisplayName = value
        End Set
    End Property
#End Region ' DisplayName

#Region "Debugging Aids"
    ' Warns the developer if this object does not have a public property with the specified name. 
    ' This method does not exist in a Release build.
    <Conditional("DEBUG"), DebuggerStepThrough()> _
    Public Sub VerifyPropertyName(ByVal propertyName As String)
        ' Verify that the property name matches a real, public, instance property on this object.
        If TypeDescriptor.GetProperties(Me)(propertyName) Is Nothing Then
            Dim msg As String = "Invalid property name: " & propertyName

            If Me.ThrowOnInvalidPropertyName Then
                Throw New Exception(msg)
            Else
                Debug.Fail(msg)
            End If
        End If
    End Sub

    ' Returns whether an exception is thrown, or if a Debug.Fail() is used when an invalid property name is passed to the VerifyPropertyName method.
    ' The default value is false, but subclasses used by unit tests might override this property's getter to return true.
    Private privateThrowOnInvalidPropertyName As Boolean
    Protected Overridable Property ThrowOnInvalidPropertyName() As Boolean
        Get
            Return privateThrowOnInvalidPropertyName
        End Get
        Set(ByVal value As Boolean)
            privateThrowOnInvalidPropertyName = value
        End Set
    End Property
#End Region ' Debugging Aides

#Region "INotifyPropertyChanged Members"
    ' Raised when a property on this object has a new value.
    Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged

    ' Raises this object's PropertyChanged event.
    ' <param name="propertyName">The property that has a new value.</param>
    Protected Overridable Sub OnPropertyChanged(ByVal propertyName As String)
        Me.VerifyPropertyName(propertyName)

        Dim handler As PropertyChangedEventHandler = Me.PropertyChangedEvent
        If handler IsNot Nothing Then
            Dim e = New PropertyChangedEventArgs(propertyName)
            handler(Me, e)
        End If
    End Sub
#End Region ' INotifyPropertyChanged Members

#Region "IDisposable Support"
    Private disposedValue As Boolean ' To detect redundant calls

    ' IDisposable
    Protected Overridable Sub Dispose(disposing As Boolean)
        If Not Me.disposedValue Then
            If disposing Then
                ' TODO: dispose managed state (managed objects).
            End If

            ' TODO: free unmanaged resources (unmanaged objects) and override Finalize() below.
            ' TODO: set large fields to null.
        End If
        Me.disposedValue = True
    End Sub

    ' Invoked when this object is being removed from the application and will be subject to garbage collection.
    Public Sub Dispose() Implements IDisposable.Dispose
        Me.OnDispose()
    End Sub

    ' Child classes can override this method to perform clean-up logic, such as removing event handlers.
    Protected Overridable Sub OnDispose()
    End Sub

    ' Controla el tancament del ViewModel.
    ' <returns></returns>
    ' <remarks></remarks>
    Public Overridable Function CanClose() As Boolean
        Return Nothing
    End Function

#If DEBUG Then
    ' Useful for ensuring that ViewModel objects are properly garbage collected.
    Protected Overrides Sub Finalize()
        Dim msg As String = String.Format("{0} ({1}) ({2}) Finalized", Me.GetType().Name, Me.DisplayName, Me.GetHashCode())
        System.Diagnostics.Debug.WriteLine(msg)
    End Sub
#End If
#End Region

End Class

DelegateCommand.vb：

Imports System.Windows.Input

Namespace MVVM
    Public NotInheritable Class RelayCommand
        Implements ICommand

#Region " Declarations "
        Private ReadOnly _objCanExecuteMethod As Predicate(Of Object) = Nothing
        Private ReadOnly _objExecuteMethod As Action(Of Object) = Nothing
#End Region

#Region " Events "
        Public Custom Event CanExecuteChanged As EventHandler Implements System.Windows.Input.ICommand.CanExecuteChanged
            AddHandler(ByVal value As EventHandler)
                If _objCanExecuteMethod IsNot Nothing Then
                    AddHandler CommandManager.RequerySuggested, value
                End If
            End AddHandler

            RemoveHandler(ByVal value As EventHandler)
                If _objCanExecuteMethod IsNot Nothing Then
                    RemoveHandler CommandManager.RequerySuggested, value
                End If
            End RemoveHandler

            RaiseEvent(ByVal sender As Object, ByVal e As System.EventArgs)
                If _objCanExecuteMethod IsNot Nothing Then
                    CommandManager.InvalidateRequerySuggested()
                End If
            End RaiseEvent
        End Event
#End Region

#Region " Constructor "
        Public Sub New(ByVal objExecuteMethod As Action(Of Object))
            Me.New(objExecuteMethod, Nothing)
        End Sub

        Public Sub New(ByVal objExecuteMethod As Action(Of Object), ByVal objCanExecuteMethod As Predicate(Of Object))
            If objExecuteMethod Is Nothing Then
                Throw New ArgumentNullException("objExecuteMethod", "Delegate comamnds can not be null")
            End If

            _objExecuteMethod = objExecuteMethod
            _objCanExecuteMethod = objCanExecuteMethod
        End Sub
#End Region

#Region " Methods "
        Public Function CanExecute(ByVal parameter As Object) As Boolean Implements System.Windows.Input.ICommand.CanExecute
            If _objCanExecuteMethod Is Nothing Then
                Return True
            Else
                Return _objCanExecuteMethod(parameter)
            End If
        End Function

        Public Sub Execute(ByVal parameter As Object) Implements System.Windows.Input.ICommand.Execute
            If _objExecuteMethod Is Nothing Then
                Return
            Else
                _objExecuteMethod(parameter)
            End If
        End Sub
#End Region
    End Class
End Namespace


Namespace MVVM
    Public NotInheritable Class RelayCommand(Of T)
        Implements ICommand

#Region " Declarations "
        Private ReadOnly _objCanExecuteMethod As Predicate(Of T) = Nothing
        Private ReadOnly _objExecuteMethod As Action(Of T) = Nothing
#End Region

#Region " Events "
        Public Custom Event CanExecuteChanged As EventHandler Implements System.Windows.Input.ICommand.CanExecuteChanged
            AddHandler(ByVal value As EventHandler)
                If _objCanExecuteMethod IsNot Nothing Then
                    AddHandler CommandManager.RequerySuggested, value
                End If
            End AddHandler

            RemoveHandler(ByVal value As EventHandler)
                If _objCanExecuteMethod IsNot Nothing Then
                    RemoveHandler CommandManager.RequerySuggested, value
                End If
            End RemoveHandler

            RaiseEvent(ByVal sender As Object, ByVal e As System.EventArgs)
                If _objCanExecuteMethod IsNot Nothing Then
                    CommandManager.InvalidateRequerySuggested()
                End If
            End RaiseEvent
        End Event
#End Region

#Region " Constructors "
        Public Sub New(ByVal objExecuteMethod As Action(Of T))
            Me.New(objExecuteMethod, Nothing)
        End Sub

        Public Sub New(ByVal objExecuteMethod As Action(Of T), ByVal objCanExecuteMethod As Predicate(Of T))
            If objExecuteMethod Is Nothing Then
                Throw New ArgumentNullException("objExecuteMethod", "Delegate comamnds can not be null")
            End If

            _objExecuteMethod = objExecuteMethod
            _objCanExecuteMethod = objCanExecuteMethod
        End Sub
#End Region

#Region " Methods "
        Public Function CanExecute(ByVal parameter As Object) As Boolean Implements ICommand.CanExecute
            If _objCanExecuteMethod Is Nothing Then
                Return True
            Else
                Return _objCanExecuteMethod(DirectCast(parameter, T))
            End If
        End Function

        Public Sub Execute(ByVal parameter As Object) Implements ICommand.Execute
            _objExecuteMethod(DirectCast(parameter, T))
        End Sub
#End Region
    End Class
End Namespace

MainWindow.xaml.vb（MainWindow的代码隐藏）：

Class MainWindow 
    Private Sub Button_Click(sender As Object, e As RoutedEventArgs)
        ic1.Items.Refresh()
    End Sub

    Private Sub RefreshCanvas(sender As Object, e As DataTransferEventArgs)
        sender.Items.Refresh()
    End Sub
End Class

感谢您提供任何可帮助我指明正确方向的帮助，希望这也可以帮助其他人。

*****更新，问题已解决*****

E-Bat非常友好地指出LineData结构的属性本身需要实现INotifyPropertyChanged。我已实现此更改并在下面添加了更新且正常工作的“MainWindowViewModel.xaml”代码：

Imports System.ComponentModel
Imports System.Collections.ObjectModel

Public Class MainWindowViewModel
    Inherits ViewModelBase

    ' Sample line data variable
    Private _LineData As ObservableCollection(Of LineData) = GetLineData()
    Public Property LineData As ObservableCollection(Of LineData)
        Get
            Return _LineData
        End Get
        Set(value As ObservableCollection(Of LineData))
            _LineData = value
            OnPropertyChanged("LineData")
        End Set
    End Property

    ' ICommands
    Private _Command1 As ICommand
    Public ReadOnly Property Command1 As ICommand
        Get
            If _Command1 Is Nothing Then
                _Command1 = New MVVM.RelayCommand(AddressOf ExecuteCommand1)
            End If
            Return _Command1
        End Get
    End Property

    Private _Command2 As ICommand
    Public ReadOnly Property Command2 As ICommand
        Get
            If _Command2 Is Nothing Then
                _Command2 = New MVVM.RelayCommand(AddressOf ExecuteCommand2)
            End If
            Return _Command2
        End Get
    End Property

    ' ICommand Methods
    Private Sub ExecuteCommand1()
        ' Re-arrange LineData(0) to make a plus sign on the canvas
        ' This works - Assigning a new value to an item of the collection updates the canvas
        LineData(0) = New LineData With {.X1 = "175", .Y1 = "50", .X2 = "175", .Y2 = "150"}
    End Sub

    Private Sub ExecuteCommand2()
        ' Put LineData(0) back into its original position
        ' Now it works, it's voodoo!
        LineData(0).X1 = "50"
        LineData(0).Y1 = "50"
        LineData(0).X2 = "300"
        LineData(0).Y2 = "50"
    End Sub

    ' Misc methods
    Private Function GetLineData() As ObservableCollection(Of LineData)
        Dim tmpList As New ObservableCollection(Of LineData)

        ' Create two horizontal parallel lines
        tmpList.Add(New LineData With {.X1 = "50", .Y1 = "50", .X2 = "300", .Y2 = "50"})
        tmpList.Add(New LineData With {.X1 = "50", .Y1 = "100", .X2 = "300", .Y2 = "100"})

        OnPropertyChanged("LineData")

        Return tmpList
    End Function
End Class

Public Class LineData
    Implements INotifyPropertyChanged

    Private _X1 As String
    Public Property X1 As String
        Get
            Return _X1
        End Get
        Set(value As String)
            _X1 = value
            OnPropertyChanged("X1")
        End Set
    End Property

    Private _Y1 As String
    Public Property Y1 As String
        Get
            Return _Y1
        End Get
        Set(value As String)
            _Y1 = value
            OnPropertyChanged("Y1")
        End Set
    End Property

    Private _X2 As String
    Public Property X2 As String
        Get
            Return _X2
        End Get
        Set(value As String)
            _X2 = value
            OnPropertyChanged("X2")
        End Set
    End Property

    Private _Y2 As String
    Public Property Y2 As String
        Get
            Return _Y2
        End Get
        Set(value As String)
            _Y2 = value
            OnPropertyChanged("Y2")
        End Set
    End Property

    Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged

    Protected Sub OnPropertyChanged(ByVal name As String)
        RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(name))
    End Sub
End Class

1 个答案:

答案 0 :(得分：1)

当你从ObservableCollection中替换一个项目时，旧的引用将首先被删除，然后它会添加新的引用，因此ObservableCollection将上升它的事件，这就是为什么第一个命令作为魔法工作。

现在，对于刷新UI的第二个命令，您必须自己创建项目，LineStructure，INotifyPropertyChanged的实现者，以便绑定刷新其属性的任何更改。所以告别这个类的自动化属性。

Public Class LineStructure
    Implements INotifyPropertyChanged

    Private _x1 As String
    Public Property X1 As String
        Get
            Return _x1
        End Get
        Set(value As String)
            If _x1 = value Then Return
            _x1 = value
            OnPropertyChanged("X1")
        End Set
    End Property
End Class
相关问题
最新问题