Question

我正在尝试使用“护送模式”来保持3个变量之间的依赖关系（两个参数和返回值）：

Require Import Vector.

(* "sparse" vector type *)
Notation svector A n := (Vector.t (option A) n).

Fixpoint svector_is_dense {A} {n} (v:svector A n) : Prop :=
  match v with
  | Vector.nil => True
  | Vector.cons (None) _ _ => False
  | Vector.cons (Some _) _ xs => svector_is_dense xs
  end.

Lemma svector_tl_dense {A} {n} {v: svector A (S n)}:
  svector_is_dense v -> svector_is_dense (Vector.tl v).
Admitted.

Lemma svector_hd {A} {n} (v:svector A (S n)): svector_is_dense v -> A.
Admitted.

Fixpoint vector_from_svector {A} {n} {v:svector A n} (D:svector_is_dense v): Vector.t A n :=
  match n return (svector A n) -> (svector_is_dense v) -> (Vector.t A n) with
  | O => fun _ _ => @Vector.nil A
  | (S p) => fun v0 D0 => Vector.cons
                            (svector_hd v0 D0)
                            (vector_from_svector (Vector.tl v) (svector_tl_dense D))
  end v D.

问题出现在最后的定义中。有什么建议吗？

Answer 1

你几乎是对的。问题出在您的return子句中，该子句不依赖。你需要的是

match n return forall (w: svector A n), (svector_is_dense w) -> (Vector.t A n) with

因此D0不属于svector_is_dense v类型，而是svector_is_dense v0。

顺便说一下，在第二个构造函数中，我猜你的意思是Vector.tl v0和svector_tl_dense D0。这是我写的完整术语（不要介意_中的附加cons，我没有激活implicits：

Fixpoint vector_from_svector {A} {n} {v:svector A n} (D:svector_is_dense v): Vector.t A n :=
  match n return forall (w:svector A n), (svector_is_dense w) -> (Vector.t A n) with
  | O => fun _ _ => @Vector.nil A
  | (S p) => fun v0 D0 => Vector.cons _
                            (svector_hd v0 D0) _
                            (vector_from_svector (svector_tl_dense D0))
  end v D.

Coq“护航模式”

1 个答案: