Question

我正在尝试在Idris中编写一个函数，通过传递Vect的大小和在参数中取索引的函数来创建Vect。到目前为止，我有这个：

import Data.Fin
import Data.Vect

generate: (n:Nat) -> (Nat -> a) ->Vect n a
generate n f = generate' 0 n f where
  generate': (idx:Nat) -> (n:Nat) -> (Nat -> a) -> Vect n a
  generate' idx Z f = []
  generate' idx (S k) f = (f idx) :: generate' (idx + 1) k f

但我想确保参数中传递的函数仅采用小于Vect大小的索引。我试过了：

generate: (n:Nat) -> (Fin n -> a) ->Vect n a
generate n f = generate' 0 n f where
  generate': (idx:Fin n) -> (n:Nat) -> (Fin n -> a) -> Vect n a
  generate' idx Z f = []
  generate' idx (S k) f = (f idx) :: generate' (idx + 1) k f

但它没有编译错误

    Can't convert
            Fin n
    with
            Fin (S k)

我的问题是：我想做什么以及如何做？

Answer 1

关键的想法是，向量的第一个元素是f 0，对于尾部，如果你有k : Fin n，则FS k : Fin (S n)是＆＃34; shift＆＃34 ;有限数的同时增加其值及其类型。

使用此观察，我们可以将generate重写为

generate : {n : Nat} -> (f : Fin n -> a) -> Vect n a
generate {n = Z} f = []
generate {n = S _} f = f 0 :: generate (f . FS)

另一种可能性是做@dfeuer建议并生成Fin s的向量，然后将f映射到它上面：

fins : (n : Nat) -> Vect n (Fin n)
fins Z = []
fins (S n) = FZ :: map FS (fins n)

generate' : {n : Nat} -> (f : Fin n -> a) -> Vect n a
generate' f = map f $ fins _

证明generate f = generate' f是留给读者的练习。

Answer 2

Cactus的答案似乎是获得你所要求的最佳方式，但是如果你想要一些可以在运行时使用的东西，它将是非常低效的。这样做的根本原因是，将Fin n弱化为Fin n+m要求您完全解构它以更改其FZ的类型，然后再将其重新构建。因此，为每个向量元素生成的Fin值之间根本不存在共享。另一种方法是将Nat与证据表明它低于给定的界限，从而导致擦除的可能性：

data NFin : Nat -> Type where
  MkNFin : (m : Nat) -> .(LT m n) -> NFin n

lteSuccLeft : LTE (S n) m -> LTE n m
lteSuccLeft {n = Z} prf = LTEZero
lteSuccLeft {n = (S k)} {m = Z} prf = absurd (succNotLTEzero prf)
lteSuccLeft {n = (S k)} {m = (S j)} (LTESucc prf) = LTESucc (lteSuccLeft prf)

countDown' : (m : Nat) -> .(m `LTE` n) -> Vect m (NFin n)
countDown' Z mLTEn = []
countDown' (S k) mLTEn = MkNFin k mLTEn :: countDown' k (lteSuccLeft mLTEn)

countDown : (n : Nat) -> Vect n (NFin n)
countDown n = countDown' n lteRefl

countUp : (n : Nat) -> Vect n (NFin n)
countUp n = reverse $ countDown n

generate : (n : Nat) -> (NFin n -> a) -> Vect n a
generate n f = map f (countUp n)

与Fin方法一样，传递给generate的函数不需要处理所有自然;它只需要处理小于n的那些。

我使用NFin类型明确指出我希望在所有情况下都删除LT m n证明。如果我不想/不需要，我可以改用(m ** LT m n)。

在Idris中，如何编写一个“vect生成器”函数，该函数在参数中采用索引函数

2 个答案: