Question

我是编程新手，F＃是我的第一语言。

以下是我的代码的相关部分：

let rec splitArrayIntoGroups (inputArray: string[]) (groupSize: int) (hashSetOfGroups: HashSet<string[]>)=
    let startIndex = 0
    let endIndex = groupSize - 1

    let group = inputArray.[startIndex .. endIndex]
    let nextInputArray = inputArray.[groupSize .. inputArray.Length - 1]

    hashSetOfGroups.Add(group) |> ignore
    splitArrayIntoGroups nextInputArray groupSize hashSetOfGroups

let hashSetOfGroups = new HashSet<string[]>()

splitArrayIntoGroups urlArray 10 hashSetOfGroups

urlArray是一个包含近3200个网址的数组。

当我尝试在F＃interactive中运行代码时，收到以下错误消息：

Program.fs（119,1）：错误FS0030：值限制。价值'它'有被推断为具有泛型类型 val it：'_ a将'it'定义为一个简单的数据术语，使其成为具有显式参数的函数，或者，如果您不打算将其用于是通用的，添加一个类型注释。

出了什么问题，我应该做出哪些改变？

Answer 1

目前，代码将无限循环。什么是退出条件？正如@Petr指出的那样，函数会返回什么？

以下是当inputArray为空时退出并返回单位的版本：

let rec splitArrayIntoGroups (inputArray: string[]) (groupSize: int) (hashSetOfGroups: HashSet<string[]>)=

    match inputArray with
    | [||] -> ()
    | _ ->
        let startIndex = 0
        let endIndex = groupSize - 1
        let group = inputArray.[startIndex .. endIndex]
        let nextInputArray = inputArray.[groupSize .. inputArray.Length - 1]

        hashSetOfGroups.Add(group) |> ignore
        splitArrayIntoGroups nextInputArray groupSize hashSetOfGroups

不是使用可变集合，更惯用的方法是使用F＃Set类型，然后将新版本传递给每个递归，如下所示：

let rec splitArrayIntoGroups2 inputArray groupSize hashSetOfGroups =

    match inputArray with
    | [||] -> hashSetOfGroups 
    | _ ->
        let startIndex = 0
        let endIndex = groupSize - 1
        let group = inputArray.[startIndex .. endIndex]
        let nextInputArray = inputArray.[groupSize .. inputArray.Length - 1]

        let newSet = Set.add group hashSetOfGroups
        splitArrayIntoGroups2 nextInputArray groupSize newSet

不过，现在的逻辑似乎是索引逻辑的错误。如果我尝试以下内容：

let urlArray = [| "a"; "b"; "c"; "d" |]
let result = splitArrayIntoGroups2 urlArray 10 Set.empty

然后我得到IndexOutOfRangeException。

你的意思是这样吗？

let rec splitArrayIntoGroups3 inputArray startIndex groupSize hashSetOfGroups =

    let maxIndex = Array.length inputArray - 1
    if startIndex > maxIndex  then
        hashSetOfGroups 
    else
        let endIndex = min (startIndex + groupSize - 1) maxIndex 
        let group = inputArray.[startIndex .. endIndex]
        let newSet = Set.add group hashSetOfGroups

        let nextStartIndex = endIndex + 1
        splitArrayIntoGroups3 inputArray nextStartIndex groupSize newSet 

let urlArray = [| "a"; "b"; "c"; "d"; "e"  |]
let result = splitArrayIntoGroups3 urlArray 0 2 Set.empty

请注意，此最终版本适用于任何类型的数组，而不仅仅是字符串数组。

F＃：错误FS0030：值限制

1 个答案: