返回两个TShapes交集的函数，包括TPaths？

Question

任何人都知道一个函数返回两个TShapes的交集TPath？特别是返回两个TPath的交集TPath的那个。

例如：

pthIntersection := PathIntersection(Path1,Path2);

Answer 1

没有内置功能。<​​br/> 但我认为你要做的是：

给出由线连接的不同点组成的多边形（也称为TPath） 返回位于ShapeB内的ShapeA中的所有点。

点交叉点
这可以使用PointInObjectLocal完成 运行循环访问PathA中的所有点，看看是否有PathB内的任何点。

线路交叉点
如果你想知道所有重叠的顶点，你首先必须Flatten（一个副本）两个TPath，然后为两个形状的所有线运行一个线交叉算法。
这会将所有曲线转换为线条。

以下是这样做的例程：
来自：http://www.partow.net/projects/fastgeo/index.html

function Intersect(const x1, y1, x2, y2, x3, y3, x4, y4: TFloat; out ix, iy: TFloat): boolean;
var
  UpperX, UpperY, LowerX, LowerY: TFloat;
  Ax, Bx, Cx, Ay, By, Cy: TFloat;
  D, F, E, Ratio: TFloat;
begin
  Result:= false;

  Ax:= x2 - x1;
  Bx:= x3 - x4;

  if Ax < Zero then begin
    LowerX:= x2;
    UpperX:= x1;
  end else begin
    UpperX:= x2;
    LowerX:= x1;
  end;

  if Bx > Zero then begin
    if (UpperX < x4) or (x3 < LowerX) then Exit;
  end else if (UpperX < x3) or (x4 < LowerX) then Exit;

  Ay:= y2 - y1;
  By:= y3 - y4;

  if Ay < Zero then begin
    LowerY:= y2;
    UpperY:= y1;
  end else begin
    UpperY:= y2;
    LowerY:= y1;
  end;

  if By > Zero then begin
    if (UpperY < y4) or (y3 < LowerY) then Exit;
  end else if (UpperY < y3) or (y4 < LowerY) then Exit;

  Cx:= x1 - x3;
  Cy:= y1 - y3;
  D:= (By * Cx) - (Bx * Cy);
  F:= (Ay * Bx) - (Ax * By);

  if F > Zero then begin
    if (D < Zero) or (D > F) then Exit;
  end else if (D > Zero) or (D < F) then Exit;

  E:= (Ax * Cy) - (Ay * Cx);

  if F > Zero then begin
    if (E < Zero) or (E > F) then Exit;
  end else if (E > Zero) or (E < F) then Exit;

  Result:= true;

  Ratio:= (Ax * -By) - (Ay * -Bx);

  if NotEqual(Ratio, Zero) then begin
    Ratio:= ((Cy * -Bx) - (Cx * -By)) / Ratio;
    ix:= x1 + (Ratio * Ax);
    iy:= y1 + (Ratio * Ay);
  end else begin
    //if Collinear(x1,y1,x2,y2,x3,y3) then
    if IsEqual((Ax * -Cy), ( -Cx * Ay)) then begin
      ix:= x3;
      iy:= y3;
    end else begin
      ix:= x4;
      iy:= y4;
    end;
  end;
end;

function Intersect(const Segment1,Segment2:TSegment2D; out ix, iy : TFloat):Boolean;
begin
  Result := Intersect(Segment1[1].x,Segment1[1].y,Segment1[2].x,Segment1[2].y,Segment2[1].x,Segment2[1].y,Segment2[2].x,Segment2[2].y,ix,iy);
end;

只需将TFloat x，y对转换为TPointF即可开展业务。 例程的一个很酷的事情是，它还告诉你线条重叠的确切点。

如果你按照直线，直到两条线重叠并从那里开始跟踪重叠线和PointInShape，你可以构建两个形状重叠的精确图像。

加快速度
如果扁平化和线段数量的相应增加使得代码太慢，则可以保持曲线并查看线/曲线是否与另一条曲线相交。
为此，您可以将曲线转换为bezier curves并使用De_Casteljau's algorithm

更多信息
另请参阅第一个或第二个答案中的this question和link to Delphi source code。