Question

我有一个基于Starman的服务器 -

#!/usr/bin/perl
use strict;
use warnings;
use Data::Printer;
use Plack::Builder;

my $app = sub {
    my $env = shift;
    my $session = $env->{'psgix.session'};

    # Print environment variables
    p($env);

    return [
        200,
        [ 'Content-Type' => 'text/plain' ],
        [ "Hello, you've been here for ", $session->{counter}++, "th   time!" ],
    ];
};

my $default = sub {
    my $env = shift;
    p($env);
    return [
        '200', [ 'Content-Type' => 'text/html' ],
        ["Welcome to default page"],
    ];
};

builder {
    mount "/validate" => builder {
        enable "Middleware::Authentication"
        enable "Session";
        $app;
    };
    mount "/" => builder { $default };
};

我自己的中间件＆＃34;身份验证＆＃34;验证用户并返回会话管理的会话信息（到期时间，会话密钥等），那么如何在会话中间件中使用这些信息呢？

Answer 1

如果我理解正确，那么问题只是中间件的顺序。在Session之前启用Auth。

使用文件存储检查以下内容，会话将持久存储。尝试一下，重新启动Starman，然后重新加载计数器。（我使用内联中间件替代Authentication。）

#!/usr/bin/env perl
use strict;
use warnings;
use Data::Printer;
use Plack::Builder;

my $app = sub {
    my $env = shift;
    my $session = $env->{'psgix.session'};
    return [
        200,
        [ 'Content-Type' => 'text/html' ],
        [
            "My app page is visited ",
            $session->{counter}++,
            "th times! Validation is done at:",
            $session->{mwaretime},
            q{<br><a href="/validate">go validate again</a> --- <a href="/">reload this page</a>}
        ],
    ];
};

my $validate = sub {
    my $env = shift;
    my $session = $env->{'psgix.session'};
    $session->{counter} = 0;
    return [
        '200', [ 'Content-Type' => 'text/html' ],
        [
            "Resetting the counter:",
            $session->{counter},
             ". Time from middleware: ",
            $session->{mwaretime},
            q{<br> <a href="/validate">reload this page</a> --- <a href="/">go to index</a> }
        ],
    ];
};

builder {
    #the session will be stored persistently
    #enable the Session BEFORE your middleware
    enable 'Session', store => 'File';

    mount "/validate" => builder {
        #enable "Authentication";
        #following is same as an middleware
        enable sub {
            my $app = shift;
            return sub {
                my $env = shift;
                my $session = $env->{'psgix.session'};
                $session->{mwaretime} = time();
                $app->($env);
            };
        };
        #end of the middleware
        $validate;
    };
    mount "/" => $app 
};

Answer 2

从您的问题来看，很难说出您的要求究竟是什么样的。但是如果你想要对会话管理进行这么多的控制，那么编写自己的中间件可能会更好。也就是说，有一些方法可以使Plack::Middleware::Session适应某些情况。但是大多数人都使用或多或少的无证功能。这意味着您必须熟悉源代码，并且这些功能可能会在以后的版本中更改或消失。

如果您想提供自己的会话密钥，可以将自定义SID生成器和验证器传递给Plack::Session::State：

enable 'Session',
    state => Plack::Session::State->new(
        sid_generator => $my_generator,
        sid_validator => $my_validator,
    );

sid_generator的{{3}}基本上表示＆＃34;只是阅读了来源＆＃34;。

您还可以实施自己的documentation后端。但在这种情况下，切换到自定义解决方案可能更有意义。

关于Cookie过期时间，您可以在创建新Cookie之前在expires 中设置$env->{'psgix.session.options'}选项：

$env->{'psgix.session.options'}{expires} = $my_expires;

这不是超时，而是自UNIX纪元以来的秒数，或Plack::Session::Store接受的任何值。

如果您的身份验证中间件确实必须生成会话密钥，也许您应该重新考虑。就像@jm666所说，你通常在认证之前运行会话中间件。然后您的身份验证代码可以访问所有会话信息。会话ID通常是会话管理的实现细节，不必涉及代码的其他部分。要更改到期时间，请参阅Cookie::Baker。

你如何使用Plack :: Middleware :: Session与Starman Server？

2 个答案: