Question

有没有办法调整自定义元素的大小以适应它的内容？我在QML上写了一些按钮示例，但是如果在main.qml中没有定义大小，我需要每次播放场景时调整文本长度。抱歉，但无法通过网络找到有关该内容的内容，只反向询问如何使内容适合父级。有一个消息来源：

BreezeButton.qml

import QtQuick 2.2
Item {
    id: root
    width: 172
    height: 72
    property string caption: "Button"
    property string iconSource: null
    signal clicked
    Rectangle {
        id: body
        border {
            width: 2
            color: "#808e8e"
        }
        anchors{
            fill: parent
        }
        gradient: Gradient {
            id: bodyGradient
            GradientStop { position: 0.4; color: "#4d4d4d" }
            GradientStop { position: 0.9; color: "#31363b" }
        }
        MouseArea{
            id: bodyMouseArea
            z: bodyText.z + 1
            anchors {
                fill: parent
            }

            hoverEnabled: true
            onEntered: {
                body.border.color = "#3daee9"

            }
            onExited: {
                body.border.color = "#7f8c8d"
            }
            onPressed: {
                body.color = "#3daee9"
                body.gradient = null
            }
            onReleased: {
                body.color = "#4d4d4d"
                body.gradient = bodyGradient
            }
            onClicked: {
                root.clicked()
            }
        }
        Text {
            id: bodyText
            anchors {
                top: body.top
                bottom: body.bottom
                left: icon.right
            }
            width: body.width - icon.width
            font.pointSize: 14
            color: "#fcfcfc"
            text: caption
            verticalAlignment: Text.AlignVCenter
            horizontalAlignment: Text.AlignHCenter
        }
        Image {
            id: icon
            source: iconSource
            anchors {
                left: body.left
                top: body.top
                bottom: body.bottom
                leftMargin: 5
                topMargin: 5
                bottomMargin: 5
            }
            height: root.height - 8
            width: icon.height
            sourceSize.width: icon.width
            sourceSize.height: icon.height
        }
    }
}

例如，基本的QML按钮可以调整每次播放的场景的大小以适应它的文本长度。

Answer 1

利用Qt是开源的这一事实是件好事。几乎所有关于如何实现Qt所做的事情的知识都可以通过在代码库中弄清楚来找到。你提到了Qt Quick Controls的Button类型，所以看看它会有所帮助。

仅通过Button.qml搜索会显示菜单宽度和高度的结果，这对我们没用。

让我们看看它的基本类型：BasicButton。也没有提到宽度或高度。

如果您熟悉Qt Quick Controls，您会记住控件通常具有相关的样式，这些样式中的组件通常决定控件的大小，这与您想要实现的非常相似。

但是我们假设你不熟悉它，因为它仍然可以找到你想知道的东西，你只需要有更多的耐心。所以，现在是转到控制台并在git grep Button中运行qt5/qtquickcontrols的好时机。如果你这样做，你会得到很多结果。我不打算通过所有这些，因为这是练习的重点：提高你找到你想要的东西的能力。但是，您将看到的许多结果与Button没有直接关系。

我们还假设您完成了结果并发现了ButtonStyle.qml个匹配项。这些是我们听起来很有趣的唯一结果，因此打开该文件。查看组件，我们会看到background和label。请注意，他们都指定implicitWidth和implicitHeight ......有趣。阅读以下文档：

如果未指定宽度或高度，则定义Item的自然宽度或高度。

...

设置隐式大小对于根据内容定义具有首选大小的组件非常有用，例如：

// Label.qml
import QtQuick 2.0

Item {
    property alias icon: image.source
    property alias label: text.text
    implicitWidth: text.implicitWidth + image.implicitWidth
    implicitHeight: Math.max(text.implicitHeight, image.implicitHeight)
    Image { id: image }
    Text {
        id: text
        wrapMode: Text.Wrap
        anchors.left: image.right; anchors.right: parent.right
        anchors.verticalCenter: parent.verticalCenter
    }
}

我们已经非常了解现在该做什么，但让我们通过了解Button的组件are used来确认它：

/*! \internal */
property Component panel: Item {
    anchors.fill: parent
    implicitWidth: Math.max(labelLoader.implicitWidth + padding.left + padding.right, backgroundLoader.implicitWidth)
    implicitHeight: Math.max(labelLoader.implicitHeight + padding.top + padding.bottom, backgroundLoader.implicitHeight)
    baselineOffset: labelLoader.item ? padding.top + labelLoader.item.baselineOffset : 0

    Loader {
        id: backgroundLoader
        anchors.fill: parent
        sourceComponent: background
    }

    Loader {
        id: labelLoader
        sourceComponent: label
        anchors.fill: parent
        anchors.leftMargin: padding.left
        anchors.topMargin: padding.top
        anchors.rightMargin: padding.right
        anchors.bottomMargin: padding.bottom
    }
}

这里反复出现的主题是implicitWidth和implicitHeight，我们可以通过查看代码来推断出这一点。当然，如果你不熟悉代码需要更长的时间，但是你做的越多，就越容易，特别是在特定框架的环境中。

QtQuick 2 - 自定义元素，如何调整根对象的大小？

1 个答案: