Question

我已经处理了这个问题几天了，我没有想法，希望你能帮助我：

我的令牌列表如下：

%Token
var       {TokenVariableDeclaration}
varId     {TokenVar $$} -- Strings like "x", "n" or "m"
int       {TokenInt $$}

我的语法规则如下：

VariablesList : var varId ';'                   {VariablesList [($2,ArithmeticInt 0)]}
              | var varId ',' VariablesList     {VariablesList (($2,ArithmeticInt 0):$4)}

ArithmeticExpression : int {ArithmeticInt $1}

它只是定义了一个变量列表，就像你在命令式编程语言中找到的那样（在这种给定的语言中，变量只能被赋予整数）：

var n,m,x;

我的词法分析器（文件的Haskell部分）具有以下数据类型：

data VariablesList = VariablesList [(String,ArithmeticExpression)] deriving (Show, Eq)
data ArithExpression = ArithInt Int deriving (Show, Eq)

因此，在解析之后，我可以获得所有声明的变量列表，使用数据“ArithmeticInt 0”进行初始化：

VariablesList [("n",ArithmeticInt 0),("m",ArithmeticInt 0),("x",ArithmeticInt 0)]

当我在提示符上运行'happy'命令时，一切都很好：

C:> happy "myParser.y"

但是当我在GHCI上加载生成的.hs文件时：

Prelude> :l "myParser.hs"

我收到一个广泛的错误，指出类型VariablesList无法与[(String,ArithmeticExpression)]类型匹配。我知道，由于我所做的测试不同，问题出现在VariablesList语法规则的第二种模式上：

VariablesList : var varId ';'                   {VariablesList [($2,ArithmeticInt 0)]}
              | var varId ',' VariablesList     {VariablesList (($2,ArithmeticInt 0):$4)}

巧妙地 ($2,ArithmeticInt 0):$4 部分。我对Haskell很新，我能理解的是，第四个参数（$ 4）的类型为VariablesList，类型(String,ArithmeticExpression)不能连接（:)。

非常欢迎任何形式的帮助或指导:)。

编辑：通过请愿，这是一个最小的工作快乐文件：

{  
module HappyLambdaSyntax4 where  
import Data.Char
import System.IO
}

%name parse VariablesList
%tokentype {Token}
%error {parseError}

%token
var       {TokenVariableDeclaration}
varId     {TokenVar $$} -- Strings like "x", "n" or "m"
int       {TokenInt $$}
';'       {TokenPuntoYComa}
','       {TokenComa}

%%

VariablesList : var varId ';'                         {VariablesList [($2,ArithmeticInt 0)]} -- var n;
              | var varId ',' varId ';'               {VariablesList (($2,ArithmeticInt 0):[($4,ArithmeticInt 0)])} --var n,m;
              | var varId ',' varId ',' varId ';'     {VariablesList (($2,ArithmeticInt 0):[($4,ArithmeticInt 0),($6,ArithmeticInt 0)])} --var n,m,x;
              -- var varId ',' VariablesList          {VariablesList (($2,ArithmeticInt):$4)} Ideal solution. Recursive. Does not work.

ArithmeticExpression : int {ArithmeticInt $1}

{
parseError :: [Token] -> a
parseError _ = error ("Parse error.")

data ArithmeticExpression = ArithmeticInt Int deriving (Show, Eq)
data VariablesList = VariablesList [(String,ArithmeticExpression)] deriving (Show, Eq)

data Token = TokenVariableDeclaration
           | TokenVar String
           | TokenInt Int
           | TokenPuntoYComa
           | TokenComa
           deriving (Show, Eq)

lexer :: String -> [Token]
lexer [] = []
lexer (c:cs)
    | isSpace c = lexer cs
    | isDigit c = lexNum (c:cs)
    | isAlpha c = lexVar (c:cs)
    | c == ';' = TokenPuntoYComa : (lexer cs)
    | c == ',' = TokenComa : (lexer cs)
    | otherwise = error ("Lexer error.")

lexNum cs = TokenInt (read num) : lexer rest
    where (num,rest) = span isDigit cs

lexVar cs =
    case span isAlpha cs of
    ("var",rest) -> TokenVariableDeclaration : lexer rest
    (var,rest) -> TokenVar var : lexer rest
}

使用以下命令运行：

>happy "file.y"

然后，在GHCI中，加载：

Prelude> :l file.hs

最后，测试一下：

Prelude> parse (lexer "var n,m,x;")

或任何少于3个变量的列表。

Answer 1

首先：当你启动happy时，它会生成一个Haskell文件，但不会编译它。因此happy 不检查您插入的haskell代码是否有效。之后在编译文件时就完成了。您看到的行为是预期的。

现在的问题是你的规则是：

var varId ',' VariablesList     {VariablesList (($2,ArithmeticInt 0):$4)}

$4指的是VariablesList但:的类型a -> [a] -> [a]不是(String, ArithmeticExpression) -> VariablesList -> VariablesList。 $4 不会引用VariablesList中包含的列表。

您需要的是一种连接VariablesList的方法，例如：

x <:> (VariablesList xs) = VariablesList (x:xs)

并使用规则：

var varId ',' VariablesList     {($2,ArithmeticInt 0) <:> $4}

建议：happy允许您定义parametrized productions。通常使用这些规则可以更好地处理列表。

例如，您可以定义一个表示带有分隔符的列表的作品：

rev_list_sep(p, sep) : p                           {[$1]}
                     | rev_list_sep(p, sep) sep p  {$3 : $1}

并将其用作：

VarDecl : var varId
VariablesList : rev_list_sep(VarDecl, ',') ';'   {VariablesList (reverse $1)}

^{（未经测试，只是为了提出一个想法）。}

请注意，您可以重复使用此类产品来定义其他列表：

SomeOtherList : rev_list_sep(SomethingElse, ';')  {Whatever (reverse $1)}

数据类型与Haskell解析器生成器不匹配 - 快乐

1 个答案: