Question

在尝试编译语法时，我得到2个shift / reduce错误：

program : declaration_list ;
declaration_list : declaration_list declaration | declaration ;
declaration : var_declaration | fun_declaration ; 

var_declaration: type_specifier var_decl_list ;
scoped_var_declaration: scoped_type_specifier var_decl_list;
var_decl_list : var_decl_list "," var_decl_initialize | var_decl_initialize ;
var_decl_initialize : var_decl_id ;
var_decl_id : ID | ID "[" INT_NUM "]" ;
scoped_type_specifier : type_specifier;
type_specifier: INT | CHAR ;
fun_declaration: type_specifier ID "(" params ")" statement | ID "(" params ")" statement ;
params : | param_list ;
param_list: param_list ";" param_type_list | param_type_list ;
param_type_list : type_specifier param_id_list ; 
param_id_list : param_id_list "," param_id | param_id ; 
param_id : ID | ID "[" "]" ;


statement: expression_stmt | compound_stmt | selection_stmt | iteration_stmt | return_stmt | break_stmt ;

compound_stmt : "{" local_declaration statement_list "}" ;
local_declaration : | local_declaration scoped_var_declaration ;
statement_list : | statement_list statement ;
expression_stmt : expression ";" | ";" ;
selection_stmt : "if" "(" simple_expression ")" statement | "if" "(" simple_expression ")" statement "else" statement ;
iteration_stmt: "while" "(" simple_expression ")" statement ;
return_stmt : "return" ";" | "return" expression ;
break_stmt : "break" ;


expression : mutable ASSIGN expression | mutable EINC expression | mutable EDEC expression | mutable INC | mutable DEC | simple_expression ;

simple_expression: simple_expression OR and_expression | and_expression ; 

and_expression: and_expression AND unary_rel_expression | unary_rel_expression ;

unary_rel_expression: "!" unary_rel_expression | rel_expression ;

rel_expression : sum_expression relop sum_expression | sum_expression ;

relop: "<" | ">" | LE | GE | COMP_OP | NE ;

sum_expression : sum_expression sumop term | term ; 

sumop : ADD | SUB ;

term: term mulop unary_expression | unary_expression ;

mulop: MULT | DIV | REM ;

unary_expression : unaryop unary_expression | factor ;

unaryop : "-" | "*" ;

factor : immutable | mutable ;

mutable : ID | ID "[" expression "]" ;

immutable : "(" expression ")" | call | constant ; 

call: ID "(" args ")" ;

args:  | arg_list;

arg_list : arg_list","expression | expression ;

constant : INT_NUM | STRINGCONST | CHARCONST | 'true' | 'false' ;

我在

获得2班/减少

状态38冲突：1班/减少州139冲突：1班/减少

具体状态是：

state 38

   81 mutable: ID .  [$end, ADD, SUB, DIV, MULT, COMP_OP, INT, CHAR, CHARCONST, STRINGCONST, GE, LE, NE, EINC, EDEC, INC, DEC, AND, OR, REM, ASSIGN, INT_NUM, ID, ",", "]", "(", ")", ";", "{", "}", "if", "else", "while", "return", "break", "!", "<", ">", "-", "*", 't', 'f']
   82        | ID . "[" expression "]"
   86 call: ID . "(" args ")"

    "["  shift, and go to state 77
    "("  shift, and go to state 78

    "("       [reduce using rule 81 (mutable)]
    $default  reduce using rule 81 (mutable)




state 139

   40 selection_stmt: "if" "(" simple_expression ")" statement .  [$end, INT, CHAR, CHARCONST, STRINGCONST, INT_NUM, ID, "(", ";", "{", "}", "if", "else", "while", "return", "break", "!", "-", "*", 't', 'f']
   41               | "if" "(" simple_expression ")" statement . "else" statement

    "else"  shift, and go to state 141

    "else"    [reduce using rule 40 (selection_stmt)]
    $default  reduce using rule 40 (selection_stmt)

有人可以解释如何修复此错误，我知道它与优先级有关。

Answer 1

状态38中的shift-reduce冲突是以下生产的结果：

return_stmt : "return" ";"
            | "return" expression
            ;

请注意，此生产允许语句以表达式结束。除此产品外，语句必须以; 或} 结尾。如果语句可以以表达式结束，则语法变得模糊不清。例如，考虑一下：

return a
(1+1);

可以是return_stmt（返回值a），后跟expression_stmt，也可以是单个return_stmt，返回函数调用a(1+1)的值。

最有可能的是，这只是你语法中的一个错字，而你打算：

 return_stmt : "return" ";"
            | "return" expression ";"
            ;

（但请参阅下面有关引号的说明。）

状态139处的shift-reduce冲突是典型的C风格if冲突，这是该语言含糊不清的结果：

if (c1) if(c2) s1; else s2;

if适用于哪个else？当然，我们都期望它是内在的if，这是唯一明智的答案（因为当我们看else时，我们不知道是否还有另一个else跟随），但语法本身允许。

正如您所见，

bison在这种情况下会做正确的事情。（它选择移动else，这意味着它不会在没有if的情况下减少内部else。因此，最简单的解决方案是忽略这种特定的转移 - 减少冲突。（参见%expect指令。）

如果这对您没有吸引力，您有两种选择：一种是使用优先级声明来显式优先考虑移位而另一种是在语法中更明确，以便使正确的解析成为必需。在this question, featuring a remarkably similar grammar的两个答案中都很好地探讨了这两种可能性。（要查看优先解决方案，您必须按照Akim的答案中的链接。）

如果您使用的是bison，则应注意"word"和'x'是完全不同的语法。第一个使用一个已经赋予人类可读名称的令牌，通常使用如下声明：

%token TOKEN_RETURN "return"

您需要扫描仪的全大写枚举名称，以便您可以编写（假设您的扫描仪是用flex编写的）：

"return" { return TOKEN_RETURN; }

但语法对引用的字符串更具可读性。（例如，EINC在您的语言中意味着什么？我不知道......）

如果您没有声明令牌的枚举名称，野牛不会抱怨，它仍然会为令牌分配一个代码，但是你要弄清楚代码是多么困难是。

另一方面，'('表示单个字符标记，其代码编号是字符的ascii代码。（因此它对应于C中(的用法。）在这种情况下，代码编号是已知的，您可以用flex编写：

"(" { return '('; }

虽然使用后备规则你最好这样做：

 . { return yytext[0]; }

简而言之，您可能希望将";"的所有用途更改为';'，并将'true'和'false'更改为"true" }和"false"。您可能还想将其他一些关键字标记（如“LE”和“INC”）替换为"<="和"++"，还要为所有双引号标记添加适当的%token声明

Answer 2

在顶部添加#include <gerald.h>

转移/减少错误BISON

2 个答案: