Question

我有一个集合（或列表或序列或矢量）的地图，如下所示：

{ :name "Bob", :data [32 11 180] }
{ :name "Joe", :data [ 4  8  30] }
{ :name "Sue", :data [10  9  40] }

我想创建包含向量＆＃34;列＆＃34;中的数据的新向量。与描述数据的键相关联，如下所示：

{ :ages [32 4 10], :shoe-sizes [11 8 9], :weights [180 30 40] }

实际上，一个简单的向量列表可能就足够了，即：

[32 4 10] [11 8 9] [180 30 40]

如果将原始列表变为矢量更好/更容易，那就没问题了;无论什么都是最简单的。

Answer 1

鉴于

(def records
  [{:name "Bob" :data [32 11 180]}
   {:name "Joe" :data [ 4  8  30]}
   {:name "Sue" :data [10  9  40]}])

您可以进行下一次转换以获得所需的结果：

(->> records
     (map :data) ; extract :data vectors 
     ; => ([32 11 180] [4 8 30] [10 9 40])
     (apply map vector) ; transpose
     ; => ([32 4 10] [11 8 9] [180 30 40])
     (zipmap [:ages :shoe-sizes :weights])) ; make map 
     ; => {:weights [180 30 40], :shoe-sizes [11 8 9], :ages [32 4 10]}

没有评论，它看起来有点清洁：

(->> records 
     (map :data)
     (apply map vector)
     (zipmap [:ages :shoe-sizes :weights]))

没有threading宏，它等同于更详细：

(let [extracted (map :data records)
      transposed (apply map vector extracted)
      result (zipmap [:ages :shoe-sizes :weights] transposed)]
  result)

Answer 2

您可以像这样使用reduce：

(def data [{ :name "Bob", :data [32 11 180] }
           { :name "Joe", :data [ 4  8  30] }
           { :name "Sue", :data [10  9  40] }])

(reduce 
  (fn [acc {[age shoe-size weight] :data}]
    (-> acc
      (update-in [:ages] conj age)
      (update-in [:shoe-sizes] conj shoe-size)
      (update-in [:weights] conj weight)))
{}
data)

返回如下内容：

{:weights (40 30 180), :shoe-sizes (9 8 11), :ages (10 4 32)}

我认为这段代码最有趣的部分是使用嵌套解构来抓住键：{[age shoe-size weight] :data}

在Clojure中将矢量图转换为列矢量

2 个答案: