Question

这是我家庭作业中的一个问题，因此提示很可能会受到赞赏。

本学期我正在学习 Haskell ，我的第一个作业要求我编写一个输入2个字符串（string1和string2）的函数，并返回一个组成的字符串第一个字符串string1的（重复的）字符，直到创建了与string2相同长度的字符串。

我只能使用 Prelude 函数length。

例如：将string1 "Key"和我的名字"Ahmed"作为string2，该函数应返回"KeyKe"。

这是我到目前为止所得到的：

    makeString :: Int -> [a] -> [a]
    makeString val (x:xs)
        | val > 0 = x : makeString (val-1) xs
        | otherwise = x:xs

而不是直接给它两个字符串我给它一个整数值（因为我可以稍后将其替换为长度），但这给了我一个运行时错误：

*Main> makeString 8 "ahmed"

"ahmed*** Exception: FirstScript.hs: (21,1)-(23,21) : Non-exhaustive patterns in function makeString

我认为我的列表可能会耗尽并成为空列表（？）。

非常感谢一点帮助。

Answer 1

我认为这段代码足以解决您的问题：

extend :: String -> String -> String
extend src dst = extend' src src (length dst)
    where
        extend' :: String -> String -> Int -> String
        extend' _ _ 0 = []
        extend' [] src size = extend' src src size
        extend' (x:xs) src size  = x : extend' xs src (size - 1)

extend'函数会循环第一个字符串，直到消耗掉然后再开始消耗它。

您也可以使用take和cycle之类的功能：

repeatString :: String -> String
repeatString x = x ++ repeatString x

firstN :: Int -> String -> String
firstN 0 _ = []
firstN n (x:xs) = x : firstN ( n - 1 ) xs

extend :: String -> String -> String
extend src dst = firstN (length dst) (repeatString src)

或更通用的版本

repeatString :: [a] -> [a]
repeatString x = x ++ repeatString x

firstN :: (Num n, Eq n ) => n -> [a] -> [a]
firstN 0 _ = []
firstN n (x:xs) = x : firstN ( n - 1 ) xs

extend :: [a] -> [b] -> [a]
extend _ [] = error "Empty target"
extend [] _ = error "Empty source"
extend src dst = firstN (length dst) (repeatString src)

能够采用任何类型的列表：

>extend [1,2,3,4] "foo bar"
[1,2,3,4,1,2,3]

Answer 2

像卡斯滕说的那样，你应该

处理列表为空的情况
删除列表末尾的第一个元素。
当n为0或更低时返回空列表

例如：

makeString :: Int -> [a] -> [a]
makeString _ [] = []    -- makeString 10 "" should return ""
makeString n (x:xs)
    | n > 0 = x:makeString (n-1) (xs++[x])
    | otherwise = []    -- makeString 0 "key" should return ""

在ghci中尝试这个：

>makeString (length "Ahmed") "Key"
"KeyKe"

Answer 3

^{注意：这个答案写在literate Haskell中。将其保存为Filename.lhs并在GHCi中尝试。}

我认为length在这种情况下是red herring。您可以通过递归和模式匹配来解决这个问题，这甚至可以在非常长的列表上工作。但首先要做的事情。

我们的功能应该是什么类型？我们正在接受两个字符串，我们将一遍又一遍地重复第一个字符串，这听起来像String -> String -> String。但是，这个＆＃34;一遍又一遍地重复＆＃34;对于字符串来说，事情并不是唯一的：你可以用各种列表做到这一点，所以我们选择以下类型：

> repeatFirst :: [a] -> [b] -> [a]
> repeatFirst as bs = go as bs

好的，到目前为止没有任何花哨的事情发生，对吧？我们根据repeatFirst定义go，但仍然缺失。在go中，我们希望将bs的项目与as的相应项目进行交换，因此我们已经知道基本情况，即如果bs为空，应该会发生什么：

>    where go  _     []     = []

如果bs不是空的，该怎么办？在这种情况下，我们希望使用as中的正确项目。所以我们应该同时遍历两者：

>          go (x:xs) (_:ys) = x : go xs ys

我们目前正在处理以下情况：清空第二个参数列表和非空列表。我们仍然需要处理空的第一个参数列表：

>          go []     ys     =

在这种情况下会发生什么？好吧，我们需要重新开始as。事实上，这有效：

>                              go as ys

这里的所有内容再次出现在一个地方：

repeatFirst :: [a] -> [b] -> [a]
repeatFirst as bs = go as bs
   where go  _     []     = []
         go (x:xs) (_:ys) = x : go xs ys
         go []     ys     =     go as ys

请注意，如果您没有约束，则可以使用cycle，zipWith和const：

repeatFirst :: [a] -> [b] -> [a]
repeatFirst = zipWith const . cycle

但这可能是另一个问题。

执行一个程序，其中字符串的字符在haskell中重复某些时间

3 个答案: