Question

如何在XSLT中找到文本节点中另一个已知单词之前和之后的单词？

Answer 1

<强>予。在XSLT 2.x / XPath 2.x中，可以使用函数tokenize()和index-of()通过单行XPath表达式生成所需的结果：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:param name="pWord" select="'three'"/>

 <xsl:template match="text()">
   <xsl:sequence select=
    "tokenize(., ',\s*')
        [index-of(tokenize(current(), ',\s*'), $pWord) -1]"/>

   <xsl:sequence select=
    "tokenize(., ',\s*')
        [index-of(tokenize(current(), ',\s*'), $pWord) +1]"/>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于以下XML文档：

<t>One, two, three, four</t>

产生了想要的正确结果：

two four

<强> II。 XSLT 1.0解决方案

可以使用 FXSL 的strSplit-to-Words模板在XSLT 1.0中解决相同的任务。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
>
   <xsl:import href="strSplit-to-Words.xsl"/>

   <xsl:output method="text"/>

   <xsl:param name="pWord" select="'three'"/>

    <xsl:template match="/">
      <xsl:variable name="vrtfwordNodes">
        <xsl:call-template name="str-split-to-words">
          <xsl:with-param name="pStr" select="/"/>
          <xsl:with-param name="pDelimiters" 
                          select="', &#9;&#10;&#13;'"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:variable name="vwordNodes"
         select="ext:node-set($vrtfwordNodes)/*"/>

      <xsl:variable name="vserchWordPos" select=
      "count($vwordNodes
                 [. = $pWord]/preceding-sibling::*
             ) +1"/>

      <xsl:value-of select=
       "concat($vwordNodes[$vserchWordPos -1],
               ' ',
               $vwordNodes[$vserchWordPos +1]
               )
       "/>
    </xsl:template>
</xsl:stylesheet>

将此转换应用于同一XML文档：

<t>One, two, three, four</t>

产生了想要的正确结果：

two four

XSLT在另一个单词附近找到单词

1 个答案: