Question

我正在学习存在量化，幻像类型和GADT。如何使用幻像变量创建数据类型的异构列表？例如：

{-# LANGUAGE GADTs #-}
{-# LANGUAGE ExistentialQuantification #-}

data Toy a where
  TBool :: Bool -> Toy Bool
  TInt  :: Int  -> Toy Int

instance Show (Toy a) where
  show (TBool b) = "TBool " ++ show b
  show (TInt  i) = "TInt "  ++ show i

bools :: [Toy Bool]
bools = [TBool False, TBool True]

ints  :: [Toy Int]
ints  = map TInt [0..9]

具有以下功能可以：

isBool :: Toy a -> Bool
isBool (TBool _) = True
isBool (TInt  _) = False

addOne :: Toy Int -> Toy Int
addOne (TInt a) = TInt $ a + 1

但是，我希望能够像这样声明异构列表：

zeros :: [Toy a]
zeros =  [TBool False, TInt 0]

我尝试使用空类型来限制a上的类型：

class Unify a
instance Unify Bool
instance Unify Int

zeros :: Unify a => [Toy a]
zeros =  [TBool False, TInt 0]

但上述内容无法编译。我能够使用存在量化来获得以下内容：

data T = forall a. (Forget a, Show a) => T a

instance Show T where
  show (T a) = show a

class (Show a) => Forget a
instance Forget (Toy a)
instance Forget T

zeros :: [T]
zeros = [T (TBool False), T (TInt 0)]

但是这样，我无法将基于a中特定类型Toy a的功能应用于T，例如上面addOne。

总之，有什么方法可以创建异构列表而不会忘记/丢失幻像变量？

Answer 1

从Toy类型开始：

data Toy a where
  TBool :: Bool -> Toy Bool
  TInt :: Int -> Toy Int

现在你可以将它包装在一个存在的中，而不用过度泛化类系统：

data WrappedToy where
  Wrap :: Toy a -> WrappedToy

由于包装器只保存Toy，我们可以展开它们并获得Toy：

incIfInt :: WrappedToy -> WrappedToy
incIfInt (Wrap (TInt n)) = Wrap (TInt (n+1))
incIfInt w = w

现在你可以区分清单中的内容了：

incIntToys :: [WrappedToy] -> [WrappedToy]
incIntToys = map incIfInt

修改

正如Cirdec指出的那样，不同的部分可以分开一点：

onInt :: (Toy Int -> WrappedToy) -> WrappedToy -> WrappedToy
onInt f (Wrap t@(TInt _)) = f t
onInt _ w = w

mapInt :: (Int -> Int) -> Toy Int -> Toy Int
mapInt f (TInt x) = TInt (f x)

incIntToys :: [WrappedToy] -> [WrappedToy]
incIntToys = map $ onInt (Wrap . mapInt (+1))

我还应该注意到，到目前为止，这里的任何内容都不能证明Toy GADT是正确的。 bheklilr使用普通代数数据类型的简单方法应该可以正常工作。

Answer 2

几天前有一个非常相似的question。

在你的情况下，它将是

{-# LANGUAGE GADTs, PolyKinds, Rank2Types #-}

data Exists :: (k -> *) -> * where
  This :: p x -> Exists p

type Toys = [Exists Toy]

zeros :: Toys
zeros = [This (TBool False), This (TInt 0)]

消除存在主义很容易：

recEx :: (forall x. p x -> c) -> Exists p -> c
recEx f (This x) = f x

然后，如果你有Toy数据类型

的recursor

recToy :: (Toy Bool -> c) -> (Toy Int -> c) -> Toy a -> c
recToy f g x@(TBool _) = f x
recToy f g x@(TInt  _) = g x

你可以映射一个包裹的toy：

mapToyEx :: (Toy Bool -> p x) -> (Toy Int -> p y) -> Exists Toy -> Exists p
mapToyEx f g = recEx (recToy (This . f) (This . g))

例如

non_zeros :: Toys
non_zeros = map (mapToyEx (const (TBool True)) addOne) zeros

这种方法与@ dfeuer的答案类似，但它不那么特别。

Answer 3

由其元素类型列表索引的普通异构列表是

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE TypeOperators #-}
{-# LANGUAGE GADTs #-}

data HList l where
    HNil :: HList '[]
    HCons :: a -> HList l -> HList (a ': l)

我们可以修改此值以保留某些f :: * -> *内的值。

data HList1 f l where
    HNil1 :: HList1 f '[]
    HCons1 :: f a -> HList1 f l -> HList1 f (a ': l)

您可以使用它来编写zeros而不会忘记类型变量。

zeros :: HList1 Toy [Bool, Int]  
zeros = HCons1 (TBool False) $ HCons1 (TInt 0) $ HNil1

Answer 4

你玩过Data.Typeable吗？ Typeable约束允许您对存在主体隐藏的类型进行猜测，并在您猜对时强制转换为该类型。

不是你的例子，而是我所说的一些示例代码：

{-# LANGUAGE GADTs, ScopedTypeVariables, TypeOperators #-}

import Data.Typeable

data Showable where
    -- Note that this is an existential defined in GADT form
    Showable :: (Typeable a, Show a) => a -> Showable

instance Show Showable where
    show (Showable value) = "Showable " ++ show value

-- Example of casting Showable to Integer
castToInteger :: Showable -> Maybe Integer
castToInteger (Showable (value :: a)) = 
    case eqT :: Maybe (a :~: Integer) of
      Just Refl -> Just value
      Nothing -> Nothing

example1 = [Showable "foo", Showable 5]
example2 = map castToInteger example1

Haskell：具有幻像变量的数据的异构列表

4 个答案:

修改