Question

我需要能够转换这个XML：

<Root>
  <Fields>
    <Field ID="XYZ" Value="M" />
    <Field ID="XYZ.DECODED" Value="Male" />    
    <Field ID="ABC.DECODED" Value="Yellow" />
    <Field ID="ABC" Value="Y" />
    <Field ID="123.DECODED" Value="Low" />
    <Field ID="456" Value="Smith" />
    <Field ID="123" Value="1" />    
  </Fields>
</Root>

进入这个XML：

<Root>
  <Fields>
    <Field ID="XYZ" Value="M" DisplayValue="Male" />
    <Field ID="ABC" Value="Y" DisplayValue="Yellow" />
    <Field ID="456" Value="Smith" DisplayValue="Smith" />
    <Field ID="123" Value="1" DisplayValue="Low" />
  </Fields>
</Root>

使用XSLT。我不会提前知道＆＃34; XYZ＆＃34;，＆＃34; ABC＆＃34;，＆＃34; 123＆＃34;等ID属性。有什么想法？我是否需要从变量创建XPATH表达式？

Answer 1

这就是你想要的

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Field">
        <xsl:variable name="ref" select="concat(@ID,'.DECODED')"/>
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:attribute name="DisplayValue"><xsl:value-of select="//Field[@ID=$ref]/@Value"/></xsl:attribute>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Field[contains(@ID,'.DECODED')]"/>

</xsl:stylesheet>

它是一个标识转换加上两个模板，一个用于消除.DECODED属性中ID的Field节点，另一个用于复制所需的节点并添加值。

Answer 2

我添加了一些内容来为没有.DECODED值的元素添加DisplayValue。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Field">
    <xsl:variable name="ref" select="concat(@ID,'.DECODED')"/>
    <xsl:copy>
      <xsl:variable name="dv">
        <xsl:choose>
          <xsl:when test="//Field[@ItemOID=$ref]/@Value">
            <xsl:value-of select="//Field[@ItemOID=$ref]/@Value"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="@Value"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:variable>
      <xsl:apply-templates select="@*"/>
      <xsl:attribute name="DisplayValue">
        <xsl:value-of select="$dv"/>
      </xsl:attribute>
    </xsl:copy>    
  </xsl:template>
  <xsl:template match="Field[contains(@ID,'.DECODED')]"/>
</xsl:stylesheet>

在XSLT中使用另一个变量值查找属性

2 个答案: