Question

如何在GLSL着色器中执行此类操作？

vec2 attribute texture_sky;
vec2 attribute texture_floor;

if(texture_sky) gl_position = position+Xoffset;
else gl_position = position;

我想将一个纹理移到另一个纹理上。是否可以使用顶点着色器？

Answer 1

我键入的内容是伪代码：不是实际代码。更多解释;假设我有两个纹理（2个图像绑定为纹理）彼此重叠。我想显示一个X + 0.5位移的纹理，而另一个保持不变。我面临的问题是在Shader代码中区分两个纹理。

这不是你可以自己使用顶点着色器做的事情。

您可以在顶点着色器中对纹理坐标应用偏移，但您肯定不会更改顶点位置。多纹理的整个想法是一次应用多个纹理，避免需要绘制多边形的两个不同副本。

在硬件能够在一次通过（Riva TNT）中采样多个纹理之前，您实际上必须多次绘制每个多边形并混合结果以应用多个纹理。这些天你只使用一个片段着色器并调用它一天，因为OpenGL 3.0需要所有硬件支持至少16个同时纹理。

非常粗略，伪代码看起来像这样：

顶点着色器：

#version 110

// Input texture coordinates (from vertex buffer)
attribute vec2 texture_sky;
attribute vec2 texture_floor;

// Output texture coordinates (to fragment shader)
varying vec2 sky_tc;
varying vec2 floor_tc;

// Your offset
uniform vec2 Xoffset;

void main (void) {
  sky_tc   = texture_sky + Xoffset;
  floor_tc = texture_floor;

  gl_Position = ...;
}

片段着色器：

#version 110

// Input texture coordinates (from vertex shader)
varying vec2 sky_tc;
varying vec2 floor_tc;

// Samplers
uniform sampler2D sky_tex;
uniform sampler2D floor_tex;

void main (void) {
  vec4 sky   = texture2D (sky_tex,   sky_tc);
  vec4 floor = texture2D (floor_tex, floor_tc);

  //
  // You have to blend these, so pick one of the following...
  //

  // Additive Blending (GL_ONE, GL_ONE):
  gl_FragColor = sky + floor;

  // or

  // Alpha Blending (GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA):
  gl_FragColor = mix (sky, floor, sky.a);
}

GLSL抵消多重纹理

1 个答案:

非常粗略，伪代码看起来像这样：