Question

每当我吃一个苹果时，我的蛇的移动速度加倍。我似乎无法弄清楚造成它的原因。另外，令我困惑的另一件事是每当我调用background（）然后在它下方调用drawgrid时，网格会在游戏开始时出现并迅速消失，然后再也不会被绘制。任何帮助将不胜感激。这是代码：

  class Sprite {
  float x;
  float y;
  float [] dx = {0, 0, 20, -20};//up, down, right, left
  float [] dy = {20, -20, 0, 0};//up, down, right, left

  void update() {
    x += dx[dir];
    y += dy[dir];
  }
}

class Body extends Sprite {

  void render() {

    pushMatrix();
    stroke(255);
    fill(0);
    rect(x, y, bSize, bSize);
    popMatrix();
  }

  void update() {
    super.update();
    if (Direction.equals("up")) {
      dir = 1;
    } else if (Direction.equals("down")) {
      dir = 0;
    } else if (Direction.equals("right")) {
      dir = 2;
    } else if (Direction.equals("left")) {
      dir = 3;
    }

    if (dist(x, y, applex*bSize, appley*bSize) < 10) {
      add = true;
      applex = ceil(random(0, 38));
      appley = ceil(random(0, 38));
    }
  }
}
int w = 50;
int h = 50;
float bSize;
color fillColor;
String Direction;
int dir = 2; //starting at the "right" direction
ArrayList<Body> sBody;
float applex;
float appley;
float prevX;
float prevY;

boolean add = false;

void setup() {

  size(801, 801);
  smooth();
  //frameRate(12);
  applex = ceil(random(0, 38));
  appley = ceil(random(0, 38));
  bSize = 20;
  prevX = -5;
  prevY = -5;
  fillColor = color(0);
  Direction = "right";
  sBody = new ArrayList<Body>();
  Body b = new Body();
  sBody.add(b);
}

void draw() {
  if (add) {
    Body b = new Body();
    sBody.add(b);
    add = false;
  }

  if ((frameCount%5)==0) {
    //background(255);
    drawGrid();
    fill(255, 0, 0);
    rect(applex*bSize, appley*bSize, 20, 20);
    for (Body t : sBody) {
      if (prevX > -1 && prevY > -1) {
        t.x = prevX;
        t.y = prevY;
      }
      t.render();
      t.update();
      prevX = t.x;
      prevY = t.y;
    }
  }
}

void keyPressed() {
  if (key == CODED) {

    if (Direction.equals("right") || Direction.equals("left")) {
      if (keyCode == UP) {
        Direction = "up";
      }
      if (keyCode == DOWN) {
        Direction = "down";
      }
    }

    if (Direction.equals("up") || Direction.equals("down")) {
      if (keyCode == RIGHT) {
        Direction = "right";
      }
      if (keyCode == LEFT) {
        Direction = "left";
      }
    }
  }
}

void drawGrid() {

  for (int i =  0; i < height; i += 20) {
    for (int j = 0; j < width; j += 20) {
      pushMatrix();
      fill(200);
      stroke(255);
      rect(i, j, bSize, bSize);
      popMatrix();
    }
  }
}


////end of code////

Answer 1

你的逻辑有一些问题。

看看这个循环：

for (Body t : sBody) {
      if (prevX > -1 && prevY > -1) {
        t.x = prevX;
        t.y = prevY;
      }
      t.render();
      t.update();
      prevX = t.x;
      prevY = t.y;
 }

注意您是如何在列表中每个 update()对象上调用Body的。这会导致蛇对每个段移动，这就是为什么它变长时会变得更快。要修复那个问题，您只需要在蛇的 head 上调用update()，然后遍历其余的段以让它们跟随头。

但这不是你唯一的问题。另请注意，退出此循环后，prevX和prevY将保留Body列表中最后 sBody对象的值。然后，当你下次循环时，你将蛇的头的位置设置到那个位置。这没有任何意义，它会使你的蛇从最后一段而不是头部“转向”。

您的第三个问题是：您在更新它们之后还设置了prevX和prevY 的值，这再次导致您的蛇行为不正确。

所以要解决所有这些问题，你需要做一些事情：

只有update()蛇头。
在每次循环之前设置prevX和prevY，而不是将头部移动到最后。
只穿过蛇的休息，让它跟随头部。
使用临时变量，因此prevX和prevY设置为t.x和t.y在更新之前持有的值。

最后，你的循环应该是这样的：

//only move the head sBody.get(0).update(); //set prevX and prevY to the head's position prevX = sBody.get(0).x; prevY = sBody.get(0).y; for (Body t : sBody) { //render ever piece, including the head t.render(); //but don't move the head again if (t == sBody.get(0)) { continue; } //store the position before you change it float tempX = t.x; float tempY = t.y; //change the position t.x = prevX; t.y = prevY; //prevX and prevY hold the t.x and t.y values **before** you updated them prevX = tempX; prevY = tempY; }

此外，值得注意的是，使用2D阵列实现这可能要容易得多。哦，您对pushMatrix()和popMatrix()的调用是不必要的，因为您实际上并没有修改矩阵。

Answer 2

如果您在设置中添加了frameRate(5)，您就会明白为什么会发生这种情况，而且您不需要if ((frameCount%5)==0)。基本上你有很多Bodys，整条蛇跳过这么多块！这是因为你构建for循环的方式，这实际上是以最后一个块是蛇头的方式渲染块。

如果我可以提出更好的解决方案。你真正需要更新的唯一一块是蛇头，我建议sBody.get(0)。其余的块只需要有前一个位置，但你必须小心每个单元格获得前一个单元格的位置！这是解决方案：

for (Body t : sBody) {
  if (t == sBody.get(0)) {
    // if its the first element (the head) store its 
    // position in prevX,prevY and update it afterwards
    prevX = t.x;
    prevY = t.y;
    t.update();
  } else {
    // otherwise for other blocks, since we are 
    // using prevX, prevY for the previous block
    // we need to store the current position
    // of this block to give it back to prevX, prevY
    float tpX = t.x;
    float tpY = t.y;
    t.x = prevX;
    t.y = prevY;
    prevX = tpX;
    prevY = tpY;
  }
  t.render();
}

在我的情况下，我没有看到网格问题，可能是因为您使用的是if ((frameCount%5)==0)行......

处理：蛇游戏运动逻辑

2 个答案: