看起来Groovy在这个帖子中被遗忘了所以我只会问Groovy同样的问题。
另见：
答案 0 :(得分：56)
使用点差运算符
def animals = ['ant', 'buffalo', 'canary', 'dog']
assert animals.size() == 4
assert animals*.size() == [3, 7, 6, 3]
这是animals.collect { it.size() }的快捷方式。
答案 1 :(得分：39)
with 方法允许转为：
myObj1.setValue(10)
otherObj.setTitle(myObj1.getName())
myObj1.setMode(Obj1.MODE_NORMAL)
进入这个
myObj1.with {
value = 10
otherObj.title = name
mode = MODE_NORMAL
}
答案 2 :(得分：37)
任何人都知道猫王？
def d = "hello";
def obj = null;
def obj2 = obj ?: d; // sets obj2 to default
obj = "world"
def obj3 = obj ?: d; // sets obj3 to obj (since it's non-null)
答案 3 :(得分：37)
将哈希用作伪对象。
def x = [foo:1, bar:{-> println "Hello, world!"}]
x.foo
x.bar()
结合鸭子打字，你可以用这种方法走很长的路。甚至不需要甩掉“as”操作符。
答案 4 :(得分：35)
找出对象上的方法就像询问metaClass一样简单：
"foo".metaClass.methods.name.sort().unique()
打印：
["charAt", "codePointAt", "codePointBefore", "codePointCount", "compareTo",
"compareToIgnoreCase", "concat", "contains", "contentEquals", "copyValueOf",
"endsWith", "equals", "equalsIgnoreCase", "format", "getBytes", "getChars",
"getClass", "hashCode", "indexOf", "intern", "lastIndexOf", "length", "matches",
"notify", "notifyAll", "offsetByCodePoints", "regionMatches", "replace",
"replaceAll", "replaceFirst", "split", "startsWith", "subSequence", "substring",
"toCharArray", "toLowerCase", "toString", "toUpperCase", "trim", "valueOf", "wait"]
答案 5 :(得分：28)
要拦截缺少的静态方法，请使用以下
Foo {
static A() { println "I'm A"}
static $static_methodMissing(String name, args) {
println "Missing static $name"
}
}
Foo.A() //prints "I'm A"
Foo.B() //prints "Missing static B"
- 肯
答案 6 :(得分：24)
<强>解构
它可能在Groovy中被称为其他东西;它被称为clojure中的解构。你永远不会相信它会变得多么方便。
def list = [1, 'bla', false]
def (num, str, bool) = list
assert num == 1
assert str == 'bla'
assert !bool
答案 7 :(得分：21)
为了使用groovy测试java代码，对象图构建器非常棒：
def company = builder.company( name: 'ACME' ) {
address( id: 'a1', line1: '123 Groovy Rd', zip: 12345, state: 'JV' )
employee( name: 'Duke', employeeId: 1 ){
address( refId: 'a1' )
}
}
标准功能，但仍然非常好。
（您需要提供POJO的任何属性，List是空列表的默认值而不是null，以便构建器支持起作用。）
答案 8 :(得分：19)
println
"""
Groovy has "multi-line" strings.
Hooray!
"""
答案 9 :(得分：15)
与Java不同，在Groovy中，任何东西都可以在 switch 语句中使用，而不仅仅是基本类型。 在典型的 eventPerformed 方法
中switch(event.source) {
case object1:
// do something
break
case object2:
// do something
break
}
答案 10 :(得分：15)
在groovy 1.6中，正则表达式适用于所有闭包迭代器（如每个，收集，注入等），并允许您轻松使用捕获组：
def filePaths = """
/tmp/file.txt
/usr/bin/dummy.txt
"""
assert (filePaths =~ /(.*)\/(.*)/).collect { full, path, file ->
"$file -> $path"
} == ["file.txt -> /tmp", "dummy.txt -> /usr/bin"]
答案 11 :(得分：15)
使用太空飞船运营商
我喜欢Spaceship operator，对各种自定义排序方案都很有用。一些使用示例是here。其中一个特别有用的情况是使用多个字段在对象的动态创建比较器。 e.g。
def list = [
[ id:0, first: 'Michael', last: 'Smith', age: 23 ],
[ id:1, first: 'John', last: 'Smith', age: 30 ],
[ id:2, first: 'Michael', last: 'Smith', age: 15 ],
[ id:3, first: 'Michael', last: 'Jones', age: 15 ],
]
// sort list by last name, then first name, then by descending age
assert (list.sort { a,b -> a.last <=> b.last ?: a.first <=> b.first ?: b.age <=> a.age })*.id == [ 3,1,0,2 ]
答案 12 :(得分：14)
闭包可以使所有旧的尝试终极资源管理游戏消失。文件流在块结束时自动关闭：
new File("/etc/profile").withReader { r ->
System.out << r
}
答案 13 :(得分：13)
GDK groovy.transform包内转换提供的功能，例如：
@Immutable：@Immutable注释指示编译器执行AST转换，该转换添加必要的getter，constructor，equals，hashCode和其他辅助方法，这些方法通常在创建具有已定义属性的不可变类时编写。 / LI>
@CompileStatic：这将让Groovy编译器以Java的风格使用编译时检查，然后执行静态编译，从而绕过Groovy元对象协议。@Canonical：@Canonical注释指示编译器执行AST转换，该转换将位置构造函数，equals，hashCode和漂亮的打印toString添加到您的类中。其他：
@Slf4j此本地转换使用LogBack日志记录为您的程序添加日志记录功能。对名为log的未绑定变量的每个方法调用都将映射到对记录器的调用。答案 14 :(得分：12)
基于闭包的界面实施
如果您有类型参考，例如：
MyInterface foo
您可以使用以下方法实现整个界面：
foo = {Object[] args -> println "This closure will be called by ALL methods"} as MyInterface
或者，如果要单独实现每个方法，可以使用：
foo = [bar: {-> println "bar invoked"},
baz: {param1 -> println "baz invoked with param $param1"}] as MyInterface
答案 15 :(得分：12)
您可以使用toSpreadMap（）将列表转换为地图，方便列表中的顺序足以确定键和与之关联的值。见下面的例子。
def list = ['key', 'value', 'foo', 'bar'] as Object[]
def map = list.toSpreadMap()
assert 2 == map.size()
assert 'value' == map.key
assert 'bar' == map['foo']
答案 16 :(得分：8)
从列表中删除null值
def list = [obj1, obj2, null, obj4, null, obj6]
list -= null
assert list == [obj1, obj2, obj4, obj6]
答案 17 :(得分：7)
class Foo {
def footest() { return "footest"}
}
class Bar {
@Delegate Foo foo = new Foo()
}
def bar = new Bar()
assert "footest" == bar.footest()
答案 18 :(得分：7)
我知道我有点晚了，但我认为这里缺少一些不错的功能：
收集加/减运算符
def l = [1, 2, 3] + [4, 5, 6] - [2, 5] - 3 + (7..9)
assert l == [1, 4, 6, 7, 8, 9]
def m = [a: 1, b: 2] + [c: 3] - [a: 1]
assert m == [b: 2, c: 3]
切换声明
switch (42) {
case 0: .. break
case 1..9: .. break
case Float: .. break
case { it % 4 == 0 }: .. break
case ~/\d+/: .. break
}
范围和索引
assert (1..10).step(2) == [1, 3, 5, 7, 9]
assert (1..10)[1, 4..8] == [2, 5, 6, 7, 8, 9]
assert ('a'..'g')[-4..-2] == ['d', 'e', 'f']
Unicode变量名称
def α = 123
def β = 456
def Ω = α * β
assert Ω == 56088
答案 19 :(得分：6)
文字中的下划线
在编写长文字数字时，更难以弄清楚某些数字是如何组合在一起的，例如数千组，单词等等。通过允许您在数字文字中放置下划线，更容易发现那些团体：
long creditCardNumber = 1234_5678_9012_3456L
long socialSecurityNumbers = 999_99_9999L
double monetaryAmount = 12_345_132.12
long hexBytes = 0xFF_EC_DE_5E
long hexWords = 0xFFEC_DE5E
long maxLong = 0x7fff_ffff_ffff_ffffL
long alsoMaxLong = 9_223_372_036_854_775_807L
long bytes = 0b11010010_01101001_10010100_10010010
答案 20 :(得分：5)
使用隐式参数重新排序参数是另一个不错的选择。
此代码：
def foo(Map m=[:], String msg, int val, Closure c={}) {
[...]
}
创建所有这些不同的方法：
foo("msg", 2, x:1, y:2)
foo(x:1, y:2, "blah", 2)
foo("blah", x:1, 2, y:2) { [...] }
foo("blah", 2) { [...] }
还有更多。将命名和序数参数置于错误的顺序/位置是不可能的。
当然，在“foo”的定义中，你可以从“String msg”和“int val”中取消“String”和“int” - 为了清楚起见，我把它们留下了。
答案 21 :(得分：4)
我认为它是闭包作为参数和参数默认值的组合：
public void buyItems(Collection list, Closure except={it > 0}){
list.findAll(){except(it)}.each(){print it}
}
buyItems([1,2,3]){it > 2}
buyItems([0,1,2])
打印：“312”
答案 22 :(得分：4)
在方法参数中使用展开运算符
将代码转换为数据时，这是一个很好的帮助：
def exec(operand1,operand2,Closure op) {
op.call(operand1,operand2)
}
def addition = {a,b->a+b}
def multiplication = {a,b->a*b}
def instructions = [
[1,2,addition],
[2,2,multiplication]
]
instructions.each{instr->
println exec(*instr)
}
此用法也很有用：
String locale="en_GB"
//this invokes new Locale('en','GB')
def enGB=new Locale(*locale.split('_'))
答案 23 :(得分：3)
<强>记忆化
Memoization是一种优化技术，它包含存储昂贵的函数调用的结果，并在每次使用相同的参数再次调用函数时返回缓存的结果。
有一个无限制的版本，它将缓存它将看到的一对（输入参数，返回值）;和一个限制版本，它将使用LRU缓存缓存看到的最后N个输入参数及其结果。
方法记忆：
import groovy.transform.Memoized
@Memoized
Number factorial(Number n) {
n == 0 ? 1 : factorial(n - 1)
}
@Memoized(maxCacheSize=1000)
Map fooDetails(Foo foo) {
// call expensive service here
}
闭包的记忆：
def factorial = {Number n ->
n == 0 ? 1 : factorial(n - 1)
}.memoize()
fooDetails = {Foo foo ->
// call expensive service here
}.memoizeAtMost(1000)
The Wikipedia page提供有关计算机科学中记忆化用途的广泛信息。我只想指出一个简单的实际用途。
将常量的初始化推迟到最后一刻
有时您有一个常量值，无法在类定义或创建时初始化。例如，常量表达式可以使用另一个常量或来自不同类的方法，这些类将在类初始化之后被其他东西（Spring等）插入。
在这种情况下，您可以将常量转换为getter并使用@Memoized进行修饰。它只会被计算一次，第一次被访问，然后缓存并重用值：
import groovy.transform.Memoized
@Memoized
def getMY_CONSTANT() {
// compute the constant value using any external services needed
}
答案 24 :(得分：2)
动态方法调用
您可以使用名称为
的字符串调用方法class Dynamic {
def one() { println "method one()" }
def two() { println "method two()" }
}
def callMethod( obj, methodName ) {
obj."$methodName"()
}
def dyn = new Dynamic()
callMethod( dyn, "one" ) //prints 'method one()'
callMethod( dyn, "two" ) //prints 'method two()'
dyn."one"() //prints 'method one()'
答案 25 :(得分：2)
如何在groovy中的几行中构建JSON树？
1）使用自引用withDefault闭包
def tree // declare first before using a self reference
tree = { -> [:].withDefault{ tree() } }
2）创建自己的JSON树
frameworks = tree()
frameworks.grails.language.name = 'groovy'
frameworks.node.language.name = 'js'
def result = new groovy.json.JsonBuilder(frameworks)
给出：{"grails":{"language":{"name":"groovy"}},"node":{"language":{"name":"js"}}}
答案 26 :(得分：2)
Groovy可以像Javascript一样工作。您可以通过关闭拥有私有变量和函数。 你也可以用闭包来理解函数。
class FunctionTests {
def privateAccessWithClosure = {
def privVar = 'foo'
def privateFunc = { x -> println "${privVar} ${x}"}
return {x -> privateFunc(x) }
}
def addTogether = { x, y ->
return x + y
}
def curryAdd = { x ->
return { y-> addTogether(x,y)}
}
public static void main(String[] args) {
def test = new FunctionTests()
test.privateAccessWithClosure()('bar')
def curried = test.curryAdd(5)
println curried(5)
}
}
输出：
foo吧 10答案 27 :(得分：2)
安全导航操作员
安全导航操作符用于避免NullPointerException。通常，在引用对象时，可能需要在访问对象的方法或属性之前验证它是否为null。为了避免这种情况，安全导航操作符将只返回null而不是抛出异常，如下所示：
def person = Person.find { it.id == 123 } // find will return a null instance
def name = person?.name // use of the null-safe operator prevents from a NullPointerException, result is null
答案 28 :(得分：1)
1）单行
中的多个变量声明def (a,b,c) = [1,2,3]
2）使用不同的类型声明。
def (String a, int b) = ['Groovy', 1]
答案 29 :(得分：0)
＆＃34; Elvis运营商＆＃34; 是三元运营商的缩短。这个方便的一个例子是返回一个明智的默认值＆＃39;表达式解析为false时的值（如在Groovy中）。一个简单的例子可能如下所示：
使用三元运算符，您必须重复要分配的值
displayCity = user.city ? user.city: 'UnKnown City'
使用Elvis运算符，如果它不是假的话，则使用测试的值
displayCity = user.city ?: 'UnKnown City'
答案 30 :(得分：0)
强制算子（as）是铸造的变体。强制将对象从一种类型转换为另一种类型而不兼容赋值。我们来举个例子：
整数x = 123
String s =（String）x
Integer不能赋值给String，因此会在运行时产生ClassCastException
这可以通过使用强制来修复：
整数x = 123
String s = x as String
整数不能赋予String，但使用as会将其强制转换为String